Microsoft 365 Formule Somme plage variable

[chris6999]

Bonjour

Je me casse la tête à trouver la formule (pas de macro) pour réaliser la somme d'une plage dont les lignes et colonnes sont définis par des critères variables.
Je dispose des formules pour identifier avec la fonction EQUIV le numéro de ligne, la colonne de départ, la colonne de fin. J'ai même réussi à faire remonter en lettre l'adresse des cellules...mais impossible d'aller plus loin!

Réaliser la somme ligne 7 (reconstituée par la formule EQUIV($Y$26;C:C;0)
Les colonnes de départ et de fin sont reconstituées à partie des dates :
-Première colonne reconstituée par la formule EQUIV(DATEVAL("01/01/"&ANNEE Col Q);$4:$4;0)
-Dernière colonne reconstituée par la formule EQUIV(DATEVAL("01/"&MOIS($Y$1)&"/"&ANNEE Col Q);$4:$4;0)
Pour l'année 2020 on aura donc somme(valeur col 4 ligne 7 : valeur col 4 ligne 7) soit somme(D7:M7)
Pour l'année 2021 on aura donc somme(valeur col 17 ligne 7 : valeur col 26 ligne 7) soit somme(Q7:Z7)…ETC

Je mets un fichier test en PJ où j'ai tout expliqué.
Si qq peut me sortir de ce trou..

Bonne journée à tous

 

[chris]

Bonjour

=SOMME(DECALER($D$4;EQUIV($Y$26;C:C;0)-4;EQUIV(DATE(Q28;1;1);$4:$4;0)-4;;MOIS($Y$1)))

 

[Hasco]

Bonjour,

J'avais :

=SIERREUR(SOMME(DECALER($D$7:$AC$7;0;EQUIV($Q28;$D$4:$AC$4;0)-13;;12));0)

et pour version 365 et + :

=SIERREUR(SOMME(FILTRE($D$7:$AC$7;SIERREUR((ANNEE($D$4:$AC$4)=$Q30)*(MOIS($D$4:$AC$4)<=10);0)));0)

Hello @chris
cordialement

 

[JHA]

Bonjour à tous,

A essayer

=SOMMEPROD((ANNEE($D$4:$AC$4)=$Q28)*(MOIS($D$4:$AC$4)>=1)*(MOIS($D$4:$AC$4)<=MOIS($Y$1));$D$7:$AC$7)

JHA

 

[Hasco]

Re,

Hello @JHA
Tu me fais penser que celle là aussi le fait :

SOMME.SI.ENS($D$7:$AC$7;$D$4:$AC$4;">=1/1/" & $Q28;$D$4:$AC$4;"<=31/10/" &$Q28)

@chris6999 n'aura que l'embarras du choix

Cordialement

 

[JHA]

Bonjour à tous,
Bonjour @ Hasco,

Juste une petite modification car on s'arrête en Octobre.

=SOMME.SI.ENS($D$7:$AC$7;$D$4:$AC$4;">=1/1/" & $Q28;$D$4:$AC$4;"<=31/10/" &$Q28)

JHA

 

[Hasco]

Re @JHA

Tu as raison, j'avais zappé la limite de mois dans mes formules.
C'est corrigé dans mon premier post.

Cordialement

 

[chris6999]

Bonjour

De retour après quelques soucis de connexion.
Merci encore pour vos différentes réponses. Je vais tester vos propositions afin de voir ce qui fonctionne le mieux

Bonne journée