Fonction qui valide la présence d'une feuille

[siocnarf]

Bonjour,

Si j'utilise la fonction FeuilleExiste de cette façon cela fonctionne correctement.
If FeuilleExiste("Feuil1") Then
Sheets("Feuil1").Select
Sheets("Feuil1").Name = VDatadeBase1(1)
End If

Si j'utilise ma fonction ainsi alors j'obtiens un type d'argument by ref incompatible. La valeur de VDatadeBase1(1) est "serveurs"

If not FeuilleExiste(VDatadeBase1(1)) Then
Sheets("Feuil1").Select
Sheets("Feuil1").Name = VDatadeBase1(1)
End If


Public Function FeuilleExiste(sNomFeuille As String) As Boolean
'Validation de l'existence d'une feuille
On Error GoTo Err_FeuilleExiste
FeuilleExiste = False
FeuilleExiste = Not ActiveWorkbook.Worksheets(sNomFeuille) Is Nothing
Err_FeuilleExiste:
End Function

Comment puis-je faire pour être compatible dans les 2 scénarios?

Merci,

François Racine

 

[Habitude]

Re : Fonction qui valide la présence d'une feuille

Bonjour

A essayer
Si le byref est incompatible
Ajoutes-y un Byval

Public Function FeuilleExiste(byVal sNomFeuille As String) As Boolean

 

[job75]

Re : Fonction qui valide la présence d'une feuille

Bonjour siocnarf, Habitude,

L'argument de la fonction doit être As Variant :

Public Function FeuilleExiste(sNomFeuille As Variant) As Boolean
On Error GoTo Err_FeuilleExiste
FeuilleExiste = False
FeuilleExiste = Not ActiveWorkbook.Worksheets(CStr(sNomFeuille)) Is Nothing
Err_FeuilleExiste:
End Function

écrit plus simplement :

Function FeuilleExiste(sNomFeuille) As Boolean
On Error Resume Next
FeuilleExiste = Not ActiveWorkbook.Worksheets(CStr(sNomFeuille)) Is Nothing
End Function

CStr est nécessaire si la valeur envoyée comme argument est un nombre.

A+