XL 2016 formule pour compter nombre valeurs différentes d'une plage

[coucoud]

Bonjour, je cherche pour trouver la formule qui me permet de trouver le nombre de valeurs différentes d'une colonne.

La formule utilisée dans mon tableau fonctionne uniquement si il y a une valeur dans la plage de données.
Si une cellule est vide dans la même plage, le résultat #DIV/0! s'affiche

Merci d'avance de votre aide

​

 

[sylvanu]

Bonjour Coucoud,
Essayez :

=SOMME(SI(FREQUENCE(C3:C10;C3:C10)>0;1))

 

[JHA]

Bonjour à tous,

Si tu as des données "texte", tu peux utiliser cette matricielle

=SOMME(SI(FREQUENCE(SI($C$3:$C$10<>"";EQUIV($C$3:$C$10;$C$3:$C$10;0));LIGNE($C$3:$C$10)-LIGNE($C$2));1))

JHA

 

[ALS35]

Bonjour à tous,
On peut aussi faire sans validation matricielle que ce soit sur des données texte ou nombre :

=SOMMEPROD(SIERREUR(1/NB.SI(E3:E10;E3:E10);""))

Cordialement

 

[JHA]

Bonjour à tous,

Ne possédant pas la version 365, il me faut valider la formule de @ALS35 (qui donne le bon résultat également) par les 3 touches malgré le sommeprod

=SOMME(SIERREUR(1/NB.SI(C3:C10;C3:C10);""))

JHA

 

[ALS35]

Re,
Bien vu @JHA, l'ajout du SIERREUR impose la validation matricielle par Ctrl+Maj+Entrée.
Avec 365 la vie est plus simple et on oublie toutes ces vérifications.
Cordialement

 

[R@chid]

Bonjour @ tous,

ALS35, ta formule est matricielle avec ou sans SIERREUR(), mais sous Excel pour Microsoft 365 la validation matricielle n'est plus indispensable.
En plus, sur une grande plage de données, ta formule renverra un faux résultat (avec des virgules), ce qui n'est pas le cas sur la formule de notre cher ami JHA.
On peut réécrire la formule de JHA :

=NB(1/FREQUENCE(SI(C3:C10<>"";EQUIV(C3:C10;C3:C10;0));LIGNE(INDIRECT("1:"&LIGNES(C3:C10)))))

@ valider par Ctrl+Maj+Entree
L'utilisation de la fonction EQUIV() est indispensable si les valeurs ne sont pas numériques.


Bien cordialement

 

[ALS35]

Bonjour à tous,

@R@chid

ALS35, ta formule est matricielle avec ou sans SIERREUR(), mais sous Excel pour Microsoft 365 la validation matricielle n'est plus indispensable.

Diantre, aurais-je dit le contraire ??

En plus, sur une grande plage de données, ta formule renverra un faux résultat (avec des virgules), ce qui n'est pas le cas sur la formule de notre cher ami JHA.

Intéressant, mais peux-tu préciser ton propos, parce que sans exemple ... (enfin si les temps de calculs ne sont pas trop prohibitifs)
Cordialement

 

[mapomme]

Surtout pour vous saluer tous 🙂,

=SOMMEPROD(--SIERREUR(EQUIV(C3:C10;C3:C10;0)=LIGNE(C3:C10)-LIGNE(C$3)+1;0))