cumul avec matricul identique

tototiti2008

XLDnaute Barbatruc

• 18 Juin 2009

• #2

Re : cumul avec matricul identique

Bonjour excelo,

en D3, à recopier vers le bas :

=SI(B3<>"";SOMME(DECALER(C3;0;0;EQUIV("?*";B4:$B$11;0);1));"")

 

Vote positif 0 Vote négatif

JeanMarie

XLDnaute Barbatruc

• 18 Juin 2009

• #3

Re : cumul avec matricul identique

Bonsoir

Une autre proposition,

Code:

=SI(B3="";"";SOMME(C3:INDEX(C3:C$11;EQUIV("*";B4:$B$11;0))))

@+Jean-Marie

 

Dernière édition: 18 Juin 2009

Vote positif 0 Vote négatif

E

excelo

XLDnaute Occasionnel

• 18 Juin 2009

• #4

Re : cumul avec matricul identique

Merci Tototiti2008, merci JeanMarie pour vos formules "magiques"
vous m'avez rendu un grand service,
bonne soirée à tous et encore une fois vive le forum!!!!!

 

Vote positif 0 Vote négatif

E

excelo

XLDnaute Occasionnel

• 18 Juin 2009

• #5

Re : cumul avec matricul identique

c encore moi ;-)
je reviens sur la formule de tototiti2008, elle marche trés bien mais au dernier matricule elle m'affiche le résultat #N/A et je n'arrive pas à savoir pourquoi , j'ai contôlé les formules de fond en comble mais je comprends pas, quelqu'un aurait une idée?

 

Pièces jointes

• cumul.zip

  39.8 KB · Affichages: 51
• cumul.zip

  39.8 KB · Affichages: 54
• cumul.zip

  39.8 KB · Affichages: 50

Vote positif 0 Vote négatif

ROGER2327

XLDnaute Barbatruc

• 18 Juin 2009

• #6

Re : cumul avec matricul identique

Bonsoir excelo

Vous utilisez la formule

Code:

[COLOR="DarkSlateGray"]=SI(B3<>"";SOMME(DECALER(C3;0;0;EQUIV("?*";B4:$B$39;0);1));"")[/COLOR]

Donc votre plage de données s'arrête à la ligne 39.
Pour régler votre problème, utilisez la formule

Code:

[COLOR="DarkSlateGray"]=SI(B3<>"";SOMME(DECALER(C3;0;0;EQUIV("?*";B4:$B$[B][COLOR="Red"]40[/COLOR][/B];0);1));"")[/COLOR]

et mettez une espace (ou tout autre caractère) en B40.​

ROGER2327

 

Vote positif 0 Vote négatif

ledzepfred

XLDnaute Impliqué

• 18 Juin 2009

• #7

Re : cumul avec matricul identique

Bonsoir à tous,

autre solution en D3:

Code:

=SI(B3<>"";SI(ESTNA(SOMME(DECALER(C3;0;0;EQUIV("?*";B4:$B$39;0);1)));SOMME(C3:$C$39);SOMME(DECALER(C3;0;0;EQUIV("?*";B4:$B$39;0);1)));"")

Puisque C40 est vide, seule la dernière formule renvoie un N/A, il suffit de tester les formules et si renvoie N/A on somme bêtement le reste de la colonne.
Y a surement moins "tirer par les cheveux" mais ça fonctionne

A+

 

Vote positif 0 Vote négatif

E

excelo

XLDnaute Occasionnel

• 19 Juin 2009

• #8

Re : cumul avec matricul identique

merci ROGER2327 merci ledzepfred, je vais finaliser mon tableau avec l'une de vos solutions, merci à tous pour votre aide - bonne nuit pour ceux qui vont dormir - bon chat pour ceux qui resteront connecté ;-)

 

Vote positif 0 Vote négatif

JeanMarie

XLDnaute Barbatruc

• 19 Juin 2009

• #9

Re : cumul avec matricul identique

Bonjour tout le monde

Comme l'a suggéré Roger, le plus simple est d'étendre d'une cellule la plage, et de mettre un espace dans cette dernière.

Pour le fun, la formule de ledzepfred peut-être simplifiée

Code:

=SI(B3<>"";SI(ESTNA(EQUIV("?*";B4:$B$39;0));SOMME(C3:$C$39);SOMME(DECALER(C3;0;0;EQUIV("?*";B4:$B$39;0))));"")

Il n'est pas utile d'aller jusqu'à la SOMME pour savoir si #N/A est retournée, c'est EQUIV qui retourne ce message d'erreur, autant s'arrêter à ce niveau.
On peut encore simplifier. On voit que la fonction SOMME, est utilisée dans la partie VRAI et dans la FAUX de la fonction SI, ce qui veut dire que l'on fait une somme quoi qu'il arrive. En déplaçant cette fonction en début de formulation, donc avant le SI, on diminue la longueur de la formule.

Code:

=SI(B3<>"";SOMME(SI(ESTNA(EQUIV("?*";B4:$B$39;0));C3:$C$39;DECALER(C3;0;0;EQUIV("?*";B4:$B$39;0))));"")

D'autres combinaisons des fonctions SOMME - DECALER -SI(ESTNA( - EQUIV, pourrait donner ceci :

Code:

=SI(B3<>"";SOMME(DECALER(C3:C$39;;;SI(ESTNA(EQUIV("?*";B4:$B$39;0));LIGNES(C3:C$39);EQUIV("?*";B4:$B$39;0))));"")

Code:

=SI(B3="";"";SOMME(C3:SI(ESTNA(EQUIV("?*";B4:B$39;0));C$39;INDEX(C3:C$39;EQUIV("?*";B4:$B$39;0)))))

Ce que je vais retenir de ces échanges c'est l'idée de TotoTiti d'utiliser "?*"

@+Jean-Marie

 

Vote positif 0 Vote négatif

E

excelo

XLDnaute Occasionnel

• 19 Juin 2009

• #10

Re : cumul avec matricul identique

bonjour tout le monde, finalement les possibilités ont été nombreuses et fructifiantes, je vous remercie tous pour votre aide et votre sympathie, j'espère un jour avoir le niveau qui me permettra de vous aider le cas echéant (j'ai du boulot), bon appetit et bonne journée à tous;-)

 

Vote positif 0 Vote négatif