Imprimer plusieurs feuilles après sélection

[TINOU]

Bonjour Le Forum,

Je coince et sollicite à nouveau vos précieux conseils.

Je souhaite lancer l'impression de plusieurs feuilles après avoir fait une sélection par l'intermédiaire de cases à cocher. Mais je ne sais pas trop quel code mettre derrière le bouton imprimer.
Merci d'avance de l'aide que vous pourrez m'apporter...🙂

Tinou.

 

[Gorfael]

Re : Imprimer plusieurs feuilles après sélection

Bonjour Le Forum,

Je coince et sollicite à nouveau vos précieux conseils.

Je souhaite lancer l'impression de plusieurs feuilles après avoir fait une sélection par l'intermédiaire de cases à cocher. Mais je ne sais pas trop quel code mettre derrière le bouton imprimer.
Merci d'avance de l'aide que vous pourrez m'apporter...🙂

Tinou.

Salut
Bienvenu au club 😛 . Je sais toujours pas comment redéfinir une Array, en lui ajoutant ou retirant un argument. Mais j'ai un palliatif

Private Sub CommandButton1_Click()
Dim X As Integer
Dim F() As String
ReDim F(0 To 0)
For X = 1 To 4
    If Me.Controls("CheckBox" & X) Then
        ReDim Preserve F(0 To UBound(F) + 1)
        F(UBound(F)) = "DOCUMENT " & X
    End If
Next X
Select Case UBound(F)
    Case 1
        Sheets(F(1)).Select
    Case 2
        Sheets(Array(F(1), F(2))).Select
    Case 3
        Sheets(Array(F(1), F(2), F(3))).Select
    Case 4
        Sheets(Array(F(1), F(2), F(3), F(4))).Select
End Select
ActiveWindow.SelectedSheets.PrintOut
End Sub

Pour faire les essais, je mets PDFCreator en imprimante, c'est plus économique.
Par contre, je ne sais pas imprimer un USF

J'ai envisgé le cas d'une impression unique (pour la numérotation de pages par exemple). Sinon,
tu fais 4 test :

Private Sub CommandButton1_Click()
Dim X As Integer
For X = 1 To 4
    If Me.Controls("CheckBox" & X) Then sheets("DOCUMENT " & X).printout
Next X
End Sub

A+

 

[TINOU]

Re : Imprimer plusieurs feuilles après sélection

Bonsoir Gorfael, Le Forum,


Un grand merci pour ton code, çà marche nickel !!🙂

Comme à chaque fois sur ce forum génial, il y a toujours quelqu'un pour vous dépanner 😉.

Encore merci.

Tinou.

 

[Catrice]

Re : Imprimer plusieurs feuilles après sélection

Bonsoir,

ci joint une variante.

Private Sub CommandButton2_Click()
Dim MaVar()
i = 0
For Each X In UserForm1.Controls
If Left(X.Caption, 8) = "DOCUMENT" Then
If X Then
ReDim Preserve MaVar(i)
MaVar(i) = X.Caption
i = i + 1
End If
End If
Next
If i <> 0 Then
Sheets(MaVar).Select
ActiveWindow.SelectedSheets.PrintOut
End If
End Sub