découpage fichier excel

[marycool]

Bonjour,

J'utilisais une macro pour découper un fichier excel sur excel 2003, qui ne fonctionne plus sur excel 2007 (installé récemment sur mon pc), j'utilisais la macro suivante:

Option Explicit

Sub Traitement()
'myDearFriend! - mon Univers Excel... : myDearFriend! Excel Pages
Dim CollMag As New Collection
Dim Plage As Range
Dim L As Long, L2 As Long, Lmax As Long
Application.ScreenUpdating = False
With Sheets("Feuil1") 'A adapter !
Lmax = .Cells(Application.Rows.Count, 1).End(xlUp).Row
'Création de la liste des magasins (sans doublons)
On Error Resume Next
For L = 2 To Lmax
CollMag.Add .Cells(L, 3).Text, .Cells(L, 3).Text
Next L
On Error GoTo 0
'Création des classeurs
For L = 2 To CollMag.Count
'Copie de l'onglet
.Copy
'Epurage des données par magasin
With ActiveSheet
Set Plage = .Rows(Application.Rows.Count)
For L2 = 2 To Lmax
If .Cells(L2, 3).Text <> CollMag(L) Then
Set Plage = Union(Plage, .Rows(L2))
End If
Next L2
Plage.Delete
End With
'Sauvegarde classeur "magasin X"
With ActiveWorkbook
.SaveAs ThisWorkbook.Path & "\Mag " & CollMag(L) & ".xls"
.Close
End With
Next L
End With
Application.ScreenUpdating = True
MsgBox CollMag.Count & " classeurs créés"
End Sub

Cette macro permettait de découper un fichier excel comprenant tous les prix dans tous mes magasins (colonne "four" dans le fichier joint)et ça me créait automatiquement un fichier excel par magasin (un fichier nommé AAA qui regroupait tous les produits et essentiellement les produits de AAA, idem pour BBB, idem pour CCC...), c'est un fichier de 4000 lignes donc c'était bien pratique!!!!

Merci d'avance de votre aide,

Cordialement,

Marycool

 

[mutzik]

Re : découpage fichier excel

bonjour,

ta macros s'arrete ou, sur quelle ligne de code ?
quelle est l'erreur générée ?

 

[marycool]

Re : découpage fichier excel

La macro ne se lance pas, le message d'erreur suivant apparait:

"Les fonctionnalités suivantes ne peuvent pas être enregistrées dans des classeurs sans macro: projet VB

Pour enregistrer un fichier avec ces fonctionnalités, cliquez sur non, puis sélectionner un type de fichier prenant en charge les macros dans la liste type de fichier

Pour continuer à enregistrer en tant que classeur sans macro, cliquez sur oui."

Si je mets NON, message d'erreur "400" qui apparait.

Sur excel 2003, la mcro marche bien, il y a ptet seulement une option de excel à modifier??

Merci d'avance,

Marycool

 

[kiki29]

Re : découpage fichier excel

Salut, ton fichier xlsm fonctionne sur mon PC ,par contre les 3 fichiers générés ( Mag BBB.xls Mag CCC.xlsMag DDD.xls ) sont illisibles
Il faut pour y remédier modifier la ligne ci-dessous en rajoutant le format de sauvegarde désiré

            With ActiveWorkbook
                .SaveAs ThisWorkbook.Path & "\Mag " & CollMag(L) & ".xls", FileFormat:=xlExcel8
                .Close
            End With

voir même encadrer par un Application.DisplayAlerts

          With ActiveWorkbook
                Application.DisplayAlerts = False
                .SaveAs ThisWorkbook.Path & "\Mag " & CollMag(L) & ".xls", FileFormat:=xlExcel8
                Application.DisplayAlerts = True
                .Close
            End With

 

[marycool]

Re : découpage fichier excel

En effet, ça marche.

Par la suite, mon fichier se bloquait sur un fournisseur avec un "/", mais j'ai supprimé le "/" et tout fonctionne.

Merci beaucoup de votre aide.

Bonne journée