Envoyer mail et choisr une signature

[Chasse]

Bonjour le forum
J’ai deux boîtes de réception une privée et une au non d’un service.
Chaque fois que j’envoie un mail sans passer par VBA il part sous le nom du service avec une signature (signature 1).
Est-il possible de changer le nom de l’expéditeur et de choisir une signature .(Signature 2)
PS:
ma signature comporte un logo (signature2)

Sub Mail_workbook_Outlook_1()
    Dim OutApp As Object
    Dim OutMail As Object
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    On Error Resume Next
    With OutMail
        .to = "Destinataire@blabla.ch"
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .Body = "Bonjour" & Chr(10) & Chr(10) & "Voici les KPI pour " & Format(Date, "MMMM  YYYY") &_
         Chr(10) & "Bonne journée et meilleures salutations"
        .Send   
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

Merci de votre aide

 

[Guest]

Re : Envoyer mail et choisr une signature

Bonjour,

C'est plus une discussion pour autres Applications Office que pour excel! m'enfin, test ceci après avoir changé "Le Nom du compte" par le nom du compte que tu veux et tel qu'il apparaît dans la liste des comptes Outlook.

Pour la signature il te suffit d'aller dans les options/signatures de Outlook et d'attacher une signature à ce compte.

Sub Mail_workbook_Outlook_1()
    Dim OutApp As Object, OutMail As Object, oCompte As Object
    Set OutApp = CreateObject("Outlook.Application")
    
    Set oCompte = OutApp.Session.Accounts.Item("Le nom du compte")
   
    Set OutMail = OutApp.CreateItem(0)

    On Error Resume Next
    With OutMail
        .to = "[EMAIL="toto@truc.fr"]toto@truc.fr[/EMAIL]"
        .BCC = ""
        .Subject = "test_" 
        .Body = "Bonjour" & Chr(10) & Chr(10) & "Voici les KPI pour " & Format(Date, "MMMM  YYYY") & _
                Chr(10) & "Bonne journée et meilleures salutations"
        .sendusingaccount oCompte
        .send
    End With
    On Error GoTo 0
    Set oCompte = Nothing
    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub

A+

 

[Chasse]

Re : Envoyer mail et choisr une signature

Bonjour et merci pour ta réponse.

Ton code et le mien c’est blanc bonnet et bonnet blanc.
Le code et enregistre dans le « Classeur de macro personnel d’Excel»
Il me permet d’envoyer en pièce jointe n’importe quel classeur sans avoir besoin d’ouvrir Outlook.
Mais il ne me sert a rien, tant que je ne peux pas insérer ou choisir une signature, et y changer le compte de l’ expéditeur.
Merci et bonne journée

 

[Guest]

Re : Envoyer mail et choisr une signature

re,

Ton code et le mien c’est blanc bonnet et bonnet blanc.

1 - Pourtant, non, tu n'as pas du le lire correctement! Le mien envoie le mail avec le compte choisit!
2 - Nous ne donnons que des pistes de travail ici, ce n'est pas un marché à la macro.

A+

 

[Chasse]

Re : Envoyer mail et choisr une signature

C’très aimable de votre par de nous donner une piste merci.

Mais pour moi elle est plus d’obstacles qu’aux étoiles

En collant ton code cette partie se met en rouge et affiche erreur de syntaxe

.to = "[EMAIL="toto@truc.fr"]toto@truc.fr[/EMAIL]"

de plus cette partie de code est juste « c’est le destinataire » en l’occurrence je n’ai pas besoin de la changer

.to = "Destinataire@blabla.ch"

Même en mettant le nom du compte, pas de changement

Set oCompte = OutApp.Session.Accounts.Item("Le nom du compte")

Merci pour tes .1 .2
de ce pas je retourne au marché non au travail.

 

[Guest]

Re : Envoyer mail et choisr une signature

Re,


C'est l'éditeur de code des posts qui met les [email....] et , quand il rencontre l'arobase il faut simplement mettre l'adresse du destinataire. J'avais changé la tienne pour une des miennes pour les tests.

A+

 

[Staple1600]

Re : Envoyer mail et choisr une signature

Bonsoir à tous

Dans le blanc bonnet d'Hasco (que je salue au passage 😉)
Il y avait ceci:
Set oCompte = OutApp.Session.Accounts.Item("Le nom du compte")
et cela
.sendusingaccount oCompte
Mais pas dans le tien de bonnet, Chasse 😉

[suggestion au passage]
Pour tout ce qui concerne Outlook , faire un tour chez Ron de Bruin (c'est ma foi, fort instructif )
[/suggestion au passage]

NB: Comme disait le "palasco" 😉
L'emploi des balises BBCODE ci-dessous
[NOPARSE]test.test@test.fr[/NOPARSE] donne cet affichage : test.test@test.fr
mais cafouille si on y ajoute la balise

 et qu'en plus on colle le tout tel quel dans VBE ;)[/FONT][/FONT][/COLOR]

 

[suistrop]

Re : Envoyer mail et choisr une signature

Bonjour,

A tester :
.from = mail@depart.fr

Cordialement,

 

[Guest]

Re : Envoyer mail et choisr une signature

Bonjour,

@Suistrop: .From n'est pas une propriété l'objet MailItem d'Outlook.
@Chasse: voir en bas dans discussion similaires.

A+

Spécial bonjour à Staple🙂

 

[Yaloo]

Re : Envoyer mail et choisr une signature

Bonjour Chasse, bonjour le fil,

Avec cette macro, tu peux définir la signature à envoyer.

Option Explicit
Public Sub EnvoiAutomatiqueMail()
  Dim OutlookApp As Object, OutlookMail As Object
  Dim SigString$, Signature$, MaSignature$, i&
  'Vérification si Outlook est ouvert
  If OutlookOuvert = False Then i = Shell("Outlook", vbNormalNoFocus)

  Set OutlookApp = CreateObject("Outlook.Application")
  Set OutlookMail = OutlookApp.CreateItem(0)

  ' recupere la signature outlook, definis à qui envoyer, l'objet et ajoute la signature outlook au corps du mail "strbody"
  MaSignature = "Le nom de ta signature.htm"
  'Normalement l'emplacement est dans AppData\Microsoft\Signatures\
  SigString = Environ("appdata") & "\Microsoft\Signatures\" & MaSignature
  'Vérification de la présence de la signature dans le répertoire
  If Dir(SigString) <> "" Then
    Signature = GetBoiler(SigString)
   Else
    Signature = ""
  End If
  On Error Resume Next
    With OutlookMail
    .Subject = "This is the Subject line"
    .To = "Destinataire@blabla.ch"
    .HTMLBody = "Bonjour" & Chr(10) & Chr(10) & "Voici les KPI pour " & Format(Date, "MMMM  YYYY") & _
            Chr(10) & "Bonne journée et meilleures salutations" & "<br><br>" & Signature
    .Display
    '.Send
    End With
End Sub
Function OutlookOuvert() As Boolean
  Dim oOL As Object
  On Error Resume Next
  Set oOL = GetObject(, "Outlook.Application")
  On Error GoTo 0
  OutlookOuvert = Not (oOL Is Nothing)
  Set oOL = Nothing
End Function
Function GetBoiler(ByVal sFile As String) As String
  'Dick Kusleika
  Dim fso As Object
  Dim ts As Object
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set ts = fso.GetFile(sFile).OpenAsTextStream(1, -2)
  GetBoiler = ts.readall
  ts.Close
End Function

A+

Martial

 

[suistrop]

Re : Envoyer mail et choisr une signature

Bonjour,

@Suistrop: .From n'est pas une propriété l'objet MailItem d'Outlook.
@Chasse: voir en bas dans discussion similaires.

A+

Spécial bonjour à Staple🙂

Bonjour,

Tu as raison, c est peut etre plutot ca :

.SentOnBehalfOfName = "tata@tata.fr"

 

[Chasse]

Re : Envoyer mail et choisr une signature

Merci à tous pour vos réponses.
A suistrop pour : .SentOnBehalfOfName = tata@tata.fr et Yaloo pour le code de la signature
Je suis presque arrivé au terme de mon marché ??

Encore merci et bonne journée
PS :

Staple1600
Dans le blanc bonnet d'Hasco (que je salue au passage )
Il y avait ceci:
Set oCompte = OutApp.Session.Accounts.Item("Le nom du compte")
et cela
.sendusingaccount oCompte
Mais pas dans le tien de bonnet, Chasse

Le bonnet n’était peut-être pas blanc dans la rédaction du code, mais dans le résultat, oui

 

[Staple1600]

Re : Envoyer mail et choisr une signature

Bonsoir à tous

Chasse:
Moi, je passais juste pour saluer l'ami Hasco et pour faire une suggestion* 😉
(dont j'ignore si tu l'as vue ou suivie)
*voir dans le message #7 à propos de Ron.

Cela pourrait s'avérer utile pour la suite de ton marché 😉

 

[xhudi69]

Re : Envoyer mail et choisr une signature

Bonsoir à tous, le Forum,
Bonsoir Hasco 🙂
Bonsoir Staple1600 🙂

[suggestion au passage]
Pour tout ce qui concerne Outlook , faire un tour chez Ron de Bruin (c'est ma foi, fort instructif )
[/suggestion au passage]

Forum.Fil.Info = True
Il est ICI
Forum.Fil.Info = False

@+ 😎

 

[Staple1600]

Re : Envoyer mail et choisr une signature

Bonsoir xhudi69

C'est volontairement que je n'avais pas mis de lien...🙄
Pour encourager le demandeur à faire montre de curiosité, à faire sa recherche lui-même.
(un clic-droit sur la patronyme de Ron et Rechercher avec G..g.e suffisait à l'amener chez celui-ci)

Et c'est comme qui dirait raccord avec son pseudo : Chasse 😉
(chasser l'info par ses propres moyens 😉 )