Correspondance entre nom et N° de colonne

[marmotte18]

Bonjour,

Je cherche à trouver une meilleure solution pour établir la correspondance entre le N° de colonne et son nom, d'autant que je souhaiterais aller jusqu'à la colonne 256 (IV) :

For Colonne = 1 To ColSup
 
    If Colonne = 1 Then Lettre = "A"
    If Colonne = 2 Then Lettre = "B"
    If Colonne = 3 Then Lettre = "C"
    If Colonne = 4 Then Lettre = "D"
    If Colonne = 5 Then Lettre = "E"
    If Colonne = 6 Then Lettre = "F"
    If Colonne > 6 Then MsgBox "Trop de tabulations !": Exit Sub
 
    Plage = Lettre & 65536
    LigneSup = Range(Plage).End(xlUp).Row 'Dernière ligne remplie de la colonne
Next Colonne

Je vous ai joint l'intégralité de mon code.

Merci par avance

 

[pierrejean]

Re : Correspondance entre nom et N° de colonne

bonjour marmotte

teste ceci

Function lettre_col(numero)
  lettre_col = Replace(Cells(1, numero).Address(0, 0), "1", "")
End Function
Sub test()
 MsgBox (lettre_col(1))
 MsgBox (lettre_col(256))
End Sub

Ps: je jette un oeil sur ton code
Et voici ton fichier

 

[marmotte18]

Re : Correspondance entre nom et N° de colonne

Bonsoir pierrejean,

Ta solution est impéccable ! Merci beaucoup !

 

[Staple1600]

Re : Correspondance entre nom et N° de colonne

Bonsoir


En complément de pierrejean (salutations)

Ici tu auras une profusion de solutions

(dont une fonction de kiki29 qui fonctionne aussi avec Excel 2007)

 

[Robert]

Re : Correspondance entre nom et N° de colonne

Bonjour le fil, bonjour le forum,

J'ai enfin compris, du moins le crois-je, la fonction Split. On pourrait peut-être faire comme ça :

lettre_col = Split(Cells(1, numero).Address, "$")
MsgBox lettre_col(1)

 

[Staple1600]

Re : Correspondance entre nom et N° de colonne

Bonsoir Robert


Comme le faisait Wilfried 42 (que je salue au passage) dans le fil que je cite dans mon précédent message 😉

 

[pierrejean]

Re : Correspondance entre nom et N° de colonne

Re

Hello Staple

As-tu testé ma fonction sous 2007 ?

 

[Staple1600]

Re : Correspondance entre nom et N° de colonne

Re

😱😱

Mais je viens de la tester sur Excel 2010 , et elle fonctionne.

Je t'en informe donc illico presto en espérant que cella rachètera ma faute.

PS: tu remarqueras que je n'ai pas insinuer que ta fonction ne fonctionnait pas sous Excel 2007.

 

[ROGER2327]

Re : Correspondance entre nom et N° de colonne

Bonsoir à tous

[COLOR="DarkSlateGray"][B]Function ANum$(n&)
   Do While n > 0
      ANum = Chr(((n - 1) Mod 26) + 65) & ANum
      n = (n - 1) \ 26
   Loop
End Function[/B][/COLOR]

ANum(1) renvoie A.
ANum(1024) renvoie AMJ.
ANum(2147483647) renvoie FXSHRXW.​

ROGER2327
#3507

Mercredi 4 Merdre 137 (Nativité de Saint Henri Rousseau, douanier, SQ)
2 Prairial An CCXVIII
2010-W20-5T23:53:57Z

 

[ROGER2327]

Re : Correspondance entre nom et N° de colonne

Suite...

... et la fonction réciproque :

[COLOR="DarkSlateGray"][B]Function NumA(s$)
Dim vl#, i&
   For i = 1 To Len(s)
      If Mid$(s, i, 1) Like "[A-Z]" Then vl = vl * 26 + Asc(Mid$(s, i, 1)) - 64
   Next i
   NumA = IIf(vl > 0, vl, "")
End Function[/B][/COLOR]

=NumA("A") renvoie 1.
=NumA("AMJ") renvoie 1024.
=NumA("FXSHRXW") renvoie 2147483647.​

ROGER2327
#3508

Jeudi 5 Merdre 137 (Saint Crouducul, troupier, SQ)
3 Prairial An CCXVIII
2010-W20-6T00:17:02Z

 

[JNP]

Re : Correspondance entre nom et N° de colonne

Bonjour le fil 🙂,

Re
Hello Staple
As-tu testé ma fonction sous 2007 ?

Elle fonctionne correctement sous 2007 😉.
Bon WE 😎

 

[pierrejean]

Re : Correspondance entre nom et N° de colonne

Re

Salut à tous

Pour la reciproque de ma fonction c'est:

Function num_col(lettre)
 num_col = Range(lettre & 1).Column
End Function

A noter que l'on ne va pas jusqu'a FXSHRXW ce qui ne parait pas très utile puisque 2007 est limité a XFD

 

[ROGER2327]

Re : Correspondance entre nom et N° de colonne

Bonjour pierrejean

Re

Salut à tous

Pour la reciproque de ma fonction c'est:

Function num_col(lettre)
 num_col = Range(lettre & 1).Column
End Function

A noter que l'on ne va pas jusqu'a FXSHRXW ce qui ne parait pas très utile puisque 2007 est limité a XFD

Il est vrai que je me suis un peu laissé entraîner par le sujet !
Ma réponse n'est pas vraiment adaptée au cas à traiter (sauf à anticiper sur une éventuelle version 2327 d'Excel qui pourra peut-être gérer 2_147_483_647 colonnes).

Faut rigoler...​

Pour rester sérieux : il vaut mieux utiliser ici une solution comme la vôtre, bien sûr.
Je laisse cependant ma proposition dans la discussion : elle dépannera peut-être dans d'autres situations.​

Bonne fin de semaine.
ROGER2327
#3510

Jeudi 5 Merdre 137 (Saint Crouducul, troupier, SQ)
3 Prairial An CCXVIII
2010-W20-6T08:51:56Z

 

[pierrejean]

Re : Correspondance entre nom et N° de colonne

Re

J'ai été un peu rapide ce matin et ai omis de saluer comme il se devait votre virtuosité a mettre les mathematiques en musique dans Excel
Voila qui est fait