Formule matricielle >vs< Format Date

[TheLio]

Hello tous,
En utilisant la formule matricielle suivante, pour une liste sans doublons, Excel ne reconnait pas le format de date,

=INDEX(COL_DATE;MIN(SI((NOM_DATE<>0)*(NB.SI($E$2:E2;NOM_DATE)=0);LIGNE(NOM_DATE))))&""

Quelqu'un aurait'il une idée pour contourner le phénomène?
Merci d'avance
A++
Lionel

 

[gilbert_RGI]

Re : Formule matricielle >vs< Format Date

Hello tous,
En utilisant la formule matricielle suivante, pour une liste sans doublons, Excel ne reconnait pas le format de date,

=INDEX(COL_DATE;MIN(SI((NOM_DATE<>0)*(NB.SI($E$2:E2;NOM_DATE)=0);LIGNE(NOM_DATE))))&""

Quelqu'un aurait'il une idée pour contourner le phénomène?
Merci d'avance
A++
Lionel

Bonjour

L'ideal serait un petit fichier en pièce jointe. Si l'original est trop lourd ou confidentiel, un petit copier/coller de quelques données dans le même environnement que le fichier d'origine serait le bienvenu
Cdlt

RGI

 

[TheLio]

Re : Formule matricielle >vs< Format Date

Hello,
Ca se passe sur l'onglet Liste Colonnes F
En attendant, j'ai trouvé une parade en récupérant les données et la fonction texte dans la colonne H
Mais la solutuion ne me plait pas trop 😉
A++
Lionel

 

[gilbert_RGI]

Re : Formule matricielle >vs< Format Date

voilà le retour de fichier
je n'ai fait que la première cellule

 

[gilbert_RGI]

Re : Formule matricielle >vs< Format Date

😱oups j'avais pas vu qu vous aviez déjà utilisé la fonction texte
je l'ai simplement ajouté à la matricielle 😱

 

[TheLio]

Re : Formule matricielle >vs< Format Date

Hello, Merci pour ta soluce, j'avais testé comme ça, mais en étirant je n'ai pas la fonction sans doublons de la matricielle...
A++
TheLio

 

[nouv]

Re : Formule matricielle >vs< Format Date

bonjour,

en ajoutant cnum(), mais il faut en plus rajouter une condition sinon ça marque valeur pour le doublon.

=SI(ESTERR(CNUM(INDEX(COL_DATE;MIN(SI((NOM_DATE<>0)*(NB.SI($F$2:F3;NOM_DATE)=0);LIGNE(NOM_DATE))))&""));"";CNUM(INDEX(COL_DATE;MIN(SI((NOM_DATE<>0)*(NB.SI($F$2:F3;NOM_DATE)=0);LIGNE(NOM_DATE))))&""))

><>

 

[JeanMarie]

Re : Formule matricielle >vs< Format Date

Bonsoir

Dans la formule matricielle de ton fichier, la fin de la formule (&"") permet de ne pas afficher une valeur à zéro, mais a aussi l'inconvénient de transformer la valeur retournée en alphanumérique.

Pour résoudre ton problème. Il faut déjà modifier la formule de la plage Nom_Date

=DECALER(Saisie!$A$2;;;NBVAL(Saisie!$A:$A))

Supprimer dans la formule matricielle la fin. Tu peux aussi supprimer la plage nommée Col_Date, c'est inutile de définir la plage, tu peux indiquer une colonne entière dans la fonction index.

=INDEX(Saisie!A:A;MIN(SI((NOM_DATE<>0)*(NB.SI($F$2:F2;NOM_DATE)=0);LIGNE(NOM_DATE))))

Ensuite tu vas avoir un problème à résoudre, c'est le retour d'une valeur à 0. Pour ce faire je te propose d'utiliser un format de cellule personnalisé.
[=0]"";jj/mm/aa

Pour ce qui est de la colonne qui se trouve à droite, utilise le format jjjj mmmm aaaa, cela évite de charger en calcul tes feuilles.

@+Jean-Marie

 

[TheLio]

Re : Formule matricielle >vs< Format Date

Hello tous,
Une fois de plus, ce forum extraordinaire fréquenté par des personnes du même acabit, m'a aidé à résoudre une formule qui prenait la forme d'une impasse à mes yeux.
Donc merci JeanMarie, merci tous et Longue Vie à XLD. 😉A++
TheLio