Envoi d'un e-mail à plusieurs destinataires

[Lauglé]

Bonjour,

On m'a donné la procédure à suivre pour envoyer un e-mail automatique à partir d'EXCEL:

Sub email()
On Error Resume Next
ActiveWorkbook.Save

Dim MailAd As String

MailAd = "....@....." 'y mettre les adresses email de destinataires
Application.Dialogs(xlDialogSendMail).Show MailAd
End Sub

Ca fonctionne bien s'il existe 1 SEUL DESTINATAIRE.
Comment faire pour envoyer ce mail à PLUSIEURS DESTINATAIRES ?
(j'ai bien tenté "&"; ";"; ... en vain).

En vous remerciant pour votre aide.
Christophe.

 

[news]

Re : Envoi d'un e-mail à plusieurs destinataires

Bonjour à tous du forum,

Re: (j'ai bien tenté "&"; ";"; ... en vain).
cela ne fonctionne pas, il y a trop de ; mises
à modifier par:

MailAd = "____@____.com" & "; " & "____@____2.com" & "; " & "____@____3.com" 'y mettre les adresses email de destinataires

ou bien la procédure suivante, des données reprises, établies de Ron :
Sub Mail_with_outlook()

Dim OutApp As Object
Dim OutMail As Object
Dim strto As String, strcc As String, strbcc As String
Dim strsub As String, strbody As String

Set OutApp = CreateObject("Outlook.Application")
OutApp.Session.Logon
Set OutMail = OutApp.CreateItem(0)

strto = "_____@_____.com" ' Range("A2")
'strto = Range("A2") 'ou bien y mettre les adresses de destinataires dans Range("A2")
strcc = "_____@_____2.com"
strbcc = ActiveCell ' est sélectionné l'adresse email figurant dans ActiveCell
strsub = "ci-joint fichier Excel"
strbody = "Bonjour, l'email fonctionne bien" & vbNewLine & vbNewLine & _
"à verify le document Excel en annexe"

With OutMail
.To = strto
.CC = strcc
.BCC = strbcc
.Subject = strsub
.Body = strbody
' .Send
.Display
Application.Wait (Now + TimeValue("0:00:02"))
Application.SendKeys "%S"
End With

Set OutMail = Nothing
Set OutApp = Nothing
End Sub

bonne journée encore,

 

[Lauglé]

Re : Envoi d'un e-mail à plusieurs destinataires

Bonjour,

Je vous remercie pour votre retour.
J'avais déjà essayé la solution que vous mentionnez en haut de page, en vain.

Détail de mon fichier EXCEL:
cellule A1 : christophe / cellule B1 : laugle
cellule A2 : peter / cellule B2 : durand

Détail de la MACRO:
Sub email()
On Error Resume Next
ActiveWorkbook.Save
Dim MailAd As String
MailAd = (range("A1") & "." & range("B1") & "@wanadoo.fr") & "; " & (range("A2") & "." & range("B2") & "@wanadoo.fr") 'y mettre les adresses email de destinataires
Application.Dialogs(xlDialogSendMail).Show MailAd
End Sub

Un bouton DIFFUSION permet l'envoi auto :
Private Sub CommandButton1_Click()
Call email
End Sub


Lorsque vous lancez l'application, cela ne fonctionne pas. Lors du clic sur le bouton permettant la diffusion, une page outlook apparaît et je vois apparaître les 2 adresses, voulues au départ. Mais lors de l'envoi du message, le système ne reconnait qu'une seule adresse e-mail (entre les guillemets) "christophe.laugle@wanadoo.fr;peter.durand@wanadoo.fr" --> le système plante.

Alors que dans mon idée, j'adressais 2 destinataires (entre les guillements) : "christophe.laugle@wanadoo.fr" et "toto.titi@wanadoo.fr"

Avez-vous une solution ?
Merci. Cordialement.
Christophe.

 

[news]

Re : Envoi d'un e-mail à plusieurs destinataires

Re:

chez mois cela fonctionne,
à essayer, ci joint exemple de fichier, à modifier par vos données et vos adresses de destinataires,

bonne journée encore,

 

[MichelXld]

Re : Envoi d'un e-mail à plusieurs destinataires

bonjour


Tu peux utiliser

Dim MailAd As Variant
 
MailAd = Array("[EMAIL="mimi@test.fr"]mimi@test.fr[/EMAIL]", "riri@test.fr", "fifi@test.fr")
Application.Dialogs(xlDialogSendMail).Show MailAd

Bonne journée
MichelXld

 

[Lauglé]

Re : Envoi d'un e-mail à plusieurs destinataires

Bonjour

Le dernier code que l'on m'a suggéré est génial. C'est exactement ce que je recherchai depuis plusieurs jours !

Merci. Cordialement.
Christophe.