Je cherche à trouver les 2 valeurs max d'un tableau Excel

D

Dan

Guest

• 6 Janvier 2004

• #2

Bonsoir,

Si j'ai bien compris ta question, tu peux utiliser la fonction MAX().

Exemple pour des données entre A1 et A10 : place la formule MAX(A1:A10) dans une cellule du tableau.

@+

Dan

 

Vote positif 0 Vote négatif

M

Martibeche

Guest

• 6 Janvier 2004

• #3

Oui, mais ça sa va donner qu'UNE valeur MAX, moi je veux les 2 valeurs MAX de la série

 

Vote positif 0 Vote négatif

M

Moa

Guest

• 6 Janvier 2004

• #4

Salut les gars !

=Grande.Valeur(A1:A10;1) donnera la première valeur max.

=Grande.Valaeur(A1:A10;2) donnera la deuxième valeur max.

=Grande.Valaeur(A1:A10;3) donnera la troisième valeur max.

et ainsi de suite et pareil dans l'autre sens pour petite valeur

=Petite.Valeur(A1:A10;1) donnera la première valeur min.

=Petite.Valaeur(A1:A10;2) donnera la deuxième valeur min.

Mais attention en cas d'égalité de valeur, cette fonction ne donnera pas la valeur suivante mais bel et bien la même.

Exemple : 6 valeurs : 2-5-7-7-9

=Grande.Valeur(A1:A10;1) résultat = 9

=Grande.Valeur(A1:A10;2) résultat = 7

=Grande.Valeur(A1:A10;3) résultat = 7

Et voilà !

@ +

Moa

 

Vote positif 0 Vote négatif

A

andré

Guest

• 6 Janvier 2004

• #5

Salut à vous deux, et aux autres,

Pour rechercher les deux plus grandes valeurs d'une plage et éviter que ne soient renvoyées les mêmes valeurs si elles sont doubles, voire même triple, quadruple, ..., la formule suivante devrait renvoyer la deuxième valeur, (la plage de valeurs de A1 à A5) :

=SI(NB.SI(A1:A5;GRANDE.VALEUR(A1:A5;1))>1;GRANDE.VALEUR(A1:A5;NB.SI(A1:A5;GRANDE.VALEUR(A1:A5;1))+1);GRANDE.VALEUR(A1:A5;2))

A vérifier, et à confirmer si cela marche.
Ândré.

 

Vote positif 0 Vote négatif

M

Monique

Guest

• 6 Janvier 2004

• #6

Bonjour,

Une autre pour trouver la 2è grande valeur inférieure au max :
=MAX(SI(A1:A10=MAX(A1:A10);"";A1:A10))
ou bien
=MAX(SI(A1:A10=MAX(A1:A10);;A1:A10))
Formule matricielle, à valider par ctrl, maj et entrée

 

Vote positif 0 Vote négatif

M

Monique

Guest

• 6 Janvier 2004

• #7

Re,

Suite
=GRANDE.VALEUR(SI(A1:A10=GRANDE.VALEUR(A1:A10;1);;A1:A10);1)

 

Vote positif 0 Vote négatif

A

andré

Guest

• 6 Janvier 2004

• #8

Salut à tous,

Monique, je rencontre un petit problème avec ta dernière formule.
Aurais-tu une explication, moi je ne la trouve pas ?

Ândré.

 

Pièces jointes

• MAX2.zip

  1.8 KB · Affichages: 205

Vote positif 0 Vote négatif

J

Jean-Marie

Guest

• 6 Janvier 2004

• #9

Bonjour tout le monde

Simplement un petit plus, puisque la solution la plus simple a été donnée pour le problème évoqué.

Pour retrouver les X valeurs les plus importantes
=MAX(SI(NB.SI(C$1:C1;A$1:A$100)=0;A$1:A$100))
Avec cette formule matricielle (à valider par les touches
Crtl+Shift+Entrer)
Cette formule doit être mise en C2 et par glisser/déposer sur les lignes en dessous. La plage des données est A$1:A$100
La cellule C1 ne doit pas contenir une valeur numérique, mais peu recevoir un texte alphanumérique, ou la formule =MAX(A$1:A100).

Si l'emplacement de la formule n'est pas la cellule C2, il faut changer dans cette formule la partie C$1:C1. Exemple tu veux la mettre en O40
remplace donc par O$39:O39,

La plage A$1:A$100 peu avoir des cellules vides, les valeurs numériques validées sont formes de texte ('15 par exemple) ne sont pas prises en compte.

Si la dernière valeur MAX a été trouvée, la fonction retournera la valeur 0, ce qui correspond aussi à la valeur d'une cellule vide.

Pour MIN il suffit de remplacer MAX.

Bonne journée

@+Jean-Marie

 

Vote positif 0 Vote négatif

M

Monique

Guest

• 6 Janvier 2004

• #10

Re,

J'ai oublié de signaler que c'est une formule matricielle, à valider par ctrl, maj et entrée
Un résultat faux si l'on valide de façon classique, d'accord.
Trois résultats différents avec la même formule, pourquoi ?
Et si l'on trie les données dans l'ordre croissant ou décroissant, les résultats se trient aussi !

 

Vote positif 0 Vote négatif

A

andré

Guest

• 6 Janvier 2004

• #11

Maintenant on est d'accord !

Ândré.

 

Vote positif 0 Vote négatif

M

Moa

Guest

• 6 Janvier 2004

• #12

Hé les filles et les gars !

Avec toutes ces réponses il devrait y arriver...non...hihihi...!!!

Vous savez quand je vois tant de réponses différentes pour une seule question, je me dis que des fois pour s'amuser, on devrait, sur un exemple comme celui-là, lancer le concours de la formule la plus courte, ou alors le concours de la formule la plus pratique....ou alors la plus débile....héhé...!!

@ cogiter...!

@ +

Moa

 

Vote positif 0 Vote négatif

A

andré

Guest

• 6 Janvier 2004

• #13

Resalut,

Sans vouloir lancer ce concours, voici une version nettement simplifiée de ma première version :

=GRANDE.VALEUR(A1:A10;NB.SI(A1:A10;GRANDE.VALEUR(A1:A10;1))+1)

Ândré.

 

Vote positif 0 Vote négatif

C

coyote

Guest

• 6 Janvier 2004

• #14

Moi c'est pour le concours de la formule la plus débile

=TA_KA_LE_CALCULER_SAN_EXCEL

 

Vote positif 0 Vote négatif