Fonction RechercheV avec condition

[nalchris]

Bonjour,

je n'arrive pas à ajouter une condition à la fonction rechercheV.

je m'explique, les colonnes d'un tableau n'ont pas une valeur sur chaque ligne. je souhaite trouver la dernière valeur d'une colonne précédant une date sélectionnée.
Mon idée de départ est d'utiliser rechercheV mais en ajoutant la condition de trouver une valeur.

ci-joint un fichier avec un exemple.

dans cette exemple, je cherche dans la colonne C le dernier résultat précédant la date du 12 juil soit la valeur 10 (valeur du 5 juil)

merci de votre aide.

 

[laurent950]

Re : Fonction RechercheV avec condition

Bonsoir,

je suis pas sur mais ces pas possible avec recherchev la matrice n'est pas faite pour cela. il faut passer par un autre moyen enfin je pense il y a des plus fort que moi, mais pourquoi pas vous aidé si vousm'expliquer davantage

laurent

 

[mapomme]

Re : Fonction RechercheV avec condition

Bonjour nalchris,

Si les données du tableau sont toutes numériques ou vides, essayez cette formule (Onglet 1°):

=SIERREUR(INDEX(C3:C14;EQUIV(1E+99;DECALER($C$3;0;0; EQUIV(J8;A3:A14;0)-1;1);1));NA())

Si les données du tableau sont toutes du texte ou vides, essayez cette formule (Onglet 2°):

=SIERREUR(INDEX(C3:C14;EQUIV(REPT("z";255);DECALER($C$3;0;0; EQUIV(J8;A3:A14;0)-1;1);1));NA())

Si les données du tableau sont soit numériques soit du texte ou vides, essayez cette formule (Onglet 3°):

=SIERREUR(INDEX(C3:C14;MAX(SIERREUR(EQUIV(1E+99;DECALER($C$3;0;0; EQUIV(J8;A3:A14;0)-1;1);1);-1);SIERREUR(EQUIV(REPT("z";255);DECALER($C$3;0;0; EQUIV(J8;A3:A14;0)-1;1);1);-1)));NA())

ou bien cette formule matricielle (Onglet 4°):

=SIERREUR(INDEX(C3:C14;MAX(NON(ESTVIDE(DECALER($C$3;0;0; EQUIV(J8;A3:A14;0)-1;1))) * LIGNE(DECALER($C$3;0;0; EQUIV(J8;A3:A14;0)-1;1)))-LIGNE(C3)+1);NA())

Formule matricielle: Elle doit être validée par la combinaison des touches Ctrl+Maj+Entrée au lieu de la seule touche Entrée comme une formule classique.
Si la validation matricielle est correcte, alors Excel entoure la formule d'accolades {=.......}.
Chaque fois que cette formule sera modifiée, la validation devra se faire par Ctrl+Maj+Entrée. Les accolades apparaissent à la validation et ne doivent pas être saisies au clavier.

 

[nalchris]

Re : Fonction RechercheV avec condition

Bonjour,

Merci pour les réponses.
Ça fonctionne exactement comme je le souhaite. je n'ai plus qu'à approfondir pour mieux comprendre les fonctions SIERREUR et DECALER.