Fonction si alors sinon avec variables entre deux valeurs

[clementguimera]

Bonjour tout le monde et d'avance merci pour votre aide.

Je n'arrive pas à créer la bonne formule de type SI X est compris entre [10-20] alors valeur.
Pour faire simple, voici mes valeurs sur lesquelles je bloque...

SI x<10 000= 0 + SI 1001<x<10000=5 + SI 10 001<x<50 000=10 + SI 50 001<x< 100 000=15 +SI x>100 000=20

Je compte sur votre aide 🙂

 

[Modeste]

Re : Fonction si alors sinon avec variables entre deux valeurs

Bonjour clementguimera et bienvenue à toi 🙂

Compter sur l'aide des autres intervenant sur un forum d'entraide ... jusque là, c'est possible 😀

Mais il faut que tu nous donnes un coup de main aussi: dépose-nous un petit fichier qui représenterait la structure de ton vrai fichier, en précisant:

• ce qui devrait apparaître
• à quel endroit
• sous quelle(s) condition(s)

... Jusque là, entre ton explication et ton essai de formule, il y a comme une discordance: d'un côté tu dis "X est compris entre [10-20]" et de l'autre, l'échelle semble plutôt comprise entre 10.000 (ou 1.001 😕) et "plus de 100.000"

[Edit:] Salut excfl 🙂

 

[excfl]

Re : Fonction si alors sinon avec variables entre deux valeurs

Bonjour le forum,

Je n'arrive pas à créer la bonne formule de type SI X est compris entre [10-20] alors valeur.

=SI(ET(A1>=10;A1<=20);"Oui";"Non")

 

[clementguimera]

Re : Fonction si alors sinon avec variables entre deux valeurs

Merci pour vos réponses qui m'ont mis sur la bonne voie.
J'ai enfin trouvé la bonne formule qui est (du moins pour son commencement):

=SI(B2>1001;5;0)*ET(SI(B2<10000;5))

YES !

 

[Dranreb]

Re : Fonction si alors sinon avec variables entre deux valeurs

Bonjour.

Que pensez vous de cette formule ?

=ENT(LOG10(MAX(B2/100;1)))*5

 

[excfl]

Re : Fonction si alors sinon avec variables entre deux valeurs

Salut modeste,

Autrement dit :

=SI(ET(B2>1001;B2<10000);5;"0")

 

[clementguimera]

Re : Fonction si alors sinon avec variables entre deux valeurs

Je ne comprend tout simplement pas cette formule 🙂

Du coup je vous joint un tableau excel d'exemple. La rubrique "Note G. Adwords" correspond au barème que je voudrais faire afficher automatiquement.

J'ai refait mon barème qui est le suivant:

x<480= 5
480<x<880= 10
880<x<1300= 15
1300<x<1600= 20
1600<x<1900= 25
1900<x<3700= 30
3700<x<5000=35
x>5000=40

Voilà, encore merci pour votre aide précieuse 🙂

 

[excfl]

Re : Fonction si alors sinon avec variables entre deux valeurs

Re,

=SI(B2>5000;40;SI(B2>=3700;35;SI(B2>=1900;30;SI(B2>=1600;25;SI(B2>=1300;20;SI(B2>=880;15;SI(B2>=480;10;5)))))))

 

[Dranreb]

Re : Fonction si alors sinon avec variables entre deux valeurs

Le premier cas étant x<480, je considère que tous les nombres à gauche de votre nouveau barême sont ceux à partir desquels s'appliquent les valeurs derrière le signe égal.

=EQUIV(B2;{0;480;880;1300;1600;1900;3700;5000})*5

 

[clementguimera]

Re : Fonction si alors sinon avec variables entre deux valeurs

Re,

=SI(B2>5000;40;SI(B2>=3700;35;SI(B2>=1900;30;SI(B2>=1600;25;SI(B2>=1300;20;SI(B2>=880;15;SI(B2>=480;10;5)))))))

Là c'est parfait, wouhouuuuuuuuuuuuuu, merci !!!!! 😉

 

[Paf]

Re : Fonction si alors sinon avec variables entre deux valeurs

Bonjour à tous

a priori
en C2 : =SI(B2<480;5;SI(B2<880;10;SI(B2<1300;15;SI(B2<1600;20;SI(B2<1900;25;SI(B2<3700;30;SI(B2<5000;35;40)))))))
puis 'tirer' vers le bas

attention aux valeurs limites qui ne sont pas prises en compte

A+


Edit: Ben... trop tard

 

[Dranreb]

Re : Fonction si alors sinon avec variables entre deux valeurs

Notez que si votre barème est amené à changer vous auriez intérêt à donner un nom dans le classeur à la liste des bornes à partir desquelles ça augmente de 5 pour pouvoir simplement mettre :

=EQUIV(B2;Barême)*5

 

[excfl]

Re : Fonction si alors sinon avec variables entre deux valeurs

Re,

Merci pour ta réponse.

Ou :

=RECHERCHEV(B2;{0.5;480.10;880.15;1300.20;1600.25;1900.30;3700.40;5000.40};2)

 

[excfl]

Re : Fonction si alors sinon avec variables entre deux valeurs

Re,

Ou:

=CHOISIR(EQUIV(B2;{0;480;880;1300;1600;1900;3700;5000});5;10;15;20;25;30;35;40)