Définir un Nom

[Guesh]

Bonjour à tous !!!

Voilà j'ai un petit problème, je souhaiterais savoir comment définir un Nom (Insertion\Nom\Définir) de façon à ce que ce nom sélectionne une plage de donnée allant de la première cellule non vide (dans mon exemple une date - colonne B) à une dernière cellule non vide, sachant que dans cette plage il peut y avoir des cases vides.

Un exemple est en copie.

Merci pour votre aide !!!

gsh

 

[TheLio]

Re : Définir un Nom

Hello,
Je ne sais pas fair depuis la première non vide,
Mais jusqu'à la dernière remplie, tu procéder ainsi:
=DECALER(Feuil1!$B$2;;;NB(Feuil1!$A:$A))
Bonne journée
A++
Lio

 

[Jocelyn]

Re : Définir un Nom

Bonjour le Forum,
Bonjour Guesh, TheLio,

La formule contenant trop de caractère pour entrée dans la donnée validation il faut passer par 2 plages nommées

dans l'exemple il y a

"Min" : =DECALER(Feuil1!$B$1;MIN(SI((Feuil1!$B$1:$B$2000<>"")*(LIGNE(Feuil1!$B$1:$B$2000)>1);LIGNE(Feuil1!$B$1:$B$2000)))-1😉

qui défini la première cellule non vide sans compter le libéllé de la colonne

et ensuite

"Plage" : =DECALER(min;;;MAX(SI(Feuil1!$B$1:$B$2000<>"";LIGNE(Feuil1!$B$1:$B$2000)))-LIGNE(min)+1)

Qui défini rééllement la plage

Jocelyn

 

[Monique]

Re : Définir un Nom

Bonjour,

On peut faire plus court avec le n° de la dernière ligne calculé comme ça :
EQUIV(9^9;$B:$B)

DECALER($B$1;MIN(SI(ESTNUM($B$2:$B$2000);LIGNE($B$2:$B$2000)))-1;0;EQUIV(9^9;$B:$B)-MIN(SI(ESTNUM($B$2:$B$2000);LIGNE($B$2:$B$2000)))+1)

Plus long mais c'est faisable, pour ne pas perdre une partie des 1000 ou 2000 lignes de temps en temps, B2:B2000 défini comme ça :
DECALER(Feuil1!$B$2;0;0;2000)

DECALER($B$1;MIN(SI(ESTNUM(DECALER($B$2;0;0;2000));LIGNE(DECALER($B$2;0;0;2000))))-1;;EQUIV(9^9;$B:$B)-MIN(SI(ESTNUM(DECALER($B$2;0;0;2000));LIGNE(DECALER($B$2;0;0;2000))))+1)

 

[Guesh]

Re : Définir un Nom

Merci à tous : c'est nickel !!!!