formule non reconnue par excel

[criscris11]

Bonjour à tous,
J'ai cette formule : =SI(AD3="";"NON OBSERVE";SI(AD3="EXEMPT";"EXEMPT";SI(ESTNUM(AD3);INDEX(DECALER(INDIRECT(AD$2);(DATEDIF($G3;AC3;"y")>=36)*6;($F3="F")*4);EQUIV(AD3;DECALER(INDIRECT(AD$2);(DATEDIF($G3;AC3;"y")>=36)*6;($F3="F")*4;;1));3);"")))

que je veux modifier comme suit : =SI(AD3="";"NON OBSERVE";SI(AD3="EXEMPT";"EXEMPT";SI(ESTNUM(AD3);INDEX(DECALER(INDIRECT(AD$2);(DATEDIF($G3;DATE(ANNEE(AC3)+1;3;0);"y")>=36)*6;($F3="F")*4);EQUIV(AD3;DECALER(INDIRECT(AD$2);(DATEDIF($G3;DATE(ANNEE(AC3)+1;3;0);"y")>=36)*6;($F3="F")*4;;1));3);"")))

mais impossible à valider car excel décèle une erreur à cette endroit là :
(DATEDIF($G3;DATE(ANNEE(AC3)+1;3;0);"y")>=36)*6;($F3="F")*4;;1));3);""))) en surlignant ANNEE.
Où est mon erreur, je suis ûr que c'est encore un truc à deux balles (plutôt euros mais cà revient cher la question) ?
S'il le faut je peux poster le fichier en question.
Bon muguet à toutes et à tous.

 

[Monique]

Re : formule non reconnue par excel

Bonjour,

En concaténant les résultats des 3 fonctions "Si()"
=SI(AD3="";"NON OBSERVE";"")&SI(AD3="EXEMPT";"EXEMPT";"")&SI(ESTNUM(AD3);INDEX(DECALER(INDIRECT(AD$2);(DATEDIF($G3;DATE(ANNEE(AC3)+1;3;0);"y")>=36)*6;($F3="F")*4);EQUIV(AD3;DECALER(INDIRECT(AD$2);(DATEDIF($G3;DATE(ANNEE(AC3)+1;3;0);"y")>=36)*6;($F3="F")*4;;1));3);"")

Pourquoi ? Je n'en sais rien

On peut enlever le 0 ici mais en gardant le point-virgule :
DATE(ANNEE(AC3)+1;3;0)

On peut enlever le "" ici mais en gardant le point-virgule :
=SI(AD3="";"NON OBSERVE";"")

 

[Tibo]

Re : formule non reconnue par excel

Bonjour,

Bravo à Monique pour avoir apporté une réponse sans avoir le fichier.

Sinon, la cause de ton problème réside très certainement dans la limite des 7 niveaux d'imbrication de fonctions (7 niveaux maxi de parenthèses).

Bon 1er mai

@+

 

[Monique]

Re : formule non reconnue par excel

Tibo, bonjour,

La formule me disait quelque chose,
j'avais le fichier, tout simplement.

 

[criscris11]

Re : formule non reconnue par excel

Bonjour Tibo, Monique,
Merci tout d'abord à Monique pour ta réactivité.
Tibo, tu cites : "la cause de ton problème réside très certainement dans la limite des 7 niveaux d'imbrication de fonctions (7 niveaux maxi de parenthèses)" mais je n'en compte pas 7 ou à moins qu'il y en a que je ne saisis pas.
Bon, je vais me mettre au boulot pour pouvoir rendre compte (désolé déformation professionnelle) à Monique tout en sachant qu'il n'y aura pas de suspens car elle garde tout les fichiers sur lesquels elle travaille (d'ailleurs je crois qu'elle va bientôt pouvoir écrire un mémoire avec mes seules demandes).
Allez bon après-midi à tous les deux et à tout de suite.
Amicalement.

 

[criscris11]

Re : formule non reconnue par excel

Voilà, le suspens est levé : dans le mille encore une fois Monique.
Merci et bonne fin de journée.