Correction formule avec Sommeprod-merci

[JJ1]

Bonjour,
J'utilise une formule sommeprod qui ne me fournit pas les résultats attendus: je recherche des duos (= 2 nombres) dans une ligne compris dans des intervalles (tranche de 1à5, puis 2 à 6....).
La formule renvoie 1 s'il y a un duo au moins dans la tranche mais j'ai 0?
je souhaiterais plus bas une formule, qui au lieu de renvoyer 1, me donne le nombre de duos par tranche.
merci de votre aide, avec fichier exemple.
Bon jeudi à tous.

 

[JHA]

Re : Correction formule avec Sommeprod-merci

Bonjour JJ1, le forum,

Pas tout saisi mais voir fichier joint (quasiment pas de modif)

JHA

 

[JJ1]

Re : Correction formule avec Sommeprod-merci

Bonjour JHA,

je te renvoie le fichier avec une annotation car je ne comprends pas pourquoi 3 en V3 (je cherche les duos seulement, donc 2 ?) et pourquoi la formule donne comme résultat 0 pour la tranche alors qu'il y a 1 2 3 inclus entre 1 et 5 ?
Je cherche à connaitre dans quelle tranche il y a le plus de duos.
(je ne peux que modifier la formule car le tableau sert à un graphe)
j'ai laissé une seule tranche pour faire simple.

Peux tu regarder la formule de comptage en W13?

merci beaucoup

 

[JHA]

Re : Correction formule avec Sommeprod-merci

Re JJ1, le forum,

Tu recherches suivant 2 critères donc tu as forcément des "duos". Si tu regardes les formules misent en W11:AB11, sommeprod te donne le nombre de "duos".
Le chiffre mis en V3 te permet de te dire le nombre de "duos" = à V3.

mais c'est peut être moi qui ne comprends pas ton raisonnement.

JHA

 

[JJ1]

Re : Correction formule avec Sommeprod-merci

Re,

Merci pour ton explication sur le V3, j'ai testé avec plusieurs nombres, c'est ok.

Pour la 2ème formule, le sommeprod n'est certainement pas adapté:il ne me compte pas toutes les permutations croissantes (1 3 oui pas 3 1) présentes dans la ligne.
Je joins mon exemple avec 2 lignes.
Si tu as un moment.
merci et bon AM

 

[CISCO]

Re : Correction formule avec Sommeprod-merci

Bonjour

La fonction SOMMEPROD proposée compte le nombre de valeur comprise entre 1 et 5, dans l'exemple.

Ci-joint, un fichier avec une formule qui me semble faire ce que tu veux.

La formule utilisée est :
(NB.SI(A4:U4;">="&X$1)-NB.SI(A4:U4;">"&X$2))*(NB.SI(A4:U4;">="&X$1)-NB.SI(A4:U4;">"&X$2)-1)/2

ou =(SOMMEPROD((A4:U4>=X$1)*(A4:U4<=X$2))*(SOMMEPROD((A4:U4>=X$1)*(A4:U4<=X$2))-1)/2)

(NB.SI(A4:U4;">="&X$1)-NB.SI(A4:U4;">"&X$2)) ou SOMMEPROD((A4:U4>=X$1)*(A4:U4<=X$2)) caclule le nombre de valeur comprise entre 1 et 5, ce qui donne 2 dans ton fichier exemple.

(NB.SI(A4:U4;">="&X$1)-NB.SI(A4:U4;">"&X$2))*(NB.SI(A4:U4;">="&X$1)-NB.SI(A4:U4;">"&X$2)-1) ou (SOMMEPROD((A4:U4>=X$1)*(A4:U4<=X$2))*(SOMMEPROD((A4:U4>=X$1)*(A4:U4<=X$2))-1) calcule le nombre de couples réalisables avec ces valeurs.

Ensuite, on divise par deux pour éliminer les couples en double (1-3 et 3-1), puisque l'ordre des valeurs n'a pas d'importance.

@ plus

 

[JPP57]

Re : Correction formule avec Sommeprod-merci

Bonjour,

Ci-joint un fichier revu qui prends en compte soit les combinaisons de 2 de 3 voir de plus possibles, chiffre à mettre en S9.
J'ai utilisé une formule mathématiques qui dénombre les combinaisons.

La formule est C(nk)=n!/(k!(n-k)!)

Bonne soirée.

 

[JeanMarie]

Re : Correction formule avec Sommeprod-merci

Bonjour le forum

Une autre proposition en utilisant une fonction d'Excel

=SI(INDEX(FREQUENCE($A3:$U3;X$1:X$2-{1;0});2;1)>=$S$9;COMBIN(INDEX(FREQUENCE($A3:$U3;X$1:X$2-{1;0});2;1);$S$9);0)

Fonction COMBIN utilisant la formule mathématique.

@+Jean-Marie

 

[JPP57]

Re : Correction formule avec Sommeprod-merci

Fonction COMBIN utilisant la formule mathématique.

@+Jean-Marie

Bonjour Jean-Marie et merci pour ta fonction,
Je ne l'avais pas trouvé, peut-être pas assez cherché, c'est pourquoi j'avais utilisé la définition mathématique. Ma formule peut donc être modifiée simplement grâce à COMBIN

=SI(NB.SI($A3:$U3;">="&X$1)-NB.SI($A3:$U3;">"&X$2)-$S$9<0;0;COMBIN(NB.SI($A3:$U3;">="&X$1)-NB.SI($A3:$U3;">"&X$2);$S$9))

A+

 

[JJ1]

Re : Correction formule avec Sommeprod-merci

Bonjour à tous,
Grand merci pour vos idées et solutions, c'est pas facile.Je vais tester les différentes formules ce WE.
Bon vendredi à tous.
merci

 

[CISCO]

Re : Correction formule avec Sommeprod-merci

Bonjour à tous,
c'est pas facile

T'inquiète pas. Les relations proposées ci-dessus utilisent, à peu de chose près, la même méthode :
* compter le nombre de valeurs > ou = à X1
* compter le nombre de valeurs > à X2
* faire la différence entre ces deux valeurs, ce qui donne le nombre de valeurs comprises entre X1 et X2.
* puis calculer le nombre de couples réalisables, différents, sans tenir compte de l'ordre, avec ces valeurs.

@ plus