double equiv()

fgehin · 15 Mai 2017

Bonjour le forum,

J'ai retourné le problème dans tous les sens, mais je ne parviens pas à trouver la formule, qui doit être très simple, pour convertir mon tableau 1 dimension dans l'onglet "table" en tableau 2 dimensions dans l'onglet "conversion format".

En gros je pars de 3 colonnes qui m'intéressent dans l'onglet "table" :

"modèle" : colonne C
"tissu" : colonne D
"PR" : colonne J

Et je veux convertir ça dans le format suivant (dans l'onglet "conversion format") :

mes modèles en colonne A --> déjà fait (j'ai fait une sélection de ceux qui m'intéresse)
mes tissus en ligne 1 --> déjà fait et dé-doublonné
les PR qui correspondent à l'intersection du modèle et du tissu à l'intérieur du tableau

Est-ce que quelqu'un pourrait me donner un petit coup de main avec la bonne formule ?

Je vous remercie d'avance !

Faustine

CISCO · 15 Mai 2017

Bonsoir

Tu peux faire avec

Code:

SI(MAX(SI(table!$C$2:$C$13368&table!$D$2:$D$13368=$A2&B$1;LIGNE($2:$13368)))=0;"";INDEX(table!$J$1:$J$13368;MAX(SI(table!$C$2:$C$13368&table!$D$2:$D$13368=$A2&B$1;LIGNE($2:$13368)))))

à valider avec Ctrl+maj+entrer mais cela risque d'être fort long vu la taille de ton tableau.

@ plus

Shakki · 15 Mai 2017

Bonjour,

Une autre manière de faire. C'est aussi une formule à valider en matricielle.

Code:

=SIERREUR(INDEX(table!$J$2:$J$13368;EQUIV($A2;SI(table!$D$2:$D$13368 =B$1;table!$C$2:$C$13368;"");0));"")

A+

CISCO · 15 Mai 2017

Rebonsoir

Tu peux aussi faire avec

Code:

SOMMEPROD((table!$J$2:$J$13368)*(table!$C$2:$C$13368&table!$D$2:$D$13368=$A2&B$1))

en modifiant l'affichage des 0 dans Options ou avec Format.

@ plus

fgehin · 16 Mai 2017

super ça marche, merci !

double equiv()

fgehin

XLDnaute Junior

Pièces jointes

CISCO

XLDnaute Barbatruc

Shakki

XLDnaute Occasionnel

CISCO

XLDnaute Barbatruc

fgehin

XLDnaute Junior

Discussions similaires