Microsoft 365 Export 2 onglets en 1 seul PDF suivant critères

Option Explicit
Sub Export_PDF()
Dim CurSh As Worksheet, Sh As Worksheet
Dim ZoneImprim As String, PdfName As String, PdfFullName As String
    Set CurSh = ActiveSheet
    For Each Sh In Sheets(Array("Feuil1", "Feuil2"))
        Select Case WorksheetFunction.Sum(Sh.Range("B4,B16,B29"))
            Case 1: ZoneImprim = "$D$2:$K$12"
            Case 2: ZoneImprim = "$D$2:$K$25"
            Case 3: ZoneImprim = "$D$2:$K$38"
        End Select
        With Sh.PageSetup
            .PrintArea = ZoneImprim
            .CenterHorizontally = True
            .FitToPagesWide = 1
            .Orientation = xlLandscape ' mode paysage ==> A choisir
            '.Orientation = xlPortrait  ' mode portrait ==> A choisir
        End With
    Next
    Sheets(Array("Feuil1", "Feuil2")).Select
        PdfName = Sheets("Feuil1").[O2] & ".pdf"
        PdfFullName = CreateObject("Wscript.Shell").SpecialFolders("MyDocuments") & "\" & PdfName
        ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PdfFullName, OpenAfterPublish:=True
        MsgBox "Le fichier PDF est sauvegardé dans " & vbLf & PdfFullName
    CurSh.Select
End Sub

Option Explicit
Sub Export_PDF()
Dim CurSh As Worksheet, Sh As Worksheet
Dim ZoneImprim As String, PdfName As String, PdfFullName As String, Zone As String
    Set CurSh = ActiveSheet
    For Each Sh In Sheets(Array("Feuil1", "Feuil2"))
        Select Case True
            Case Sh.[B29] <> "": ZoneImprim = "$D$2:$K$38"
            Case Sh.[B16] <> "": ZoneImprim = "$D$2:$K$25"
            Case Sh.[B4] <> "":  ZoneImprim = "$D$2:$K$12"
            Case Else:           ZoneImprim = ""
        End Select
        If ZoneImprim <> "" Then
            With Sh.PageSetup
                .PrintArea = ZoneImprim
                .CenterHorizontally = True
                .FitToPagesWide = 1
                .Orientation = xlLandscape ' mode paysage ==> A choisir
                '.Orientation = xlPortrait  ' mode portrait ==> A choisir
            End With
            Zone = Trim(Zone & " " & Sh.Name)
        End If
    Next
    If Zone <> "" Then
        Sheets(Split(Zone)).Select
            PdfName = Sheets("Feuil1").[O2] & ".pdf"
            PdfFullName = CreateObject("Wscript.Shell").SpecialFolders("MyDocuments") & "\" & PdfName
            ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=PdfFullName, OpenAfterPublish:=True
            MsgBox "Le fichier PDF est sauvegardé dans " & vbLf & PdfFullName
    End If
    CurSh.Select
End Sub