Formule pour reproduire fonction "convertir > délimité"

grimat · 17 Octobre 2013

J'ai des cellules avec des textes séparés par un caractère commun : -
je souhaite une formule pour séparer chaque groupe de texte entouré ainsi

ex :
j'ai :
toto rara - golfy yuti
bh - yar tur

je voudrais :
cellule A1 : toto rara
cellule A2 golfy yuti
cellule b1 bh
cellule B2 yar tur

Je sais que je peux faire cela avec le menu données > convertir - mais j'ai besoin d'une formule (et non du vba) car je dois automatiser le calcul pour une utilisation au quotidien.

merci

grenadine · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

Bonjour Grimat,

Si ton mot est en A1
Voilà la formule que j'ai trouvépour la partie "toto rara"
=GAUCHE(A1;NBCAR(STXT(A1;1;TROUVE("-";A1;1)-1)))

Pour la partie golfy yuti
=DROITE(A1;NBCAR(B3)-NBCAR(STXT(A1;1;TROUVE("-";A1;1))))

Après il y a peut être plus simple mais ça marche.

grena

R@chid · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

Bonjour @ tous,
En D3,

Code:

=SUPPRESPACE(GAUCHE(B3;TROUVE("-";B3)-1))

En E3,

Code:

=SUPPRESPACE(STXT(B3;TROUVE("-";B3)+1;99))

@ tirer vers le bas
@ + +

titiborregan5 · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

bonjour grimat, re grenadine (décidément),

effectivement il y plus simple et en natif dans excel:

Tu sélectionnes tes données, ensuite tu vas dans Données/Convertir, délimité et tu mets le tiret comme délimiteur puis terminer...
ça te scinde en 2 colonnes (ou plus s'il y a plus de -) au niveau des tirets...
Attention toutefois, il faut que les colonnes à droite soient disponibles sinon ça les écrase...

R@chid · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

Re,
Salut titiborregan5 ,

Je sais que je peux faire cela avec le menu données > convertir - mais j'ai besoin d'une formule (et non du vba) car je dois automatiser le calcul pour une utilisation au quotidien.

@ + +

grenadine · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

Re,

titiborregan5: j'attend une réponse à mon problème alors je fait ce que je peux pour aider les autre.

Grimat: sinon tu peux enregistrer une macro.
Macro --> enregistrer une macro --> tu fait t'a manip de délimiteur, tu peux même rajouter d'autre critère de mise en page --> Macro --> arrêter l'enregistrement.
Et avec une petite touche raccourcis tu peux appliquer ta mise en forme sur tous tes fichiers, tous les jours.
C'est ce que nous faisons au quotidien avec ma collègue, ça nous à changer la vie!

grimat · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

R@chid à dit:
Bonjour @ tous,
En D3,

Code:

=SUPPRESPACE(GAUCHE(B3;TROUVE("-";B3)-1))

En E3,

Code:

=SUPPRESPACE(STXT(B3;TROUVE("-";B3)+1;99))

@ tirer vers le bas
@ + +

Merci à tous et surtout r@chid pour cette fabuleuse formule !! ca marche top !!

J'ai parfois des cellules avec 3 tirets, ca serait trop demander de me donner la formule à mettre dans la 3e colone ?

MERCI !!!

R@chid · 17 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

Re,

En D3,

Code:

=SUPPRESPACE(GAUCHE(B3;TROUVE("-";B3)-1))

En E3,

Code:

=SUPPRESPACE(STXT(B3;TROUVE("-";B3)+1;TROUVE("*";SUBSTITUE(B3&"-";"-";"*";2))-TROUVE("-";B3)-1))

En F3,

Code:

=SI(NBCAR(B3)-NBCAR(SUBSTITUE(B3;"-";))=2;SUPPRESPACE(STXT(B3;TROUVE("*";SUBSTITUE(B3;"-";"*";2))+1;99));"")

@ + +

titiborregan5 · 18 Octobre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

grimat à dit:
Je sais que je peux faire cela avec le menu données > convertir - mais j'ai besoin d'une formule (et non du vba) car je dois automatiser le calcul pour une utilisation au quotidien.

J'ai lu trop vite, je n'avais même pas supputé l'existe de cette petite phrase qui change tout au problème.

Désolé du "hors sujet" donc!

A+

grimat · 3 Décembre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

@rachid : ca marche très bien effet, mon besoin a évolué, mon expression de base (en B3) comporte parfois 1, 2, 3, 4, 5 ou 6 tirets et même parfois plus.

Ta formule fonctionne avec 3 tirets, en revanche quand j'en ai plus, les cellules E3 et F3 sont vides.

voici l'ensemple de ce que je voudrais (désolé, j'ai l'impression d'être hyper exigeant !!!) :

B3 : 1aa - 2bb - 3cc ff - 4dd ee - 5ee zz

formule de calcul pour avoir en :
D3 : 1aa =>OK
E3 : 2bb
F3 : 3cc ff - 4dd ee - 5ee zz

MERCI D AVANCE

R@chid à dit:

Re,

En D3,

Code:

=SUPPRESPACE(GAUCHE(B3;TROUVE("-";B3)-1))

En E3,

Code:

=SUPPRESPACE(STXT(B3;TROUVE("-";B3)+1;TROUVE("*";SUBSTITUE(B3&"-";"-";"*";2))-TROUVE("-";B3)-1))

En F3,

Code:

=SI(NBCAR(B3)-NBCAR(SUBSTITUE(B3;"-";))=2;SUPPRESPACE(STXT(B3;TROUVE("*";SUBSTITUE(B3;"-";"*";2))+1;99));"")

@ + +

david84 · 3 Décembre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

Bonsoir,
à tester :

Code:

=SI(COLONNES($A:A)<NBCAR(SUBSTITUE(" - "&$A1&" - ";" - ";"/"))-NBCAR(SUBSTITUE(" - "&$A1&" - ";" - ";""));STXT(SUBSTITUE(" - "&$A1&" - ";" - ";"/";COLONNES($A:A));CHERCHE("/";SUBSTITUE(" - "&$A1&" - ";" - ";"/";COLONNES($A:A)))+1;CHERCHE("/";SUBSTITUE(" - "&$A1&" - ";" - ";"/";COLONNES($A:B)))-CHERCHE("/";SUBSTITUE(" - "&$A1&" - ";" - ";"/";COLONNES($A:A)))-3);"")

A+

grimat · 5 Décembre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

top merci !

seul petit hic, quand il y a un grand nombre de tirets, la fin n'apparait pas dans la dernière cellule

david84 · 5 Décembre 2013

Re : Formule pour reproduire fonction "convertir > délimité"

grimat à dit:
top merci !

seul petit hic, quand il y a un grand nombre de tirets, la fin n'apparait pas dans la dernière cellule

Je ne vois pas pourquoi cela ne fonctionnerait pas avec un plus grand nombre de tirets...quelle est la chaîne à tester ?
A+

Lau79 · 30 Juin 2022

Bonjour à tous,
nouvellement arrivée dans le groupe je retrouve cet historique d'échanges qui répond quasiment à mon casse-tête.
Je dois automatiser un rapport graphique excel à partir d'un export de données. Une colonne de cet export liste des éléments. Chaque cellule a plusieurs éléments séparés par des sauts de ligne. Je dois automatiser le fait que chaque élément doit se retrouver dans une colonne. Je ne parviens malheureusement pas à convertir automatiquement par une formule les éléments listés dans la cellule en éléments séparés.
Merci pour votre aide

Deadpool_CC · 30 Juin 2022

Bonjour,

ben non ... pas sur un sujet de 2013.supprime ton post est fait ta propre question/demande d'aide

Formule pour reproduire fonction "convertir > délimité"

grimat

XLDnaute Occasionnel

Pièces jointes

grenadine

XLDnaute Nouveau

Pièces jointes

R@chid

XLDnaute Barbatruc

titiborregan5

XLDnaute Accro

R@chid

XLDnaute Barbatruc

grenadine

XLDnaute Nouveau

grimat

XLDnaute Occasionnel

Pièces jointes

R@chid

XLDnaute Barbatruc

titiborregan5

XLDnaute Accro

grimat

XLDnaute Occasionnel

david84

XLDnaute Barbatruc

Pièces jointes

grimat

XLDnaute Occasionnel

david84

XLDnaute Barbatruc

Lau79

XLDnaute Nouveau

Pièces jointes

Deadpool_CC

XLDnaute Accro

Discussions similaires