Autres inclure des si dans une formule datedif

patricktoulon · 22 Octobre 2019

Bonjour a tous

je voudrais inclure des si dans une formule datedif
en effet j'ai une formule qui peut me donner comme résultat
0 ans 0 mois 15 jours

je voudrais inclure des si si les valeurs an et mois et jour donne zero
l'exemple précédemment donné devrait donner par exemple simplement 15 jours
et pour parfaire la chose je voudrais aussi des si >1 mettre les "s"

la formule

=DATEDIF(A1;B1;"y")&" Ans "
&DATEDIF(A1;B1;"ym")&" mois "
&DATEDIF(DATE(ANNEE(B1);MOIS(B1);JOUR(A1));B1;"d")&" jours"

job75 · 22 Octobre 2019

Bonjour patricktoulon,

Définir comme indiqué dans le fichier joint les 3 noms a m j et entrer en C1 la formule :

Code:

=SUPPRESPACE(REPT(a&" an"&SI(a=1;" ";"s ");a>0)&REPT(m&" mois ";m>0)&REPT(j&" jour"&REPT("s";j>1);j>0))

Edit : bah j'oubliais que mois s'écrit avec un "s" au singulier !!!

A+

patricktoulon · 22 Octobre 2019

re bonjour job75
la formule doit se répéter dois-je répéter les names !!???

au moins n'y a til pas moyen par exemple de mettre les formules en r1c1 dans les name

xUpsilon · 22 Octobre 2019

Simple indication, FormulaLocal est plus pratique à utiliser que R1C1, ça évite de se taper la conversion des lignes/colonnes et la traduction en anglais

Bonne continuation

patricktoulon · 22 Octobre 2019

re j'ai tenté cela au moins pour les années en colonne "E" mais visiblement une condition va contre l'autre (difficile sans les( if else de vba)
j'avoue avoir du mal a comprendre le 2d si est dans la condition1 ">0"

=SI(DATEDIF(A1;B1;"y")>0;DATEDIF(A1;B1;"y")&" an"&SI(DATEDIF(A1;B1;"y")>1;"s";"");"")

alors quand j'ai 0 ans c'est bon
quand j'ai plus de 1 c'est bon
mais quand j'ai 1 j'ai "1 ansFAUX"

job75 · 22 Octobre 2019

C'est pourtant simple, les formules des noms définis au post #2 utilisent des références relatives.

On peut donc tirer la formule en C1 vers le bas.

patricktoulon · 22 Octobre 2019

re
ok job75
je sais pas pourquoi j'avais essayé la première fois et en étendant la formule ca me mettait #NOMBRE

bon me reste a la digérer

pour que je comprenne
la formule =DATEDIF(Feuil1!A1;Feuil1!B1;"y") dans le name "a",devient une matrice de formule dans le sens A1 et B1 sont modifiés
automatiquement quand j' étends la formule

en fait on créé une sorte de pattern de formule

merci Job75

edit :
ok j'ai pigé
repete formule "a" la valeur numerique du booleen obtenu par >1
pareil pour mois et jour

si je me sert pas des name pour abréger mes formules ca donne ca (je suis pas payé au kilometre)

=REPT(DATEDIF(Feuil1!A1;Feuil1!B1;"y")&" an"&SI(DATEDIF(Feuil1!A1;Feuil1!B1;"y")=1;" ";"s ");DATEDIF(Feuil1!A1;Feuil1!B1;"y")>0)&REPT(DATEDIF(Feuil1!A1;Feuil1!B1;"ym")&" mois ";DATEDIF(Feuil1!A1;Feuil1!B1;"ym")>0)&REPT(DATEDIF(DATE(ANNEE(Feuil1!B1);MOIS(Feuil1!B1);JOUR(Feuil1!A1));Feuil1!B1;"d")&" jour"&REPT("s";DATEDIF(DATE(ANNEE(Feuil1!B1);MOIS(Feuil1!B1);JOUR(Feuil1!A1));Feuil1!B1;"d")>1);DATEDIF(DATE(ANNEE(Feuil1!B1);MOIS(Feuil1!B1);JOUR(Feuil1!A1));Feuil1!B1;"d")>0)

bien vu le rept

Modeste geedee · 23 Octobre 2019

Bonsour®

job75 à dit:
Définir comme indiqué dans le fichier joint les 3 noms a m j et entrer en C1 la formule :

Code:

=SUPPRESPACE(REPT(a&" an"&SI(a=1;" ";"s ");a>0)&REPT(m&" mois ";m>0)&REPT(j&" jour"&REPT("s";j>1);j>0))

? pourquoi dans la définition de "j" ne pas utiliser :
=DATEDIF(Feuil1!A1;Feuil1!B1;"md")

et pourquoi alors :

patricktoulon · 23 Octobre 2019

bonjour Modeste geedee
en effet il y a bien erreur

pour la formule avec "md" c'est non parce que les jours vont plus loin que 31
j'obtient 121 jours avec tes deux dates
merci pour ton intervention

moi qui voulais me simplifier la vie avec des formules

Modeste geedee · 23 Octobre 2019

Bonsour®

patricktoulon à dit:
en effet il y a bien erreur

pour la formule avec "md" c'est non parce que les jours vont plus loin que 31
j'obtient 121 jours avec tes deux dates

tu utilises alors EXCEL 2007 !!!
sauf que avec Excel 2007 DateDif est buggé lors de l'utilisation du parametre "md"
lorsque la date la plus récente est un année bissextile, en janvier et le jour récent < jour début

patricktoulon · 23 Octobre 2019

Bonjour Modeste geedee
oui exact j'utilise 2007 et ou 2013
je viens de tester sur 2013 ca fonctionne

bon ben c'est pas gagné alors pour trouver un truc qui va fonctionner partout

job75 · 23 Octobre 2019

Bonjour patricktoulon, Modeste geedee,

Je n'ai pas trop cherché mais ça semble aller en définissant en C1 le nom j par :

Code:

=B1-DATE(ANNEE(B1);MOIS(B1)-(B1<DATE(ANNEE(B1);MOIS(B1);JOUR(A1)));JOUR(A1))

qui se convertit bien sûr en :

Code:

=Feuil1!B1-DATE(ANNEE(Feuil1!B1);MOIS(Feuil1!B1)-(Feuil1!B1<DATE(ANNEE(Feuil1!B1);MOIS(Feuil1!B1);JOUR(Feuil1!A1)));JOUR(Feuil1!A1))

Fichier (2).

A+

Modeste geedee · 23 Octobre 2019

Bonsour®

job75 à dit:
Je n'ai pas trop cherché mais ça semble aller en définissant en C1 le nom j par :

Code:

=B1-DATE(ANNEE(B1);MOIS(B1)-(B1<DATE(ANNEE(B1);MOIS(B1);JOUR(A1)));JOUR(A1))

méfiance dans l'utilisation des argument de DATEDIF

patricktoulon · 23 Octobre 2019

re
bonjour Job75
ca a l'air de fonctionner je testerais avec plus de date dans mon fichier original

je reviens tout a l'heure pour confirmation

Modeste geedee · 23 Octobre 2019

Bonsour®

patricktoulon à dit:
bon ben c'est pas gagné alors pour trouver un truc qui va fonctionner partout

solution alternative :
années
=année(B1-A1)-1900

mois
=Mois(B1-A1)-1

jours
=jour(B1-A1)

Autres inclure des si dans une formule datedif

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

patricktoulon

XLDnaute Barbatruc

xUpsilon

XLDnaute Accro

patricktoulon

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Modeste geedee

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Modeste geedee

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

job75

XLDnaute Barbatruc

Pièces jointes

Modeste geedee

XLDnaute Barbatruc

patricktoulon

XLDnaute Barbatruc

Modeste geedee

XLDnaute Barbatruc

Discussions similaires