formule derniere ligne/colonne

[C@thy]

Bonsoir le forum,

j'ai fait des recherches sur le forum, mais je n'ai pas (su?) trouvé(er) la réponse à ma question :

comment trouver le n° de la dernière ligne ou colonne remplie par formule
(voir fichier joint)

Merci à vous si vous avez quelques idées sur la question et bonne soirée

Bises

C@thy

 

[hoerwind]

Re : formule derniere ligne/colonne

Bonjour C@thy,

D6 : =EQUIV(RECHERCHE("zzz";A1:Z1);A1:Z1)
D7 : =EQUIV(RECHERCHE("zzz";A1:A20);A1:A20)
D8 : =EQUIV(RECHERCHE(9^9;B1:B20);B1:B20)

Si tu ne sais pas d'avance si la dernière valeur est numérique ou alphabétique, il y a une formule de Monique (matricielle si mes souvenirs sont bons) qui permet de renvoyer les deux valeurs.

 

[hoerwind]

Re : formule derniere ligne/colonne

Re,

Si tu ne retrouves pas la formule de Monique, en voici une matricielle qui pourra faire l'affaire (pas de différence entre les valeurs numériques et alphabétiques) :
=EQUIV(INDEX(A1:A10;MAX((A1:A10<>"")*LIGNE(A1:A10)));A1:A10)
étire la vers la droite et tu verras qu'elle fonctionne (pour la colonne B)

 

[C@thy]

Re : formule derniere ligne/colonne

Wunderbach!!!!! (je ne sais pas comment tu dis ça en flammand!!)

Mille mercis, je te dois encore une Duvel.

Bisous bisous et bonne soirée

C@thy

 

[hoerwind]

Re : formule derniere ligne/colonne

Re,

En flamand : wonderbaar.
Mais il ne faut pas exagérer, ce n'était pas compliqué ! (= maar je moet niet overdrijven, het was niet ingewikkeld !)

 

[Monique]

Re : formule derniere ligne/colonne

Bonjour,

Si on n'a pas besoin de prendre en compte les lignes et colonnes entières :

=MAX(SI(A1:Z1<>"";COLONNE(A1:Z1)))

=MAX(SI(A1:A20<>"";LIGNE(A1:A20)))

=MAX(SI(B1:B20<>"";LIGNE(B1:B20)))

Sinon :

=MAX(SI(ESTNUM(EQUIV(9^9;$1:$1));EQUIV(9^9;$1:$1));SI(ESTNUM(EQUIV("zz";$1:$1));EQUIV("zz";$1:$1)))

=MAX(SI(ESTNUM(EQUIV(9^9;A:A));EQUIV(9^9;A:A));SI(ESTNUM(EQUIV("zz";A:A));EQUIV("zz";A:A)))

=MAX(SI(ESTNUM(EQUIV(9^9;B:B));EQUIV(9^9;B:B));SI(ESTNUM(EQUIV("zz";B:B));EQUIV("zz";B:B)))

Toutes en matriciel

 

[C@thy]

Re : formule derniere ligne/colonne

Eh ben voilà!

Ici on a une leçon d'Excel et de néerlandais, et tout ça pour le même prix!

Un grand merci, Monique, quel plaisir de te revoir parmi nous, tu te fais si rare

dank je wel (je te remercie) hoerwind, (qu'on traduit par les hauts de hurlevent??? 🙂),
trugarez (pas sûre de moi sur ce coup-là, mais Monique ne parle pas le breton), Monique.

J'engrange ces super formules dans mon grenier, ça me tiendra chaud l'hiver.

Mille mercis à vous deux, c'est toujours une joie de vous croiser sur des fils ou en direct, comme il y a peu avec Monique.

Bonne journée😎

C@thy