Décalage de tableau dans une formule

[sand13]

Bonjour à tous,

J'ai une petite question à vous poser:
J'utilise des formules types recherchev,h, index etc...
De la forme: recherchev(A1;F1:GG2000;6;faux)
imaginons que cette formule se trouve dans la cellule B1.
Dans B2 maintenant je vais mettre la meme formule sauf que ce ne sera plus dans le tableau F1:GG2000, mais dans L1:GG2000

Comment puis-je faire pour que si je tire ces formules, cela les recopisse en décalant systématiquement le tableau de recherche de la même sorte.
(donc en B3: R1:GG2000) .....

Merci d'avance pour votre aide et votre temps

 

[sousou]

Re : Décalage de tableau dans une formule

Bonjour
En théorie
l'adressage est relatif, cela veut dire que quant tu tires ta formule elle suit les decallage.
Mais dans ton cas je pense que tu veux que certaines valeurs soit adressées en absolue.
dans la formule =recherchev(A1;F1:GG2000;6;faux) tout est relatif
le $ est le signe de l'adressage absolue
=recherchev($a$1;F1:$GG$200;6,faux)
essaie cette solution

 

[ThomThom13]

Re : Décalage de tableau dans une formule

Bonjour,

Je pense qu'en écrivant manuellement les deux premières formules puis en les sélectionnant et en le étirant tu pourra avoir le décalage voulu.

A essayer!

Désolé ça ne fonctionne pas!

 

[Samantha]

Re : Décalage de tableau dans une formule

Bonjour,

Sousou je pense que justement c'est un adressage semi relatif qui est demandé mais un adressage semi realtif un peu spécial : incrémenté de 6 colonnes pour le début mais avec une fin absolue

du genre recherchev($a$1;F1:$GG$200;6,faux) d'accord mais que le F devienne F+6 soit L lors d'une recopie vers la droite... et là je cale


Samantha(décodeur)

 

[Monique]

Re : Décalage de tableau dans une formule

Bonjour,

Fais un essai comme ça :
En B1 puis copier coller bers les bas
=INDEX(DECALER($K$1:$K$2000;0;(LIGNE()-1)*6);EQUIV(A1;DECALER($F$1:$F$2000;0;(LIGNE()-1)*6);0))
Decaler(Plage; nb de lignes; nb de colonnes; hauteur identique donc omis; largeur 1 donc omis)
Nb de colonnes est donné par (LIGNE()-1)*6

Ou bien en C1 puis copier coller bers les bas
=INDEX(DECALER($K$1;0;(LIGNE()-1)*6;2000);EQUIV(A1;DECALER($F$1;0;(LIGNE()-1)*6;2000);0))
Decaler(Cellule; nb de lignes; nb de colonnes; hauteur 2000; largeur 1 donc omis)

 

[Monique]

Re : Décalage de tableau dans une formule

Re,

C'est plus court et plus simple avec Recherchev()

Decaler tableau
=RECHERCHEV(A1;DECALER($F$1:$K$2000;0;(LIGNE()-1)*6);6;0)
Decaler(Tableau; 0 ligne ; 0 puis 6 puis 12 etc colonnes ; hauteur identique donc omis; largeur identique donc omis)

Decaler cellule
=RECHERCHEV(A1;DECALER($F$1;0;(LIGNE()-1)*6;2000;6);6;0)
Decaler(Cellule;0 ligne; 0 puis 6 puis 12 colonnes; hauteur 2000; largeur 6)