Imprimer un fichier word avec macro excel

[Tchingum]

Bonjour,

Je suis à la recherche d'une macro qui par inscription dans une cellule excel pour faire imprimer une feuille word

exemple: dans la cellule "DE" imprime le doc. allemand ou "FR" imprime le doc. français ou "E" imprime le doc. espagnol (~9 langues)

Voici la macro que j'ai mise, mais il me faut un bouton pour chaque langue.

Sub ouvrirDocWord_Impression()
'necesite d'activer la reference Microsoft Word xx.x Object Library
Dim appWrd As Word.Application
Dim docWord As Word.Document
Dim Fichier As String

Fichier = "C:\document\allemand.doc"

Set appWrd = CreateObject("Word.Application") 'creation session Word
appWrd.Visible = False 'pour que word reste masqué pendant l'operation
Set docWord = appWrd.Documents.Open(Fichier)

docWord.PrintOut 'impression

docWord.Close 'fermer le document Word
appWrd.Quit 'fermer la seesionWord

End Sub

 

[ftho]

Re : Imprimer un fichier word avec macro excel

Bonjour,

Une solution éventuelle via Select Case

Sub ouvrirDocWord_Impression()
'necesite d'activer la reference Microsoft Word xx.x Object Library
Dim appWrd As Word.Application
Dim docWord As Word.Document
Dim Fichier As String
Dim Langue As String

Select Case Sheets("Feuil1").Range("A1")
    Case "DE": Langue = "allemand"
    Case "FR": Langue = "français"
    Case "E": Langue = "espagnol"
    'etc...
    Case Else
        MsgBox "aucune langue ne correspond à " & Sheets("Feuil1").Range("A1")
        Exit Sub
End Select

Fichier = "C:\document\" & Langue & ".doc"

Set appWrd = CreateObject("Word.Application") 'creation session Word
appWrd.Visible = False 'pour que word reste masqué pendant l'operation
Set docWord = appWrd.Documents.Open(Fichier)

docWord.PrintOut 'impression

docWord.Close 'fermer le document Word
appWrd.Quit 'fermer la seesionWord

End Sub