Listbox1 sans doublon

[bmhx60]

Bonjour a tous,

Avez vous une idée pour eviter les doublons dans une listBox1.
J'utilise le code suivant :

Private Sub UserForm_Activate()
Dim i As Integer
For i = 1 To Sheets("Base MP").Range("B65535").End(xlUp).Row
If Sheets("Base MP").Cells(i, 2).Value = ActiveCell.Offset(0, -1).Value Then
ListBox1.AddItem (Sheets("Base MP").Cells(i, 1).Value)
End If
Next
End Sub

Merci d'avance de votre aide.

@+

 

[jp14]

Re : Listbox1 sans doublon

Bonjour

Une solution parmi d'autres basée sur l'unicité dans une collection

Dim i As Integer
Dim erreur As Boolean
Dim coll As New Collection
For i = 1 To Sheets("Base MP").Range("B65535").End(xlUp).Row
If Sheets("Base MP").Cells(i, 2).Value = ActiveCell.Offset(0, -1).Value Then
    erreur = False
    On Error GoTo suite
    coll.Add (Sheets("Base MP").Cells(i, 1).Value), CStr((Sheets("Base MP").Cells(i, 1).Value))
    If erreur = False Then
        ListBox1.AddItem (Sheets("Base MP").Cells(i, 1).Value)
    End If

End If
On Error GoTo 0
Next
Exit Sub
suite:
erreur = True
Resume Next
End Sub

A tester

JP

 

[BOISGONTIER]

Re : Listbox1 sans doublon

Bonjour,

Méthode rapide 0,1s pour 10.000 lignes

  Set f = Sheets("BD")
  Set MonDico = CreateObject("Scripting.Dictionary")
  For Each c In Range(f.[A2], f.[A65000].End(xlUp))
   If c.Value <> "" Then MonDico.Item(c.Value) = c.Value
  Next c
  Me.ComboBox1.List = MonDico.items

http://boisgontierjacques.free.fr/pages_site/formulairelistesansdoublons.htm

JB

 

[JPS28]

Re : Listbox1 sans doublon

Bonjour bmhx60
En l'adaptant a ton cas je pense que se code peut être intéressant
Cordialement.
JPS
Private Sub UserForm_Initialize()
For i = 1 To Sheets(1).[A65000].End(xlUp).Row
Me.ComboBox1 = Sheets(1).Cells(i, "A") ' on se positionne dans le combobox
If Me.ComboBox1.ListIndex = -1 Then ' Existe t-il?
Me.ComboBox1.AddItem Sheets(1).Cells(i, "A")
End If
Next i
End Sub

 

[bmhx60]

Re : Listbox1 sans doublon

Bonjour,

Merci a JP14 , BOISGONTIER, JPS28 pour leur aide.

Je teste les codes dans l'apres midi

Bonne journée