détecter un onglet inexistant

[ragus77]

Bonjour a tous,

J'ai ce code :

For a = 5 To 10
ThisWorkbook.Sheets("Résultats").Range("AA" & a) = Workbooks(varNomFichier).Sheets("CTRL").Range("B" & a).Value
Next a

la valeur de l'onglet "CTRL" en B* se copie dans l'onglet "Résultat" en AA* le soucis est que sur certain fichiers, l'onglet "CTRL" n'existe pas, je ne sais pas comment le détecter

 

[Pierrot93]

Re : détecter un onglet inexistant

Bonjour,

regarde ceci, devrait t'aider...

Sub TestFeuilleExiste()
Dim nomfeuille As String
nomfeuille = "Feuil1"
If Not FeuilleExiste(nomfeuille) Is Nothing Then MsgBox "OK"
End Sub
Function FeuilleExiste(f As String) As Worksheet
On Error Resume Next
Set FeuilleExiste = Worksheets(f)
End Function

bon après midi
@+

 

[Robert]

Re : détecter un onglet inexistant

Bonjour Ragus, Pierrot, bonjour le forum,

Pierrot a dégainé plus vite... Tant pis je t'envoie quand même ma proposition :

Sub Macro1()
Dim o As Object 'déclare la variable o (Onglet)

On Error Resume Next 'gestion des erreurs (passe à la ligne suivante en cas d'erreur
Set o = Workbooks(varNomFichier).Sheets("CTRL") 'définit l'onglet o (si l'onglet CTRL n'existe pas cela provoque une erreur)
If Err <> 0 Then 'condition : si une erreur a été générée
    Err = 0 'annule l'erreur
    MsgBox "l'onglet CTRL n'existe pas !" 'message
    GoTo suite 'va à l'étiquette "suite" (sans exécuter ton code)
End If 'fin de la condition
On Error GoTo 0 'fin de la gestion des erreurs
'ton code
For a = 5 To 10
ThisWorkbook.Sheets("Résultats").Range("AA" & a) = Workbooks(varNomFichier).Sheets("CTRL").Range("B" & a).Value
Next a
suite: 'étiquette
'le reste de ton code (éventuellement)
End Sub

 

[ragus77]

Re : détecter un onglet inexistant

Merci a vous deux, Pierrot, désolé, j'ai pris celui de Robert, je m'y retrouvais mieux.