Microsoft 365 Macro : masquage cellule d'une colonne suivant valeur

[Bobo80]

Bonjour,

J'aimerais masquer automatiquement les lignes si les cellules de la colonne B contiennent "-"
Comment procéder dans une macro ?

Merci de votre aide 🙂

 

[sylvanu]

Bonjour Bobo,
il eût été préférable de joindre un petit fichier plutôt qu'une image, c'est plus facile.
En PJ un essai avec:

Sub Masque()
    Dim Début%, Fin%, L%
    Application.ScreenUpdating = False
    Début = Range("A1").End(xlDown).Row
    Fin = Range("A65500").End(xlUp).Row
    For L = Fin To Début Step -1
        If Cells(L, "A") = "-" Then Rows(L).Hidden = True
    Next L
End Sub
Sub Démasque()
    Dim Début%, Fin%, L%
    Application.ScreenUpdating = False
    Début = Range("A1").End(xlDown).Row
    Fin = Range("A65500").End(xlUp).Row
    Rows(Début & ":" & Fin).Hidden = False
End Sub

En supposant que le caractère recherché est "-"

 

[Bobo80]

Merci 🙂 alors je n'arrive pas a l'appliquer dans mon cas..

Voilà le fichier joint, dans mon cas, cela concerne la colonne B et C

 

[sylvanu]

Re,
Sur votre "image" seule la colonne B semblait concernée. D'où l'utilité des fichiers test. 🙂

 

[Bobo80]

Merci 🙂 , est-ce que ca serait possible que le masquage soit automatique suivant la valeur qui est prise dans la base de données ? suivant l'article qui est entré sur D8 ? donc sans les icones masquage démasquage ?

 

[sylvanu]

En D8 vous avez un N°. Quand masque t-on ? sur quel N° ? Masque t-on si D8 est vide ?

 

[Bobo80]

en faite suivant le numéro choisis en D8, cela va aller chercher dans la base de donnée, ce qui va remplir les cellules avec ou sans "-"

 

[sylvanu]

En PJ un essai en passant par une macro événementielle mise dans la feuille Test Report :

Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, [Article_Number]) Is Nothing Then
        Application.ScreenUpdating = False
        Démasque
        If Target <> "" Then Masque
    End If
    Application.ScreenUpdating = True
End Sub

La macro s'exécute lorsque la valeur de D8 change.

 

[Bobo80]

Hello, merci bcp 🙂
J'ai encore une requête... j'ai ajouté une option: si la cellule S13 est sur OUI => les lignes 17 à 51 sont masquées et les lignes 51 à 85 sont affichées, si sur NON, c'est l'inverse. Ca ca fonctionne, mais par contre ca désactive le premier masquage avec les cellule comportant "-".. j'ai surement mal mis cela dans la macro...

 

[sylvanu]

Bonjour,
Ca ne peut pas marcher. Vous avez deux macros qui masquent/démasquent et que se suivent.
Il faut faire deux macros suivant les différents choix.
En PJ un essai avec une macro pour les lignes 17 50 et une pour les lignes 51 85 :

Sub Worksheet_Change(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, [Article_Number]) Is Nothing Or _
        Not Intersect(Target, [OuiNon]) Is Nothing Then
        Application.ScreenUpdating = False
        Démasque
        If Target <> "" And [OuiNon] = "OUI" Then Masque1750 Else Masque5185
    End If
    Application.ScreenUpdating = True
End Sub
Sub Masque1750()
    Dim L%
    Rows("17:50").Hidden = False
    Rows("51:85").Hidden = True
    For L = 50 To 17 Step -1
        If Cells(L, "A") = "-" Then Rows(L).Hidden = True
        If Cells(L, "C") = "-" Then Rows(L).Hidden = True
    Next L
End Sub
Sub Masque5185()
    Dim L%
    Rows("17:50").Hidden = True
    Rows("51:85").Hidden = False
    For L = 85 To 51 Step -1
        If Cells(L, "A") = "-" Then Rows(L).Hidden = True
        If Cells(L, "C") = "-" Then Rows(L).Hidden = True
    Next L
End Sub
Sub Démasque()
    Rows("1:" & Range("C200").End(xlUp).Row).Hidden = False
End Sub

 

[Bobo80]

Merci! 🙂 il y a juste un autre problème, c'est que la colonne C qui doit être pris en compte se trouve entre la ligne 93 et 125, donc ca ne prends pas en compte le masquage des cellule avec "-"

 

[sylvanu]

Bonjour,
Je n'ai retravaillé que vos ranges 17 50 et 51 85.
Comment le oui non intervient sur 93 125 ?
Pouvez vous être plus précis ?

 

[Bobo80]

Bonjour,
les ranges 93 125 ne concernent pas le OUI NON mais le masquage des cellules de la colonne C comportant un ”-“
Il y a bien la colonne A qui fonctionne pour les ranges 17 50 et 51 85 avec le masquage des cellules “-“ mais pas la colonne C

 

[sylvanu]

Re,
Dans ce cas il suffit de rajouter une macro Masque93125 qui traite ce segment indépendamment de OuiNon.