Microsoft 365 "Dépassement de capacité"

[rafi93]

bonjour à tous

sur une feuille contenant un tableau, j'ai une macro VBA qui se contente d'afficher toutes les colonnes, au cas où certaines seraient masquées, qui fonctionne parfaitement,
Sub Col_Affiche_tout()
Cells.Select
Selection.EntireColumn.Hidden = False
Range("A1").Select
End Sub

sur les cellules d'une colonne du tableau, j'ai rajouté une combobox toute simple pour sélectionner des items dans une liste
depuis, quand je lance la macro Col_Affiche_tout() j'ai un message d'erreur "Dépassement de capacité"
pourquoi ?
y a t il une solution ?

merci !

 

[Oneida]

Bonjour,
Pouvez mettre un fichier exemple a dispo

 

[pierrejean]

Bonjour
A tester:

Sub Col_Affiche_tout()
ActiveSheet.Columns.Hidden = False
Range("A1").Select
End Sub

 

[rafi93]

Merci Pierrejean !
c'était bien ça
mais pour que je puisse aller pêcher tout seul : quelle est l'explication ?
car je m'y perds toujours dans les multiples façon d'écrire la même chose en VB

 

[pierrejean]

Je pense que c'est le fait de sélectionner toutes les cellules qui sature la mémoire

 

[rafi93]

j'y ai pensé
mais le pb ne se pose pas quand il n'y a pas de combobox sur la feuille

 

[Cousinhub]

Bonjour,
Hello @pierrejean
A tout hasard, il n'y aurait pas un code genre :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.Count > 1 Then Exit Sub
End Sub

Si c'est le cas, il faut remplacer Count par CountLarge (mais c'est rarement le cas de devoir sélectionner toutes les cellules...
Bonne fin d'apm

 

[rafi93]

très bien, merci !

 

[Katido]

Bonjour,

C'est effectivement le Target.Count qui sature quand on sélectionne toutes les cellules (il y en a 2 ^ 34)
car c'est plus que la limite du Long, et .Count ramène un Long.

C'est en fait très facile de sélectionner toutes les cellules, même si on ne le veut pas : il suffit de cliquer sur le petit carré en haut à gauche des en-têtes (au-dessus du 1 et à gauche du A)

Plusieurs solutions :
1) utiliser .CountLarge (mais probablement pas disponible avec les anciennes versions) :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.CountLarge > 1 Then Exit Sub
End Sub

2) décomposer les lignes et les colonnes

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If Target.rows.Count > 1 Then Exit Sub
If Target.columns.Count > 1 Then Exit Sub
End Sub

3) multiplier les nombres de lignes et de colonnes après conversion en Double

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If CDbl(Target.rows.Count) * Target.columns.Count > 1 Then Exit Sub
End Sub

 

[mapomme]

Bonsoir à tous,

Une fonction CellsCount qui prend en compte les Range à plusieurs zones:

Function CellsCount(xrg As Range)
Dim xa, x As Currency
   For Each xa In xrg.Areas: x = x + xa.Rows.Count * xa.Columns.Count: Next
   CellsCount = x
End Function

 

[rafi93]

merci à tous !
Raphaël