Création d'un menu dans un userform

[kchton57]

Bonjour,

Je souhaiterai créer un menu personnalisable dans un userform afin d'ouvrir d'autre userform.


Merci D'avance

 

[MichelXld]

Re : Création d'un menu dans un userform

bonjour

Cet exemple suppose que l'UserForm contient un label nommé Label1. La barre d'outils s'affiche lorsque tu cliques sur ce label.

Option Explicit
 
Dim X As Single
Dim Y As Single
 
 
'Création de la barre d'outils lors du lancement du UserForm
Private Sub UserForm_Initialize()
    Dim Barre As CommandBar
    
    Set Barre = CommandBars.Add("MenuUSF", msoBarPopup, False, True)
    
    With Barre.Controls.Add(msoControlButton, 1, , , True)
        .Caption = "Menu 01"
        .FaceId = 50
        'La procédure va appeler une macro nommée "Macro1", lorsque vous cliquerez
        'sur le bouton.
        .OnAction = "Macro1"
    End With
    
    With Barre.Controls.Add(msoControlButton, 2, , , True)
        .Caption = "Menu 02"
        .FaceId = 49
        'La procédure va appeler une macro nommée "Macro2", lorsque vous cliquerez
        'sur le bouton.
        .OnAction = "Macro2"
    End With
    
    
    With Me
        X = (.Width - .InsideWidth) / 2 + 8
        Y = .Height - .InsideHeight - X + 24
    End With
End Sub
 
 
 
'Affiche la barre d'outils lorsque vous cliquez sur le label.
Private Sub Label1_Click()
    Dim PosX As Single, PosY As Single
    
    PosX = (Me.Left + X + Label1.Left) * 4 / 3
    PosY = (Me.Top + Y + Label1.Top) * 4 / 3
    
    Application.CommandBars("MenuUSF").ShowPopup PosX, PosY
End Sub
 
 
 
'Supprime la barre d'outils lors de la fermeture du UserForm
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
    On Error Resume Next
    CommandBars("MenuUSF").Delete
End Sub

Ajoute ces deux macros dans un module standard:

Option Explicit
Sub Macro1()
    UserForm2.Show
End Sub

Sub Macro2()
    UserForm3.Show
End Sub

Bonne soirée
MichelXld

 

[biker]

Re : Création d'un menu dans un userform

Bonjour;

Je suis votre sujet et j'ai bien réussi à faire ce que demandais kchton57 mais moi mon souci est que dans les userform 2 et userform 3 je reprends le menu personnalisable de l'userform (d’origine).

Je voudrai savoir si c'était possible lorsque que je lance macro1 par exemple par le biais du menu ; un code vba pourrait me permettre de fermer l'userform actif auparavant.


Si mon explication n'est pas tres claire je peux vous faire parvenir un fichier