Imbriquation de SI et ET

[xlsm50]

Bonsoir le forum,
je n'arrive pas à imbriquer mes formules SI et ET :

pour un championnat sportif, je voudrais que quand le score de l'équipe A est compris entre 0 et 5, l'équipe remporte 1 points, entre 6 et 8, ça rapporte 2 points, entre 9 et 11, ça rapporte 5 points, et entre 12 et 16, ça rapporte 6 points;
J'ai essayé la formule ci dessous, mais ça ne fonctionne pas

=SI(ET(B3>=0;ET(B3<6;ET(B3=7)));1;2)

voici le fichier en piece jointe, merci d'avance

 

[JCGL]

Re : Imbriquation de SI et ET

Bonjour à tous,

Peux-tu essayer avec :

=SI(B3="";"";SI(B3>11;6;SI(ET(B3>=9;B3<=11);5;SI(ET(B3>=6;B3<=8);2;1))))

A+ à tous

 

[herve62]

Re : Imbriquation de SI et ET

Bonsoir
Jean-Claude ... tu vas trop vite ,je cherchais mais de toute façon j'avais erreur car il me manquait une ) !!!
pour simplifier nous, en logique electronique au lieu de <=12 on met <13

A+

PS : j'ai un Post en suspend !!!!de finition

 

[poilamonnez]

Re : Imbriquation de SI et ET

Bonsoir le forum JCGL et Xlsm 50

Une autre possibilité si j'ai bien compris

==> =(ET(B3<=5;B3>0)*1)+(ET(B3<=8;B3>5)*2)+(ET(B3<=11;B3>8)*5)+(ET(B3<=16;B3>11)*6)

Cordialement

 

[excfl]

Re : Imbriquation de SI et ET

Bonsoir le forum,

=SI(OU(B3="";B3>16);"***";SI(B3>11;6;SI(B3>8;5;SI(B3>5;2;1))))

excfl

 

[xlsm50]

Re : Imbriquation de SI et ET

Merci à tous, de vos réponses, j'essaierais ça demain et je vous tient au courant

 

[poilamonnez]

Re : Imbriquation de SI et ET

Re)

Allez une autre pour la forme

=INDEX({0;1;2;5;6;0};EQUIV(B3;{0;1;6;9;12;17};1))

@+

 

[xlsm50]

Re : Imbriquation de SI et ET

Bonjour, et merci à tous, toutes les formules que vous me proposez les uns et les autres, fonctionnent toutes comme je le souhaite.,ces formules que vous me proposez, ne seront qu'une petite partie de la formule finale, j'utiliserais donc celle qui sera la plus facilement modifiable (au cas ou) et la plus facilement compréhensible pour moi, et pour les personnes à qui sera destiné le fichier final
merci encore
@+