Pour la mise en forme de ton tableau, je te propose différentes petites choses ci-dessous.
Je te propose de mettre en cellule AJ6 la formule suivante :
=SIERREUR(SI(JOUR(AI$6+1)=1;"";AI$6+1);"")
En suite, copier la cellule AJ6, puis la coller en AK6 et AL6.
Ainsi ça marchera aussi pour le mois de février, qu'il comporte 28 ou 29 jours.
Bien sûr, en AJ7 tu mets la formule suivante :
=SIERREUR(JOUR(AJ$6);"")
à copier, puis coller en AK7 et AL7.
Et en AJ8 tu mets la formule suivante :
=SIERREUR(CHOISIR(JOURSEM(AJ$6);"D";"L";"M";"M";"J";"V";"S");"")
à copier, puis coller en AK8 et AL8.
Je te propose également de changer la formule de la cellule H9 comme ceci :
="S "&NO.SEMAINE(H$6;21)
Ainsi tu auras toujours le numéro de semaine du premier jour du mois, que ce soit un lundi ou pas.
Tu sembles utiliser la convention selon laquelle une semaine commence le lundi et non le dimanche, donc il faut ajouter un paramètre à la fonction "NO.SEMAINE".
Ce paramètre peut dans ce cas être soit 2, soit 11, soit 21.
Je ne sais pas la différence qu'il y a entre 2 et 11, mais perso je préfère 21 qui évite d'avoir deux semaines n° 1 en début d'année...
En effet, avec la valeur 21 le premier jour de l'année peut alors faire partie de la 51ème ou 52ème semaine de l'année précédente. Alors que si tu utilises la valeur 2, le premier jour de l'année peut faire réellement partie de la 52ème semaine de l'année mais afficher qu'il fait partie de la première semaine...
Essaye avec le mois de janvier 2017, tu comprendras tout de suite.
Si ça te convient, tu peux modifier la formule en cellule I9 :
=SI(I$8="L";"S "&NO.SEMAINE(I$6;21);"")
à copier et coller de J9 à AL9.
Une fois que tu as fais ça, si tu affiches le mois de février 2017, tu dois avoir les trois dernières colonnes qui apparaissent toujours mais qui sont vides.
Je te propose donc d'essayer un truc.
Va sur la cellule AJ6 et ajoute une MFC comme ceci :
- formule de la MFC :
=AJ$6=""
- Format : dans l'onglet "Bordure", clique (deux fois s'il le faut) sur la bordure du haut pour qu'elle disparaisse, et fais de même pour la bordure du bas et celle de droite
- s'applique à :
=$AJ$6:$AL$55
Tu valides tout ça et ça doit être bon : les colonnes vides de fin de tableau doivent avoir "disparu".
Si en plus tu vas dans l'onglet "Affichage" et que tu décoches "Quadrillage", ça doit être encore plus joli.
Si cette "clarification" du mois par "disparition" des colonnes superflues t'as plu, je te propose d'utiliser le même principe pour mieux mettre en valeur les séparations entre les semaines.
Va sur la cellule I9 (et non pas H9) et ajoute une MFC comme ceci :
- Formule :
=ET(I$8<>"";I$8<>"L")
- Format : dans l'onglet "Bordure", clique (deux fois s'il le faut) sur la bordure de gauche pour qu'elle disparaisse, mais ne touche surtout aux autres bordures.
- s'applique à :
=$I$9:$AL$9
Tu valides tout ça et tu dois alors mieux voir les semaines.