Format de cellule personnalisé

[big_cham]

Bonjour,

Je récupère via un outil des valeurs que je traite dans excel. Malheureusement, ces valeurs sont dans un format qui ne me permettent pas de faire des opérations mathématiques dessus.
Par exemple, elles ont le format : 8 525 XO ou 123 XO.

Pourriez vous m'indiquer la marche à suivre (mis à part la suppression des espaces et de XO) pour faire mes opérations ?

D'avance merci.

 

[abcd]

Re : Format de cellule personnalisé

Bonjour,

En remplaçant dans la formule la référence de la cellule par :
=GAUCHE(SUPPRESPACE(A1);NBCAR(A1)-2)*1

abcd

 

[Tibo]

Re : Format de cellule personnalisé

Bonjour big cham,

Tout dépend du type d'opération que tu souhaites faire sur ta liste.

S'il s'agit d'additionner les valeurs numériques en faisant abstraction du " XO", un essai avec cette formule matricielle :

=SOMME(SI(SUBSTITUE(A1:A20;" XO";"")<>"";SUBSTITUE(A1:A20;" XO";"")*1))

Formule à valider par CTRL + MAJ + ENTREE

Si pas ça, reviens avec plus de détails : un petit fichier par exemple.

Bon app

@+

Edit : Bing ! salut abcd

@+

 

[JCGL]

Re : Format de cellule personnalisé

Bonjour à tous,

Tes valeurs en A, mettre en B :

=GAUCHE(A1;TROUVE("X";A1;1)-1)*1

et tirer vers le bas

Avec ce que j'ai compris

A+

Edition Salut ABCD, Salut Tibo

 

[big_cham]

Re : Format de cellule personnalisé

Les deux formules fonctionnent, mais j'ai du mal à comprendre le rôle de nbcar et ce qui va derrière...

Je ne parle pas du substitue...😱

Vous pourriez me décortiquer vos formules ?🙄

 

[big_cham]

Re : Format de cellule personnalisé

Bon, je vous joins une copie de mon classeur.
Il est composé de 3 onglets "jour1" "jour2" "variation"

En fait, je ne vois pas comment appliquer vos formules sur une cellule calculée. Par exemple dans l'onglet Evolution et dans jour2...

 

[abcd]

Re : Format de cellule personnalisé

Re,

Evolution!C2 : =SUBSTITUE(RECHERCHEV(A2;Jour1!$A$2:$B$10;2;FAUX);"XO";"")*1
Evolution!D2 : =SUBSTITUE(RECHERCHEV(A2;Jour2!$A$2:$B$10;2;FAUX);"XO";"")*1

Ou sans modifier C2 et D2 :
Evolution!E2 : =SUBSTITUE(C2;"XO";"")-SUBSTITUE(D2;"XO";"")

abcd

 

[big_cham]

Re : Format de cellule personnalisé

Re,

Evolution!C2 : =SUBSTITUE(RECHERCHEV(A2;Jour1!$A$2:$B$10;2;FAUX);"XO";"")*1
Evolution!D2 : =SUBSTITUE(RECHERCHEV(A2;Jour2!$A$2:$B$10;2;FAUX);"XO";"")*1

Ou sans modifier C2 et D2 :
Evolution!E2 : =SUBSTITUE(C2;"XO";"")-SUBSTITUE(D2;"XO";"")

abcd

Ok pour la feuille variation. Mais comment voyez-vous l'onglet jour2 et sa colonne, qui permet de faire une évolution par rapport au jour précédent ?
Pour rappel la formule est :

=SI(ESTNA(EQUIV(A2;Jour1!$A$2:$A$35;0));"nonprésentmois1";B2-INDEX(Jour1!$B$2:$B$10;EQUIV(A2;Jour1!$A$2:$A$35;0)))

 

[abcd]

Re : Format de cellule personnalisé

Re,

Toujours de la même façon :
Jour2!C2 :
=SI(ESTNA(EQUIV(A2;Jour1!$A$2:$A$35;0));"nonprésentmois1";SUBSTITUE(B2;"XO";"")-INDEX(SUBSTITUE(Jour1!$B$2:$B$10;"XO";"");EQUIV(A2;Jour1!$A$2:$A$35;0)))

ou un peu plus court :
=SI(NB.SI(Jour1!$A$2:$A$35;A2)=0;"nonprésentmois1";SUBSTITUE(B2;"XO";"")-INDEX(SUBSTITUE(Jour1!$B$2:$B$10;"XO";"");EQUIV(A2;Jour1!$A$2:$A$35;0)))

abcd

 

[big_cham]

Re : Format de cellule personnalisé

Ok, une fois écrit ca parait tellement plus simple !😀

Merci à vous