Fonction OU comme critère de la fonction NB.SI

[GBL]

Bonjour,

Je voudrais imbriquer une fonction OU comme critère d’une fonction NB.SI
Je crois deviner que la fonction NB.SI n’accepte qu’un seul critère.
Quelqu’un peut-il m’en dire plus.
En fait je teste dans un tableau de pointage (40 entrées) les symboles des pauses effectuées et je comptabilise les heures prestées, heures de maladie, de congé, heures Sup. …...
Pour chaque ligne ( le pointage d’un mois pour un employé), je teste 6 critères (types de pause) sur 3 zones différentes pour chaque semaine du mois.
Je dois maintenant considérer les pauses non prestées pour cause de maladie, comme prestées pour les heures Sup. ! ! !
Je voudrais donc remplacer le critère A (par exemple pour la pause A prestée) par le critère A ou MA (pause A en maladie) ; ce qui donne :
* la formule initiale qui fonctionne : =(NB.SI($B6:$K6;"A")*$F$101)+(NB.SI($P6:$Y6;"A")*$F$101)+(NB.SI($AD6:$AM6;"A")*$F$101)+(NB.SI($AR6:$BA6;"A")*$F$101)+(NB.SI($BF6:$BO6;"A")*$F$101)+(NB.SI($BT6:$CC6;"A")*$F$101)
* que je voudrais remplacer par celle--ci
=(NB.SI($B6:$K6;OU(A;MA))*$F$101)+(NB.SI($P6:$Y6;OU(A;MA))*$F$101)+(NB.SI($AD6:$AM6;OU(A;MA))*$F$101)+(NB.SI($AR6:$BA6;OU(A;MA))*$F$101)+(NB.SI($BF6:$BO6; OU(A;MA))*$F$101)+(NB.SI($BT6:$CC6;OU(A;MA))*$F$101)

Excel ne donne aucun message d’erreur, mais ne trouve jamais le critère A ni MA.

Je sais qu’il suffit de prolonger ma formule initiale par la même en remplaçant le critère A par le critère MA, mais les formules deviennent vraiment kilométriques.

Quelqu’un peut-il m’aider ?

Merci d’avance

 

[Tibo]

Re : Fonction OU comme critère de la fonction NB.SI

Bonjour,

Il est généralement plus simple de joindre un fichier pour exposer un problème.

Cela dit, essaye avec :

=SOMMEPROD(((B6:K6="A")+(B6:K6="MA")+(P6:Y6="A")+(P6:Y6="MA")+
(AD6:AM6="A")+(AD6:AM6="MA")+(AR6:BA6="A")+(AR6:BA6="MA")+(BF6:BO6="A")+
(BF6:BO6="MA")+(BT6:CC6="A")+(BT6:CC6="MA"))*F101)

Je te laisse tester

@+

 

[haonv]

Re : Fonction OU comme critère de la fonction NB.SI

Bonsoir GBL ,

Sans voir un bout de ton fichier , il est assez difficile de proposer une solution à ton problème.
Je me demandais ainsi une chose : dans les colonnes de la ligne 6 que tu sautes(de L à O ;de Z à AC ...)As tu un risque de retrouver où pas un "A" ou "MA" ?
Sinon une plage (B6:CC6) devrait suffire avec cette formule :

=NB.SI(B6:CC6;"A")+NB.SI(B6:CC6;"MA")

Edit :correction de la formule

=(NB.SI(B6:CC6;"A")+NB.SI(B6:CC6;"MA"))*$F$101

bonsoir Tibo

Amicalement

 

[Tibo]

Re : Fonction OU comme critère de la fonction NB.SI

re,

Compte tenu des "sauts" de 4 cellules, une autre proposition :

=SOMMEPROD(((B6:CC6="A")+(B6:CC6="MA"))*(MOD(COLONNE(B6:CC6);14)<12)*F101)

Essaye et dis-nous

@+

 

[GBL]

Re : Fonction OU comme critère de la fonction NB.SI

Bonjour Tibo,

Merci pour le conseil, mais les matrices que je pourrais définir n'auraient pas les mêmes tailles (ce qui semble obligatoire) et le résultat des formules (B6:K6="A") par exemple, me sort des VRAI ou FAUX mais pas un nombre utilisable par mes formules.

J'ai simplifié les formules au Max (le tableur a été créé il y a quelques temps par quelqu'un qui a disparu) ce qui m'a permis d'ajouter des fonction NB.SI qui comptent les MA, MB, MC, MAB, MN .... tout en restant dans des limites acceptables (et acceptées par Excel).

Encore merci pour l'effort.

GBL

 

[GBL]

Re : Fonction OU comme critère de la fonction NB.SI

Bonsoir GBL ,

Sans voir un bout de ton fichier , il est assez difficile de proposer une solution à ton problème.
Je me demandais ainsi une chose : dans les colonnes de la ligne 6 que tu sautes(de L à O ;de Z à AC ...)As tu un risque de retrouver où pas un "A" ou "MA" ?
Sinon une plage (B6:CC6) devrait suffire avec cette formule :

Edit :correction de la formule

bonsoir Tibo

Amicalement

Bonjour haonv,

Les colonnes sautées représentent les pauses du Week-End qui sont traîtées différemment.
Pour m'en sortir avec mes petites connaissances, J'ai simplifié les formules au Max (le tableur a été créé il y a quelques temps par quelqu'un qui a disparu) ce qui m'a permis d'ajouter des fonction NB.SI qui comptent les MA, MB, MC, MAB, MN .... tout en restant dans des limites acceptables (et acceptées par Excel).

Encore merci pour l'effort.

GBL

 

[haonv]

Re : Fonction OU comme critère de la fonction NB.SI

Bonsoir GBL,

Tu signales à Tibo:

le résultat des formules (B6:K6="A") par exemple, me sort des VRAI ou FAUX mais pas un nombre utilisable par mes formules.

Mais ensuite excel doit transformer cela en 1 ou 0 ?
ce qui rend exploitable la formule.

Tu me signales ensuite :

Les colonnes sautées représentent les pauses du Week-End qui sont traîtées différemment

Dommage que tu ne me répondes pas à ma question du postes précédent: peux tu avoir un "A" ou "MA" dans ces colonnes?

Essaies d'envoyer un petit fichier sans données confidentielles et qui nous montre le résultat attendu.Tu obtiendras certainement une solution.

Amicalement