Macro à créer avec 6 critères

[MisterT]

Bonjour à tous,

C'est ma 1ère présence sur un Forum. C'est nouveau pour moi.

J'ai insérée une pièce jointe contenant les détails de mon besoin sur la Feuil1.

Mes connaissances en VBA sont trop limitées pour trouver la solution moi-même. J'utilise Excel 2003 PC.

Merci à l'avance à ceux qui utiliseront temps et connaissances pour m'aider pour cette Macro !

MisterT

 

[Cousinhub]

Re : Macro à créer avec 6 critères

Bonjour,

et bienvenue

essaie avec ce code, à coller dans un module :

Sub cherche()
Dim Prem As String, Deuz As String, Troiz As String
Dim Sh As String
Dim Lig1 As Long, Lig2 As Long, Lig3 As Long, Lig4 As Long
Dim Plg1 As Range, Plg2 As Range, Plg3 As Range
'calcul du nom de la feuille
Prem = [J6] & "x"
Deuz = [K6] & "_"
Troiz = IIf([J8] = [J9], "1 PIECE", IIf([J8] < [J9], "3 PIECE", "2 PIECE"))
Sh = Prem & Deuz & Troiz
With Sheets(Sh)
    Lig1 = Application.Match([G6], .Columns(1), 1)
    Set Plg1 = .Cells(Lig1, 3).Resize(.Cells(Lig1, 1).MergeArea.Rows.Count, 1)
    Lig2 = Application.Match([J8], Plg1, 1) - 1
    Lig2 = Lig1 + Lig2
    Set Plg2 = .Cells(Lig2, 5).Resize(.Cells(Lig2, 3).MergeArea.Rows.Count, 1)
    Lig3 = Application.Match([J9], Plg2, 1) - 1
    Lig3 = Lig2 + Lig3
    Set Plg3 = .Cells(Lig3, 7).Resize(.Cells(Lig3, 5).MergeArea.Rows.Count, 1)
    Lig4 = Application.Match([N5], Plg3, 1) - 1
    Lig4 = Lig3 + Lig4
    Range("B14:Q14").Value = .Range(.Cells(Lig4, 10), .Cells(Lig4, 25)).Value
    Range("B23:T23").Value = .Range(.Cells(Lig4 + 1, 10), .Cells(Lig4 + 1, 28)).Value
End With
End Sub

Regarde le fichier

Bonne journée

 

[MisterT]

Re : Macro à créer avec 6 critères

Merci infiniment bhbh !

Ça fonctionne à merveille, j'en suis très étonné, un code si court pour accomplir autant.

Il me reste à inclure des données dans les pages 2 PIECES et 3 PIECE pour confirmer le tout.

Un GROS MERCI, c'est une aide précieuse !!!