XL 2019 Incrémenter un n° dans une colonne en fonction des infos présente sur les colonnes précédente

[Midolieu]

Bonjour,

Je débute sur un excel et je suis confronté un petit problème pour automatiser l'incrémentation d'un numéro.

J'ai un tableau avec les colonnes suivantes :
- Colonne "Service" qui permet de sélectionner une liste déroulante avec les différents service de mon entreprise
- Colonne "Métier" qui permet de sélectionner une liste déroulante avec les différents métier technique de mon entreprise
- Colonne "Taches" qui permet de sélectionner une liste déroulante avec les différentes taches qui peuvent être réalisées
- Colonne "Chrono" que je souhaiterai remplir avec un numéro 001 à 999

Ce que je voudrait c'est que la colonne Chrono s'incrémente de la manière suivante :

Ex :
Achat | Electricité | Tache 01 | 001
Achat | Mécanique | Tache 01 | 001
Magasin | Electricité | Tache 01 | 001
Magasin | Mécanique | Tache 01 | 001
Achat | Electricité | Tache 01 | 002
Achat | Electricité | Tache 01 | 003
Magasin | Hydraulique | Tache 01 | 001
Achat | Electricité | Tache 02 | 001
Achat | Electricité | Tache 02 | 002
Magasin | Hydraulique | Tache 02 | 001

Après je ne sais pas trop pour ce qui est du remplissage de la colonne "Chrono" :
- est ce que le remplissage doit être automatique dès que la tache est choisi dans la colonne "Tache" ?
ou
- est ce que le remplissage doit être manuel dans une liste déroulante qui ne contiendrait que la bonne valeur de Numéro ?

Est ce que vous pourriez m'orienter vers une solution pour réaliser ce petit cahier des charges, est ce que une série de formules peut répondre à ce besoin ?

Merci d'avance pour votre aide

Bonne soirée

 

[Hasco]

Bonjour,

Avec la première ligne des données en A2 et le chrono en D

=NB.SI.ENS($A$2:$A2;$A2;$B$2:$B2;$B2;$C$2:$C2;$C2)

ATTENTION à la position des $
Mettre la colonne en format personnalisé : '000'

Cordialement

 

[gbinforme]

Bonjour,

Je suppose que tu as une ligne titre et donc en D2 je te propose de mettre cette formule et de la tirer sur la colonne pour avoir ton numéro "Chrono" en mettant le bon format ( ooo ) bien sûr.

=SOMMEPROD(($A$2:A2=A2)*($B$2:B2=B2)*($C$2:C2=C2))

 

[job75]

Bonjour Midolieu, bienvenue sur XLD,

Voyez le fichier joint.

Le tableau est un tableau structuré (menu Insertion-Tableau).

Formule en D2 =[@Service]&[@Métier]&[@Tache]

Formule en E2 :

=SI(NB.VIDE(Tableau1[@[Service]:[Tache]]);"";NB.SI(D$1:D2;D2))

Edit : c'est pas vrai, quand j'ai posté ni le post #2 ni le post #3 n'étaient affichés, bonjour à vous deux.

A+

 

[Midolieu]

Bonsoir à vous trois,

Merci pour votre accueil et vos réponses.

C'est parfait pour les 3 solutions, je suis partie sur celle de job75 qui me permet en plus de travailler au format d'un tableau structuré.

Encore merci pour votre réactivité.

Bonne soirée

Cordialement

 

[job75]

Bonjour Midolieu, le fil, le forum,

Puisque les formules NB.SI.ENS et SOMMEPROD fonctionnent pourquoi j'utilise une colonne auxiliaire ?

Eh bien testez en copiant la ligne 2 sur 20 000 lignes, chez moi :

- avec colonne auxiliaire => 9 secondes

- sans colonne auxiliaire et formule NB.SI.ENS => 25 secondes

- sans colonne auxiliaire et formule SOMMEPROD => 32 secondes.

A+

 

[Midolieu]

Bonjour job75,

Merci pour cette précision.
En quoi l'ajout de cette colonne permet un traitement plus rapide?

Merci d'avance pour ton retour
A+

 

[job75]

En quoi l'ajout de cette colonne permet un traitement plus rapide?

Parce que la formule avec NB.SI travaille sur une seule colonne, les autres formules sur 3 colonnes.