XL 2016 Fonction si, et avec 3 variables et 7 retour possible(réponse).

[geoffreywolter]

Dans une classeur j'ai 3 cellules qui peuvent contenir soit un "oui" ,soit un "non". la combinaison de ses Oui et Non doit me retourner dans une autre cellule un chiffre entre 1 et 7 (en fonction de la combinaison précédemment citée). Comment dois-je m'y prendre? merci.

 

[Dranreb]

Bonjour.
C'est du genre =4*(A1="oui")+2*(B1="oui")+(C1="oui")

 

[geoffreywolter]

Dans une classeur j'ai 3 cellules qui peuvent contenir soit un "oui" ,soit un "non". la combinaison de ses Oui et Non doit me retourner dans une autre cellule un chiffre entre 1 et 7 (en fonction de la combinaison précédemment citée). Comment dois-je m'y prendre? merci.

=SI(ET(AL15="oui")+(AL16="oui")+(AL17="OUI");1) voici ma première section qui fonctionne mais je ne parviens pas à intégrer la suite de la ligne. =si(et((AL15="oui")+(AL16="oui")+(AL17="NON");2) et cela continue jusqu'à 7
Merci.

 

[Dranreb]

Il n'y a pas de ET à utiliser pour obtenir le résultat décrit.
Sommez simplement les expressions booléennes vraie multipliée les poids binaire 4, 2, 1. Par exemple, pour obtenir respectivement 1 et 2 pour vos deux premiers cas (mais ça va alors de 1 à 8) :

=4*(AL15="NON")+2*(AL16="NON")+(AL17="NON")+1

 

[mapomme]

Bonsoir à tous 🙂,

Juste pour le fun, une généralisation à n cellules (ici à 5 cellules). le bit de poids fort est celui qui est le plus à gauche (A1) :
=SOMMEPROD((A1:E1="oui")*TRANSPOSE(2^(COLONNES(A1:E1)-LIGNE(INDIRECT("1:"&COLONNES(A1:E1))))))
ou si on commence à 1 et non pas à 0 :
=1+SOMMEPROD((A1:E1="oui")*TRANSPOSE(2^(COLONNES(A1:E1)-LIGNE(INDIRECT("1:"&COLONNES(A1:E1))))))

 

[geoffreywolter]

Je pense que je me suis mal fais comprendre. en AH15,AH16,AH17 j'ai des cellules qui peuvent avoir de oui ou non dans un ordre diffèrent. en fonction du résultat une valeur entre 1 et 7 doit s'afficher automatiquement dans la cellule AA32.
Je ne parviens pas à intégrer de multiple condition.
Merci pour votre aide.

fichier joint pour exemple

 

[Dranreb]

Toujours le même principe, en AA32 :

=4*(AH15="NON")+2*(AH16="NON")+(AH17="NON")

Faite des essais, bon sang, avant de décider que ça ne va pas.
Notez que vous pourriez aussi utiliser les vraies conditions de départ :

=4*(AF15<15)+2*(AF16<15)+(AF17<15)

En y ajoutant 1, au vu de la légende (je l'ai vue après) :

=4*(AF15<15)+2*(AF16<15)+(AF17<15)+1

Mais avec un 8ème poste : "Aucun" pour 3 "NON"
Vous comprenez le principe ?
À 1 au cas où il y aurait tout, on ajoute 4 s'il n'y a pas trop de sucre, puis 2 s'il n'y a pas trop de gras saturé, puis 1 s'il n'y a pas sodium.

 

[geoffreywolter]

Toujours le même principe, en AA32 :

=4*(AH15="NON")+2*(AH16="NON")+(AH17="NON")

Faite des essais, bon sang, avant de décider que ça ne va pas.
Notez que vous pourriez aussi utiliser les vraies conditions de départ :

=4*(AF15<15)+2*(AF16<15)+(AF17<15)

En y ajoutant 1, au vu de la légende :

=4*(AF15<15)+2*(AF16<15)+(AF17<15)+1

Mais avec un 8ème poste : "Aucun" pour 3 "NON"

 

[geoffreywolter]

J'ai bien saisi que vous essayé de m'aider et je vous en remercie. je ne comprend simplement pas comment la combinaison d'un oui à AH15 et AH17 (qui doit avoir une valeur de 3) est declaré différemment d'un oui à AH15 et AH16 qui devrait avoir une valeur de 2. (détaille dans la combinaison en bas)

 

[Dranreb]

Parce qu'ils ont des poids différents: 4 pour le sucre, 2 pour le gras et 1 pour le sodium.
Faites une table de vérité de tous les cas, vous verrez bien.
"NON" à AH16 donne 0 + 2 + 0 +1 = 3 tandis que
"NON" à AH17 donne 0 + 0 + 1 +1 = 2

 

[Dranreb]

Mais je suis en train de voir que ça ne va pas parce que d'après la légende le sucre tout seul n'est pas dans le paquet du début. Dans ce cas on va faire autrement, sauf erreur de ma part, en AA32 :

=CHOISIR(1+4*(AF15>=15)+2*(AF16>=15)+(AF17>=15);8;7;5;4;6;3;2;1)

 

[geoffreywolter]

Mais je suis en train de voir que ça ne va pas parce que d'après la légende le sucre tout seul n'est pas dans le paquet du début. Dans ce cas on va faire autrement, sauf erreur de ma part, en AA32 :

=CHOISIR(1+4*(AF15>=15)+2*(AF16>=15)+(AF17>=15);8;7;5;4;6;3;2;1)

Super gros merci!
je n'étais pas fou ..cela fonctionnait seulement en partie avec l'autre méthode

 

[mapomme]

Re 😉,

Je n'étais pas fou ..cela fonctionnait seulement en partie avec l'autre méthode

Non mais vous étiez incomplet 😡. Vous avez fait travailler les autres inutilement sur des hypothèses non dites. Ce n'est que la mise à disposition de votre classeur qui a permis de débloquer la situation (il aura fallu attendre le 6ème message de cette discussion).
Les répondeurs ne sont pas des Madames Irma qui grâce à la vision dans leur boule de cristal peuvent deviner l'agencement de vos données.

Lisez la charte du site et méditez les deux articles suivants :

2.4 – La question doit être posée le plus clairement possible en comprenant bien que le lecteur ne peut pas s’imaginer le problème.


2.5 – La possibilité de joindre des fichiers est donnée sur ce forum. Ne pas hésiter à utiliser cette fonction, tout en veillant à ce que les données soient fictives et donc qu’aucune donnée confidentielle, nominative ne soit dans le fichier.