Formule introuvable - Besoin d'aide

[chrystou]

Bonjour à toutes et tous,

Dans la colonne A j'ai enregistré mes patients, en B, la date de leur RDV, en C, s'ils se sont présentés au RDV j'ai inscris un "X" et en D, le professionnel rencontré.

En C1, mes 10 patients ont eu 10 RDV, mais le chiffre que je souhaite trouvé est le 6.

Lorsqu'un MEME patient est présent PLUSIEURS FOIS DANS LA MEME JOURNEE, je voudrai qu'une seule présence soit comptée.

Soit X toujours = 1 sauf si même patient est présent plusieurs fois dans la même journée.

Un grand merci à vous.

 

[JCGL]

Re : Formule introuvable - Besoin d'aide

Bonjour à tous,

Peux-tu essayer :

=SOMMEPROD((1/NB.SI($A$3:$A$12;$A$3:$A$12)))

A+ à tous

 

[Paf]

Re : Formule introuvable - Besoin d'aide

Bonjour chrystou, JCGL


une autre proposition

en E3 : =SOMMEPROD(($A$3:$A$12=A3)*($C$3:$C$12="X")*($B$3:$B$12=B3))

A+

Edit Ah ben non!

Mal lu la question et donc réponse à coté !

 

[grisan29]

Re : Formule introuvable - Besoin d'aide

bonsoir chrystou, Paf ,JCGL et le forum

le temps que je recherche un post Paf et JCGL ont déja répondu bon voici donc un post qui peut intéresser notre ami car il traite un peu du même sujet
https://www.excel-downloads.com/threads/remplacer-calendrier-existant.232089/

chrystou tu peut ouvrir les 2 classeurs présents et tu dira ce que tu en pense

Pascal

 

[job75]

Re : Formule introuvable - Besoin d'aide

Bonjour christou, salut les amis,

En C1 :

=SOMMEPROD((A3:A1201<>"")*(EQUIV(A3:A1201&B3:B1201;A3:A1201&B3:B1201;0)=LIGNE(A3:A1201)-2))

A+

 

[BOISGONTIER]

Re : Formule introuvable - Besoin d'aide

Bonsoir,

=NB(1/FREQUENCE(SI(présent="x";EQUIV(patient;patient;0));LIGNE(INDIRECT("1:"&LIGNES(patient)))))
Valider avec maj+ctrl+entrée

Accepte les lignes vides

JB

 

[job75]

Re : Formule introuvable - Besoin d'aide

Re,

Ah j'oubliais les "X" donc utiliser :

=SOMMEPROD((EQUIV(A3:A1201&B3:B1201;A3:A1201&B3:B1201;0)=LIGNE(A3:A1201)-2)*(C3:C1201="X"))

A+

 

[chrystou]

Re : Formule introuvable - Besoin d'aide

Bonjour,

Merci pour toutes ses réponses, elles sont très appréciées.

Si à l'inverse, j'ai un MEME patient qui rencontre le pédiatre tous les jours pendant un mois, je met un X dans la case des présences, cependant je souhaite qu'il me compte 1 fois car c'Est le même patient, quelle est la formule.

MERCI

 

[job75]

Re : Formule introuvable - Besoin d'aide

Re,

Formule matricielle à valider par Ctrl+Maj+Entrée :

=SOMME((EQUIV(A3:A1201&ANNEE(B3:B1201)&MOIS(B3:B1201)&D3:D1201;A3:A1201&ANNEE(B3:B1201)&MOIS(B3:B1201)&D3:D1201;0)=LIGNE(A3:A1201)-2)*(C3:C1201="X"))

Bonne fin de soirée.

 

[job75]

Re : Formule introuvable - Besoin d'aide

Bonjour chrystou, le forum,

Il faut faire attention avec le fichier du post #1.

En effet les dates en colonne B ne sont pas de vraies dates mais des textes.

Si l'on revalide par exemple B3 le texte sera converti en nombre et la formule du post #7 ne renverra pas le bon résultat.

Il n'y a pas ce problème avec la formule du post #9 parce que les fonctions ANNEE et MOIS font la conversion.

Bonne journée.

 

[job75]

Re : Formule introuvable - Besoin d'aide

Re,

Un autre point intéressant à signaler.

Chez moi (Excel 2013) la formule du post #9 ne fonctionne pas avec SOMMEPROD et la validation normale.

J'avoue ne pas comprendre pourquoi.

A+

 

[chrystou]

Re : Formule introuvable - Besoin d'aide

Bonjour Job75,

La formule du poste #9 ne fonctionne pas !

Une autre idée !

Merci

 

[job75]

Re : Formule introuvable - Besoin d'aide

Re,

La formule du poste #9 ne fonctionne pas !

Si le résultat (10) de la formule du post #9 ne vous convient pas il faut nous dire pourquoi.

J'espère au moins que vous savez faire une validation matricielle.

Je joins votre fichier avec la formule.

A+

 

[13GIBE59]

Re : Formule introuvable - Besoin d'aide

Bonjour tout le monde,

Job, je pense que chrystou veut obtenir 6, soit le total des patients ayant consulté (a-b-c-d-e-f).
En revanche, ta formule du post 7 fonctionne bien !

 

[job75]

Re : Formule introuvable - Besoin d'aide

Bonjour 13GIBE59,

Non, 6 c'est la formule du post #7.

Ensuite il y a eu d'autres hypothèses :

Si à l'inverse, j'ai un MEME patient qui rencontre le pédiatre tous les jours pendant un mois, je met un X dans la case des présences, cependant je souhaite qu'il me compte 1 fois car c'Est le même patient, quelle est la formule.

A+