faire une somme en VBA

[seb631]

salut
voilà mon problème

j'ai un même tableau sur 3 feuilles.
Je dois effectuer une somme (colonne C = Col A + Col B)

j'ai fait le programme suivant.

Sub Somme()
For i = 1 To 3
With Worksheets("Feuil" & i)
.Range("C1").Select
.Range("C1") = "=SUM(A1:B1)"
.Range("C1").Select
Selection.AutoFill Destination:=.Range("C1:C5"), Type:=xlFillDefault
.Range("C1:C5").Select
End With
Next

End Sub


Mais le code ne fonctionne pas? Pourquoi?

PS j'ai modifié le programme, oublie des guillemets à "Feuil" mais ça marche toujours pas.
l'erreur est : la méthode Select de la classe range a échoué.

 

[vbacrumble]

Re : faire une somme en VBA

Bsr à tous

Essaye ainsi

Sub Somme()
For i = 1 To 3
With Worksheets("Feuil" & i)
.Activate
.Range("C1") = "=SUM(A1:B1)"
.Range("C1").AutoFill Destination:=.Range("C1:C5"), Type:=xlFillDefault
End With
Next
End Sub

NB: Les feuilles doivent se nommées Feuil1, Feuil2, Feuil3

A+

 

[alexga78]

Re : faire une somme en VBA

bonsoir seb631,
un essai si j'ai bien compris le probleme,


#
Sub Somme()
Dim Ws As Worksheet
Dim a, i As Integer
For Each Ws In ActiveWorkbook.Worksheets
a = Application.CountA(Ws.Range("A1:A65536"))
For i = 1 To a
Ws.Range("C" & i) = Application.Sum(Ws.Range("A" & i & ":B" & i))
Next i
Next
End Sub
#

bonne soirée

 

[job75]

Re : faire une somme en VBA

Bonjour le fil, le forum,

En VBA la sélection de cellules ou feuilles est presque toujours inutile :

Sub Somme()
Dim i As Byte
For i = 1 To 3
Worksheets("Feuil" & i).Range("C1:C5").FormulaR1C1 = "=SUM(RC[-2]:RC[-1])"
Next
End Sub

ou encore :

Sub Somme()
Dim i As Byte
For i = 1 To 3
With Worksheets("Feuil" & i)
.Range("C1:C5").FormulaR1C1 = "=SUM(RC[-2]:RC[-1])"
.Range("C1:C5").Value = .Range("C1:C5").Value 'ne conserve que les valeurs
End With
Next
End Sub

Bonne journée.