Erreur de code calcul de pourcentage par tranche

[Plans24]

Bonjour, je suis nouveau sur le forum
j’apprécie vraiment qu’il y ait ce genre de forum pour pouvoir aider les personnes comme moi qui ne sommes pas très pro avec Excel
J’ai voulu faire une calculette sur excel pour calculer les sommes à payer en commission à la ADAGP pour la vente d’œuvre d’art

Le montant du droit de suite se calcule dans la limite d’un plafond fixé à 12 500 € dont voici le barème :

• 4 % pour la tranche du prix jusqu’à 50 000 € ;
• 3 % pour la tranche du prix comprise entre 50 000,01 € et 200 000 € ;
• 1 % pour la tranche du prix comprise entre 200 000,01 € et 350 000 € ;
• 0,5 % pour la tranche du prix comprise entre 350 000,01 € et 500 000 € ;
• 0,25 % pour la tranche du prix excédant 500 000,01 €

J’ai demandé à IA de me générer le code
J’ai reçu ce code, le voici

=MIN(12500; SI(A2<=50000; A20.04; SI(A2<=200000; 500000.04 + (A2-50000)0.03; SI(A2<=350000; 500000.04 + 1500000.03 + (A2-200000)0.01; SI(A2<=500000; 500000.04 + 1500000.03 + 1500000.01 + (A2-350000)0.005; 500000.04 + 1500000.03 + 1500000.01 + 1500000.005 + (A2-500000)*0.0025)))))


Lorsque je veux le coller le code dans la cellule, Excel me dit qu’il y a une erreur de code
Quelqu’un pourrait me dire ce qui ne va pas ?
J’utilise Excel 2000 21 pro en français
Merci de votre aide

 

[crocrocro]

Bonjour le fil,
concernant les erreurs, elles sont de 2 types :
- les décimaux le . à remplacer par , (selon votre paramétrage Excel)
- il manque l'opérateur de multiplication *
La formule avec ces corrections (sans avoir testé la validité par rapport aux règles que vous avez indiquées

=MIN(12500; SI(A2<=50000; A2*0,04; SI(A2<=200000; 50000*0,04 + (A2-50000)*0,03; SI(A2<=350000; 50000*0,04 + 150000*0,03 + (A2-200000)*0,01; SI(A2<=500000; 50000*0,04 + 150000*0,03 + 150000*0,01 + (A2-350000)*0,005; 50000*0,04 + 150000*0,03 + 150000*0,01 + 150000*0,005 + (A2-500000)*0,0025)))))

A noter qu'il serait plus simple d'avoir une formule où les paramètres sont dans des cellules et non 'en dur' dans la formule
Par exemple en c1 4% en d1 50000 en c2 3% en d2 200000 ...

 

[Dranreb]

Bonjour.
Vérifiez si cette formule ne donnerait pas le même résultat :

=MIN($A2*4%;500+$A2*3%;4500+$A2*1%;6250+$A2*0,5%;7500+$A2*0,25%;12500)

 

[Plans24]

mERCI

Bonjour le fil,
concernant les erreurs, elles sont de 2 types :
- les décimaux le . à remplacer par , (selon votre paramétrage Excel)
- il manque l'opérateur de multiplication *
La formule avec ces corrections (sans avoir testé la validité par rapport aux règles que vous avez indiquées

=MIN(12500; SI(A2<=50000; A2*0,04; SI(A2<=200000; 50000*0,04 + (A2-50000)*0,03; SI(A2<=350000; 50000*0,04 + 150000*0,03 + (A2-200000)*0,01; SI(A2<=500000; 50000*0,04 + 150000*0,03 + 150000*0,01 + (A2-350000)*0,005; 50000*0,04 + 150000*0,03 + 150000*0,01 + 150000*0,005 + (A2-500000)*0,0025)))))

A noter qu'il serait plus simple d'avoir une formule où les paramètres sont dans des cellules et non 'en dur' dans la formule
Par exemple en c1 4% en d1 50000 en c2 3% en d2 200000 ...

Merci 100000 Fois cela fonctione Parfaitement
Vous etes top
Formidable
Merci encore

 

[Plans24]

mERCI

Merci 100000 Fois cela fonctione Parfaitement
Vous etes top
Formidable
Merci encore

Bonjour.
Vérifiez si cette formule ne donnerait pas le même résultat :

=MIN($A2*4%;500+$A2*3%;4500+$A2*1%;6250+$A2*0,5%;7500+$A2*0,25%;12500)

Merci 100000 Fois cette fonction egalement Parfaitement
Vous etes top
Formidable
Merci encore