XL 2019 Ligne excel répétition

[fimo41]

Bonjour à tous

Désolé encore un problème tordu !!

Je bloque pour faire un publipostage ( pas pour le courrier )

Ci joint le fichier !!!

Mon probleme le fichier comporte des lignes ok mais il faut que je fasse étiquettes par rapport au stock !!

Donc en fusion avec indesign pas trop le choix de faire plusieurs lignes !!

Exemple Ref EX05 stock 4 il me faut 4 lignes
Exemple Ref EX06 stock 12 il me faut 12 lignes


Merci

@+ Rodolphe

 

[mapomme]

Bonjour @fimo41 🙂,

Si j'ai bien compris, voici une version VBA. La feuille "Duplication" se met à jour quand on la sélectionne.
Le code est dans le module associé à la feuille "Duplication":

Private Sub Worksheet_Activate()
Dim t, n&, i&, j&, k&
   With Sheets("Feuil1")
      If .FilterMode Then .ShowAllData
      t = Intersect(.Range("a1").CurrentRegion, .Range("a:i"))
      n = Application.Sum(.Range("i:i"))
   End With
   ReDim r(1 To n + 1, 1 To UBound(t, 2)): n = 1
   For j = 1 To UBound(t, 2): r(n, j) = t(1, j): Next
   For i = 2 To UBound(t)
      For k = 1 To t(i, UBound(t, 2))
         n = n + 1
         For j = 1 To UBound(t, 2): r(n, j) = t(i, j): Next j
      Next k
   Next i
   With Sheets("Duplication")
      .Columns(1).Resize(, UBound(r, 2)).ClearContents
      .Columns(1).Resize(UBound(r), UBound(r, 2)) = r
      .Columns(1).Resize(, UBound(r, 2)).AutoFit
   End With
End Sub