Incompréhension d'une formule assez longue

[Hoerges H.]

Bonjour le forum,

Je dois analyser une formule en excel mais vue que je suis débutant c'est pas évident.

Quelqu'un pourraît'il me dire à quoi correspond cette formule ?

=($D$7*(SI(ESTTEXTE(D10);0;1))+$E$7*(SI(ESTTEXTE(E10);0;1))+$F$7*(SI(ESTTEXTE(F10);0;1))+$G$7*(SI(ESTTEXTE(G10);0;1))+$H$7*(SI(ESTTEXTE(H10);0;1))+$I$7*(SI(ESTTEXTE(I10);0;1))+$J$7*(SI(ESTTEXTE(J10);0;1)))+$K$7*(SI(ESTTEXTE(K10);0;1))

Merci d'avance pour l'aide que vous m'apporterez et bonne fin de journée.

Goerges H.

 

[Gérard DEZAMIS]

Bonsoir H. Hoerges

$D$7*(SI(ESTTEXTE(D10);0;1))+

Le contenu de la cellule D7 est multiplié par 1 si le contenu de la cellule D10 est du texte sinon on multiplie par zéro c'est à dire que l'on annule.

Début de déchiffrage , la suite est du même genre ... et on additionne les membres.

@+ GD

Message édité par: Gérard DEZAMIS, à: 12/05/2005 17:26

 

[Goerges H.]

Bonjour,

Merci pour votre réponse.

Cela m'aide beaucoup.

Demain je pense que je devrais encore venir sur ce forum car il y'en a d'autre genre :

=SI(OU(NB.SI(D10:R10;'abs')>0;NB.SI(D10:R10;'j')>0);0;(U10+W10)/(T10+V10))

ou

=SI(OU((Z10<AJ10*0,9);AH10>1);'';SI((AI10>2);'LPGD';CTXT(Z10-AJ10*0,9;0)&' / lpgd  ?'))

Merci et bonne soirée

Goerge H.

 

[Monique]

Bonjour,

Celle-ci fait la même chose :
=SOMMEPROD((NON(ESTTEXTE(D10:K10)))*D7:K7)

 

[Robert]

Salut Goerges (ou Hoerges), salut le forum,

la formule additionne toute les cellules de la plage D7:K7 mais en vérifiant pour chaque cellule trois lignes plus bas. Si D10 contient du texte alors D7 n'est pas pris en compte et si D10 contient un valeur numerique, alors D7 est pris en compte. Cela grace à la condition SI(ESTTEXTE(D10);0;1) qui renvoie 0 si D10 est du texte et 1 si D10 est numérique. Donc D7*0 (si D10 = texte) = 0 ou D7*1 (si D10 est numérique)=D7. Idem pour les autres cellule D7, F7..., K7.
J'espère que j'ai été assez clair

 

[Gérard DEZAMIS]

Re Suite (?)

=SI(OU(NB.SI(D10:R10;'abs')>0;NB.SI(D10:R10;'j')>0);0;(U10+W10)/(T10+V10))

Si le Nombre d' 'abs' est plus grand que 0 OU si le nombre de 'J' est lui aussi plus grand que 0 dans la plage de cellules allant de D10 à R10 alors on met zéro sinon en divise la somme de U1 et W10 par la somme de T10 et de V10


@+ GD

 

[Gérard DEZAMIS]

Belle entorse à la politesse

Bonsoir Monique
Bonsoir Robert

J'ai risqué le cachot !

@+ GD

 

[GH]

Merci Monqiue pour votre réponse.

Je vais appliquer ce que vous me dite.

GH

 

[GH]

Bonjour Robert,

Un super grand merci et une super bonne soirée.

GH

 

[GH]

Gérard DEZAMIS écrit:

Re Suite (?)

=SI(OU(NB.SI(D10:R10;'abs')>0;NB.SI(D10:R10;'j')>0);0;(U10+W10)/(T10+V10))

Si le Nombre d' 'abs' est plus grand que 0 OU si le nombre de 'J' est lui aussi plus grand que 0 dans la plage de cellules allant de D10 à R10 alors on met zéro sinon en divise la somme de U1 et W10 par la somme de T10 et de V10


@+ GD

Je suis très impressionné par votre savoir !

Merci beaucoup !

Je vais analyser vos réponses et les appliquer.

Encore un grand merci.

GH

 

[Gérard DEZAMIS]

Re à tous

Puisque l'on est si bien parti ....:huh:


pourquoi ne pas continuer ...:unsure:


=SI(OU((Z10<AJ10*0,9);AH10>1);'';SI((AI10>2);'LPGD';CTXT(Z10-AJ10*0,9;0)&' / lpgd ?'))

Si le contenu de la cellule Z10 est plus petit que les 90% de la cellule AJ10 OU que AH10 est supérieur à 1 alors on ne met rien et la cellule est vide sinon si AI10 est supérieur à 2 on écrit LPGD sinon il faut convertir en texte la valeur (entière) de Z10 moins les 90% de AJ10 et ensuite on ajoute à ce texte /lpgd ?

@+ GD