ERREUR #NA et camomille

[yoyopasnet]

Bonjour à tous,
J'ai chercher dans tous les sens et pris 5 camomille pour me calmer mais la sa m'ernerve je ne vois pas d'ou vient l'erreur
Quelqu'un peut il m'aider
merci car je n'ai plus de camomille
Regarde la pièce jointe Classeur2.xls

 

[jeanpierre]

Re : ERREUR #NA et camomille

Bonsoir yoyopasnet,

Essaie avec : =RECHERCHEV("0730";Feuil1!I:M;5;0)

"0730", en texte puisque c'est en texte dans ta feuille 1, plage I:M, 5 pour cinquième colonne de la plage et le zéro pour une recherche exacte

Tu peux remplacer la valeur en dur dans la formule par la référence d'une cellule contenant cette valeur (toujours en texte).

Bonne soirée.

Jean-Pierre

 

[ROGER2327]

Re : ERREUR #NA et camomille

Bonjour yoyopasnet

Essayez

[COLOR="DarkSlateGray"][B]=RECHERCHE("0730";Feuil1!I1:I32;Feuil1!M1:M32)[/B][/COLOR]

ROGER2327
#2130

 

[yoyopasnet]

Re : ERREUR #NA et camomille

MERCI
cela marche ouf
derniere chose comment afficher toutes les ligne quie comporte par exemple le 0101

 

[job75]

Re : ERREUR #NA et camomille

Bonsoir yoyopasnet, jeanpierre 🙂 Roger Re 🙂

MERCI
cela marche ouf
derniere chose comment afficher toutes les ligne quie comporte par exemple le 0101

Oui une "dernière chose" comme vous dites, nettement plus trapue.

Entrer en B1 :

=INDEX(Feuil1!M$1:M$100;PETITE.VALEUR(SI(ESTNUM(TROUVE("0101";Feuil1!I$1:I$100));LIGNE($1:$100));LIGNES(B$1:B1)))

Formule matricielle à valider par Ctrl+Maj+Entrée, et à tirer vers le bas.

Si on veut éviter les valeurs d'erreur #NOMBRE! c'est possible et plus mignon.

Mais ça complique encore la formule, il vaut mieux s'arrêter avant 😎

A+

 

[yoyopasnet]

Re : ERREUR #NA et camomille

oups ca ne marche pas je pense que je dois mal faire quelque chose

 

[job75]

Re : ERREUR #NA et camomille

Re,

Je répète :

Formule matricielle à valider par Ctrl+Maj+Entrée, et à tirer vers le bas.

Edit : fichier joint

A+

 

[yoyopasnet]

Re : ERREUR #NA et camomille

J'ai coller la formule en B1 puis j'ai fais ctrl+maj+entre puis j'ai tiré vers le bas mais rien a faire sa ne veux pas

 

[job75]

Re : ERREUR #NA et camomille

Re,

Pour valider il faut d'abord cliquer dans la barre de formule.

Voir le fichier joint de mon post précédent.

A+

 

[yoyopasnet]

Re : ERREUR #NA et camomille

mille merci ca marche une derniere chose (encore la cela devient de la gourmandise de savoir)est il possible d'eviter les #nombres

 

[job75]

Re : ERREUR #NA et camomille

Re,

J'ai écrit :

Si on veut éviter les valeurs d'erreur #NOMBRE! c'est possible et plus mignon.

Mais ça complique encore la formule, il vaut mieux s'arrêter avant  :cool:

Il est tard, j'en ai assez fait pour aujourd'hui.

Bonne nuit.

 

[JCGL]

Re : ERREUR #NA et camomille

Bonjour à tous,

Un essai avec un TCD

A+ à tous

Edition : Salut Job 🙂

 

[job75]

Re : ERREUR #NA et camomille

Bonjour JCGL 🙂 le fil, le forum.

Pas de doute, un TCD fait vraiment un excellent travail.

A noter cependant que la formule matricielle que j'ai donnée avec TROUVE recherche en colonne I les valeurs comportant "0101", et trouvera aussi bien "A0101" ou "0101B".

Pour terminer mon travail, si l'on veut éviter les #NOMBRE! :

=SI(LIGNES(B$1:B1)>NB.SI(Feuil1!I$1:I$100;"*0101*");"";INDEX(Feuil1!M$1:M$100;PETITE.VALEUR(SI(ESTNUM(TROUVE("0101";Feuil1!I$1:I$100));LIGNE($1:$100));LIGNES(B$1:B1))))

Et si l'on veut que la cellule en colonne I soit égale à "0101" :

=SI(LIGNES(B$1:B1)>NB.SI(Feuil1!I$1:I$100;"0101");"";INDEX(Feuil1!M$1:M$100;PETITE.VALEUR(SI([COLOR="Red"]Feuil1!I$1:I$100="0101"[/COLOR];LIGNE($1:$100));LIGNES(B$1:B1))))

Bonne journée et A+