formule

[pigvoy]

Bonjour

Pouvez m'aider sur une formule avec plusieurs conditions...

avec un preference pour une formule car les macros je ni comprend rien..😡

Il y a une piece jointe avec des explications.

un grand Merci

 

[Tibo]

Re : formule

Bonjour,

Pas vraiment sûr d'avoir tout compris.

Un essai avec cette formule en F2 :

=SI($H2="Maximale";DATE(ANNEE($C2)+RECHERCHEV($B2;DECALER(Maxi!$A$1;4;
EQUIV($A2;Maxi!$1:$1;0)-1;15;2);2;0);MOIS($C2);JOUR($C2));SI($H2="Minimale";
DATE(ANNEE($C2)+RECHERCHEV($B2;DECALER(Mini!$A$1;4;EQUIV($A2;Maxi!$1:$1;0)-1;
15;2);2;0);MOIS($C2);JOUR($C2));""))

Si pas ça, reviens avec ton fichier complété manuellement avec plusieurs exemples et les réponses attendues (en rouge par exemple).

A te (re)lire

@+

 

[Brigitte]

Re : formule

Bonjour,

Je m'incruste juste pour m'émerveiller de la formule à rallonges de Tibo... (bisous au passage), j'avais ouvert le fichier et refermé tant la tâche me paraissait dure.

Bravo Tibo.

 

[pigvoy]

Re : formule

Merci pour ta reponse tibo la formule fonctionne presque, tu as tout compris mais (un petit mais) il y a des periodes de 1an et 6mois et la formule prend pas en compte les 6 mois....(desolé)

en piece jointe le fichier avec les bonnes reponses en rouge...

merci encore

 

[gilbert_RGI]

Re : formule

Merci pour ta reponse tibo la formule fonctionne presque, tu as tout compris mais (un petit mais) il y a des periodes de 1an et 6mois et la formule prend pas en compte les 6 mois....(desolé)

en piece jointe le fichier avec les bonnes reponses en rouge...

merci encore

Bonjour

et Bravo Tibo

une solution convertir les tableaux en mois et dans la formule faire l'addition sur les mois et non sur les années

Salutations

Gilbert_RGI

 

[Tibo]

Re : formule

re,

Une autre formule pour tenir compte de ces cas particuliers :

toujours en F2 :

=SI($J2="Maximale";DATE(ANNEE($C2)+RECHERCHEV($B2;DECALER(Maxi!$A$1;4;
EQUIV($A2;Maxi!$1:$1;0)-1;15;2);2;0);MOIS($C2)+MOD(RECHERCHEV($B3;DECALER(
Maxi!$A$1;4;EQUIV($A3;Maxi!$1:$1;0)-1;15;2);2;0);1)*10;JOUR($C2));SI($J2=
"Minimale";DATE(ANNEE($C2)+RECHERCHEV($B2;DECALER(Mini!$A$1;4;EQUIV(
$A2;Maxi!$1:$1;0)-1;15;2);2;0);MOIS($C2)+MOD(RECHERCHEV($B3;DECALER(
Mini!$A$1;4;EQUIV($A3;Mini!$1:$1;0)-1;15;2);2;0);1)*10;JOUR($C2));""))

A tester quand même.

Attention : le fait de mettre les mois sous cette forme : 3,6 pour 3 ans et 6 mois présente un inconvénient majeur : confusion entre 3 ans et 1 mois (3,1) et 3 ans et 10 mois (3,10), valeurs qui sont équivalentes.

Ce n'est peut-être pas un problème pour toi.

@+

 

[JeanMarie]

Re : formule

Bonsoir tout le monde

En plaçant la condition J2 = Maximale/Minimale, différement on diminue la longueur de la formule

=SI(J2="";"";DATE(ANNEE($C2)+RECHERCHEV($B2;DECALER(SI($J2="Maximale";Maxi!$A$1;Mini!$A$1);4;EQUIV($A2;Maxi!$1:$1;0)-1;15;2);2;0);MOIS($C2)+MOD(RECHERCHEV($B2;DECALER(SI($J2="Maximale";Maxi!$A$1;Mini!$A$1);4;EQUIV($A2;Maxi!$1:$1;0)-1;15;2);2;0);1)*10;JOUR($C2)))

Néanmois bravo à Tibo, quel boulot!

@+Jean-Marie

 

[pigvoy]

Re : formule

Excellent !!! ça fonctionne

Un grand merci a TIBO (Belle formule !!!) et Jean Marie.

gilbert_RGI :J'ai essayé ce que tu as dit et ça fonctionne aussi.

Encore merci