XL 2016 Fonction SI cellule = texte ou texte; alors

Dugenou

XLDnaute Barbatruc

• 26 Novembre 2020

• #2

Bonjour,
Dans votre exemple on a l'impression que tout se trouve dans la même cellule : quand société = FR001, PL0001, DK001 : il faut renvoyer quoi puisqu'on a à la fois FR, PL et DK ?
Votre formule doit être modifiée en remplaçant à chaque fois le ;"") par le SI suivant :
=SI(NB.SI(B2;"*FR*";"EUR";SI(NB.SI(B2;"*PL*";"EUR";SI(NB.SI(B2;"*DK*";"DDK"))) etc..
Essayez peut être la fonction TROUVE ou CHERCHE, ou joignez un fichier exemple

Cordialement

 

Vote positif 0 Vote négatif

Phil69970

XLDnaute Barbatruc

• 26 Novembre 2020

• #3

Bonjour Maxou, le forum

Je propose :
=SI(GAUCHE(A1;2)="FR";"EUR";SI(GAUCHE(A1;2)="PL";"PLN";SI(GAUCHE(A1;2)="DK";"DKK";"Valeur non prévue")))

@Phil69970

 

Dernière édition: 26 Novembre 2020

Vote positif 0 Vote négatif

fanch55

XLDnaute Barbatruc

• 26 Novembre 2020

• #4

Bonjour le fil,
Si A1 est la cellule à vérifier
=STXT("EURPLNDKK";TROUVE(GAUCHE(A1;2);"FR_PL_DK");3)

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 26 Novembre 2020

• #5

Bonjour à tous,

Pour "A1" en "B1"

VB:

=CHOISIR(EQUIV(GAUCHE($A1;2);{"DK";"FR";"PL"});"DKK";"EUR";"PLN")

Copier vers le bas

JHA

 

Vote positif 0 Vote négatif

Solution

M

Maxou69

XLDnaute Nouveau

• 27 Novembre 2020

• #6

Bonjour à tous,

Merci beaucoup pour vos retours !

J'ai tenter vos formules dans mon fichier, et le vainqueur est JHA !

DUGENOU, merci pour ton aide ! Je me suis suis peut être mal exprimé dans mon post en effet.
La valeur de ma cellule A1 est égal à FR001 ou DK001 ou PL001 etc.. J'ai environ un 15zaine de valeur qui peuvent remplir la cellule.
Néanmois, la formule que vous m'avez donnée, je rencontrais le même problème, trop grand nombre d'argument.

Phil69670, Merci également pour ta réponse. J'ai essayé ta formule, mais la valeur affiché est "Valeur non prévue".

Je me suis peut être emmêler les pinceaux avec vos formules dans mon fichier, ce qui est fort probable !

FRanch, je pense que la formule que tu m'as fournis sert si la cellule A1 contient l'ensemble de des données PL+FR+DK

JHA, ta formules correspond à mon besoins, elle colle parfaitement !!

Meri beaucoup de votre aide !

Excellente journée à vous

 

Vote positif 0 Vote négatif

J

JHA

XLDnaute Barbatruc

• 27 Novembre 2020

• #7

Bonjour à tous,

Ci-joint un fichier avec toutes les réponses à ce topic.

JHA

 

Pièces jointes

• Classeur fonctions de recherche des 2 premiers caractères.xlsx

  9.7 KB · Affichages: 17

Vote positif 0 Vote négatif

Phil69970

XLDnaute Barbatruc

• 27 Novembre 2020

• #8

Bonjour à tous

Maxou69 à dit:

Je cherche a créer une fonction si pour chercher dans la cellule A1

Cliquez pour agrandir...

Si tu as "Valeur non prévue" c'est que ta cellule ne commence pas aucune des valeurs prévues à savoir FR, PL ou DK

La formule que j'ai donné fonctionne pour la celulle A1 comme demandé .
=SI(GAUCHE(A1;2)="FR";"EUR";SI(GAUCHE(A1;2)="PL";"PLN";SI(GAUCHE(A1;2)="DK";"DKK";"Valeur non prévue")))
Et à copier vers le bas

As tu bien fais tes essais ?

Car voila ce que je trouve sur les différentes formules proposées.(Voir fichier)

Solution de ==>	JHA	Fanch55	Phil69970
FR001	EUR	EUR	EUR
DK001	DKK	DKK	DKK
PL001	PLN	PLN	PLN
GHG001	EUR	#VALEUR!	Valeur non prévue
XX001	PLN	#VALEUR!	Valeur non prévue
01FR001	#N/A	#VALEUR!	Valeur non prévue
01DK001	#N/A	#VALEUR!	Valeur non prévue

Quand à la phrase je la prends pour de l'humour :

Maxou69 à dit:

et le vainqueur est JHA !

Cliquez pour agrandir...

Ce n'est pas un concours simplement un retour ou souvent pour faire la même opération il y a plusieurs chemins qui devraient aboutir au même résultat.
Au demandeur de choisir en fonction de ces aptitudes personnels, et/ou de la maintenance ultérieure du fichier à mettre en œuvre la ou les solutions proposés.

@Phil69970

 

Pièces jointes

• Formule.xlsm

  10.7 KB · Affichages: 2

Vote positif 0 Vote négatif

fanch55

XLDnaute Barbatruc

• 27 Novembre 2020

• #9

Pour finaliser, pour @JHA ou moi,
il suffit d'englober la formule par la fonction SiErreur :

=SIERREUR(STXT("EURPLNDKK";TROUVE(GAUCHE(A1;2);"FR_PL_DK");3);"")

=SIERREUR(CHOISIR(EQUIV(GAUCHE($A1;2);{"DK";"FR";"PL"});"DKK";"EUR";"PLN");"")

 

Vote positif 0 Vote négatif

Phil69970

XLDnaute Barbatruc

• 27 Novembre 2020

• #10

Bonjour à tous

Voici le fichier après finalisation de Fanch55

@Phil69970

 

Pièces jointes

• Formule V2.xlsm

  11.2 KB · Affichages: 6

Vote positif 0 Vote négatif

fanch55

XLDnaute Barbatruc

• 27 Novembre 2020

• #11

Pour que la formule de @JHA fonctionne "au mieux" :

=SIERREUR(CHOISIR(EQUIV(GAUCHE($A2;2);{"DK";"FR";"PL"};0);"DKK";"EUR";"PLN");"")

 

Vote positif 0 Vote négatif

Phil69970

XLDnaute Barbatruc

• 27 Novembre 2020

• #12

Là maintenant les 3 formules donnent le même résultat, et juste de surcroit !
*Précision si le demandeur ne veut pas dans ma formule de la phrase "Valeur non prévue" libre à lui de la remplacer par une autre ou rien du tout en laissant alors juste les "".

@Phil69970

 

Vote positif 0 Vote négatif

M

Maxou69

XLDnaute Nouveau

• 30 Novembre 2020

• #13

Salut à tous,

Oui Phil69970, c'est évidemment de l'humour !

Je ne cherchai pas à vous mettre en compétition, bien au contraire, je suis bien content que vous ayez pris le temps de répondre à mes questions et en plus de me donner des réponses !

Désormais j'aurais 3 formules différentes pour parvenir à mes fins, et j'ai pu améliorer mes compétences Excel grâce à vous tous !

UN grand merci à vous

 

Vote positif 0 Vote négatif