Formules excel en VBA dans plage variable

[Delux]

Bonjour a tous,
(desole pour les accents, je travaille sur clavier QWERTY)

Cela fait plusieurs jours que je cherche une solution pour inserer une formule dans une plage variable grace a une macro.

Pour exemple, j'ai choisi cette formule :

=CONCATENATE(LEFT($A5, 1), $B5, $C5, MID($D5, 2, 1))

J'ai essaye de la retranscrire dans une macro, mais le code ci-dessous ne fonctionne pas :

Sub Conca()
'
Dim Cell As Range
Dim Lg As Integer

Lg = 5

For Each Cell In Sheet1.Range("A5:D" & [A65489].End(xlUp).Row)
    If Cell.Value <> "" Then

        Sheet1.Range("F" & Cell.Row).Formula = Application.WorksheetFunction.Left(Cells(Lg, 1) & Cells(Lg, 2) & Cells(Lg, 3) & Application.WorksheetFunction.Mid(Cells(Lg, 4), 2, 1))
        
        Lg = Lg + 1
    
    End If
    Next

End Sub

J'ai joint un petit fichier exemple pour plus de precision ^^

Si vous possedez la solution, je suis preneur

Merci beaucoup

Cordialement,

Delux

 

[ERIC S]

Re : Formules excel en VBA dans plage variable

Bonjour

l'enregistreur de macro donne

    ActiveCell.FormulaR1C1 = _
        "=CONCATENATE(LEFT(RC1,1), RC2, RC3, MID(RC4, 2,1))"

 

[Efgé]

Re : Formules excel en VBA dans plage variable

Bonjour Delux, Bonjour ERIC S , Si j'ai bien compris..

Sheet1.Range("F5.F" & [A65489].End(xlUp).Row).Formula = "=CONCATENATE(LEFT($A5, 1), $B5, $C5, MID($D5, 2, 1))"

Cordialement

 

[Delux]

Re : Formules excel en VBA dans plage variable

Bonjour Delux, Bonjour ERIC S , Si j'ai bien compris..

Sheet1.Range("F5.F" & [A65489].End(xlUp).Row).Formula = "=CONCATENATE(LEFT($A5, 1), $B5, $C5, MID($D5, 2, 1))"

Cordialement

Bonjour a tous,

Elge,

Ceci ne fonctionnera que pour la premiere ligne :/
J'aimerais que pour chaque cellules non vide en A:A, la formule prenne les infos de chaque ligne.

Un peu dans ce style:

=CONCATENATE(LEFT(Cells(Lg, 1), 1), Cells(Lg, 2), Cells(Lg, 3), MID(Cells(Lg, 4), 2, 1))

Cordialement,

Delux

 

[ERIC S]

Re : Formules excel en VBA dans plage variable

Re

tu as essayé la proposition d'Efgé?

Moi pas, mais il me semble qu'il remplit la colonne F de la ligne 5 à la ligne de la dernière cellule de A

 

[Efgé]

Re : Formules excel en VBA dans plage variable

Re,

Ceci ne fonctionnera que pour la premiere ligne :/

Si tu le dis, c'est que tu as du tester..... Cordialement EDIT Merci Eric ; )

 

[Efgé]

Re : Formules excel en VBA dans plage variable

Re
Même si Delux semble avoir trouvé une réponse qui lui convient .

Pour strictement répondre à la question d'origine et sur la base du code fourni dans l'exemple:

Sub Conca2()
Dim Cell As Range
For Each Cell In Sheet1.Range("A5:D" & [A65489].End(xlUp).Row)
    If Cell.Value <> "" Then
        Sheet1.Range("F" & Cell.Row).Formula = _
        "=CONCATENATE(LEFT($A" & Cell.Row & ", 1), $B" & Cell.Row & _
        ", $C" & Cell.Row & ", MID($D" & Cell.Row & ", 2, 1))"
    End If
Next
End Sub

Pour le même résultat en "accélérant la manoeuvre":

Sub test()
With Sheet1.Range("A5.A" & [A65489].End(xlUp).Row)
    .Offset(, 5).Formula = "=CONCATENATE(LEFT($A5, 1), $B5, $C5, MID($D5, 2, 1))"
    .SpecialCells(xlCellTypeBlanks).Offset(, 5).ClearContents
End With
End Sub

Voir:

Sub test2()
Sheet1.Range("A5.A" & [A65489].End(xlUp).Row).SpecialCells(xlCellTypeConstants).Offset(, 5).Formula = _
"=CONCATENATE(LEFT($A5, 1), $B5, $C5, MID($D5, 2, 1))"
End Sub

Cordialement