incrémenter formule vers le bas

[diesel]

Bonjour,

désolé pour le titre un peu flou mais je ne sais pas comment formuler ma demande.

voici les faits:

je cherche une façon d'incrémenter la lettre d'une colonne en tirant vers le bas la poignée de recopie et en augmentant de 4 colonne à chaque fois.

je pense que c'est incompréhensible donc voici le but recherché:

sur la feuille1 en A1: j'ai une formule =somme(feuille2!C6), je veux recopier cette formule vers le bas et obtenir dans la cellule du dessous A2: =somme(feuille2!g6) en A3 =somme(feuille2!K6) etc....

est ce possible?

merci d'avance à tous les pro 😉

 

[job75]

Re : incrémenter formule vers le bas

Re,

Vous aurez vu toutes les fonctions sur ce fil !

Voilà les 2 formules :

=INDIRECT("'"&INDEX($B:$B;LIGNE())&"'!"&ADRESSE(10;COLONNE()))

=INDIRECT("'"&DECALER($B$8;LIGNES(C$9:C9);0)&"'!"&ADRESSE(10;COLONNE(C9)))

Edit : la feuille où se trouvent les formules ne doit pas être une feuille B9 B10 B11...

A+

 

[diesel]

Re : incrémenter formule vers le bas

effectivement je pense que l'on à fait le tour des cas de figure, quoique.. 😉

En tout cas mille merci pour votre patience et pour cette aide toujours rapide.

je me désole de ne pas lire ces formule avec autant de faciliter que vous à les composer.

merci encore et bonne journée.

 

[lyo75]

Re : incrémenter formule vers le bas

Bonsoir à tous,

Désolé de réouvrir ce poste car je n'arrive pas à adapter les explications à mon cas d'espèce.

Supposons qu'en B2, j'ai la formule matricielle suivante.Mon objectif est de renvoyer la première cellule non vide de la plage K6 à K212, puis L6 à L212,....

+INDEX('BG french - V1'!K$6:K$212;EQUIV(VRAI;'BG french - V1'!K$6:K$212<>"";0))

Je souhaiterais l'incrémenter pour avoir en B3:

+INDEX('BG french - V1'!L$6:L$212;EQUIV(VRAI;'BG french - V1'!L$6:L$212<>"";0))

PS: je suis novice sur les formules INDEX, EQUIV, DECALER et INDIRECT et j'ai plus de 100 lignes à traiter🙁

Merci d'avance pour votre aide 🙂

Lyo75

 

[job75]

Re : incrémenter formule vers le bas

Bonjour lyo75, bienvenue sur XLD,

Formule matricielle en B2 à tirer vers le bas :

=INDEX(DECALER('BG french - V1'!J:J;;LIGNES(B$2:B2));MIN(SI(SOUS.TOTAL(3;DECALER('BG french - V1'!J$1;LIGNE(INDIRECT("6:212"))-1;LIGNES(B$2:B2)));LIGNE(INDIRECT("6:212")))))

Elle fonctionne bien, sur des nombres comme sur des textes, mais il y a peut-être plus simple.

A+

 

[job75]

Re : incrémenter formule vers le bas

Re,

Une formule en B2 un peu plus simple :

=INDEX(DECALER('BG french - V1'!J$6:J$212;;LIGNES(B$2:B2));EQUIV(1;SOUS.TOTAL(3;DECALER('BG french - V1'!J$1;LIGNE(INDIRECT("6:212"))-1;LIGNES(B$2:B2)));0))

A+

 

[R@chid]

Re : incrémenter formule vers le bas

Bonjour et Bienvenue sur XLD,
Salut maitre Job75,
Faute de fichier exemple pour faire le test..
en B2,

=DECALER('BG french - V1'!J$5;EQUIV(VRAI;DECALER('BG french - V1'!J$6:J$212;;LIGNES($2:2))<>"";0);LIGNES($2:2))

@ valider par Ctrl+Maj+Entree
@ tirer vers le bas

@ + +

 

[job75]

Re : incrémenter formule vers le bas

Bonjour R@chid,

Oui il était inutile d'utiliser SOUS.TOTAL.

Ta formule pèse 68 octets contre 96 au post #20 et 112 au post #19.

A+

 

[R@chid]

Re : incrémenter formule vers le bas

Re,
Je ne sais pas comment calculer le poids de formules, et pour te montrer que je ne sais pas le faire, voir le poids que j'ai pu trouver 😉 😀


@ + +

 

[lyo75]

Re : incrémenter formule vers le bas

Bonsoir job75 et R@chid,

Merci beaucoup!! Vos formules fonctionnent à merveille. Je vais essayer de comprendre la plus simple, à savoir celle de R@chid.

Bonne soirée
A++