copier lignes choisies les coller en bas sur plusieurs feuilles

marskng · 5 Novembre 2012

Bonsoir
j'ai besoin d'aide s'il vous plait.
En fait, j'ai des variables à utiliser pour faire des formules avec, donc j'ai colorié en jaune les lignes de mes variables sur plusieurs feuilles , après pour répéter les manipulations avec ces variables sur plusieurs feuilles(faire sélectionner toutes les feuilles et effectuer mes formules), je voudrais copier les lignes jaunes en question, et les coller en bas de chaque feuille à la ligne 920 .
j'ai laissé un fichier joint avec un modèle réduit de mon classeur , en fait je veux reproduire ce qui a été fait dans la feuille 1 sur toutes les feuilles, soit copier les lignes jaunes ,les coller à partir de la ligne 920 pour toutes les autres feuilles.

marskng · 6 Novembre 2012

Re : copier lignes choisies les coller en bas sur plusieurs feuilles

personne pour m'aider s'il vous plait?
j'en ai vraiment besoin pour mon projet d'études ,

job75 · 6 Novembre 2012

Re : copier lignes choisies les coller en bas sur plusieurs feuilles

Bonjour marskng,

Sur Excel 2007 et versions suivantes on peut filtrer les couleurs avec le filtre automatique :

Code:

Sub FiltrerCouleur()
Dim w As Worksheet, plage As Range
Application.ScreenUpdating = False
For Each w In Worksheets
  Set plage = w.[U:U] 'colonne à adapter éventuellement
  w.AutoFilterMode = False
  plage.AutoFilter 1, RGB(255, 255, 0), xlFilterCellColor 'filtre la couleur jaune
  Set plage = plage.SpecialCells(xlCellTypeVisible).EntireRow
  w.AutoFilterMode = False
  w.Rows("920:" & w.Rows.Count).Delete
  plage.Copy w.Rows(920)
  w.Rows(920).Delete
Next
End Sub

Le filtrage se fait sur la colonne U qui convient pour toutes les feuilles de votre fichier.

Copie des lignes filtrées sur la ligne 920 de chaque feuille, comme demandé.

A+

marskng · 6 Novembre 2012

Re : copier lignes choisies les coller en bas sur plusieurs feuilles

bonsoir job75
Merci infiniment grâce à vous je vais gagner beaucoup de temps surtout que je suis débutant .

job75 · 7 Novembre 2012

Re : copier lignes choisies les coller en bas sur plusieurs feuilles

Bonjour marskng, le forum,

Je n'avais pas bien testé hier.

Il faut limiter la colonne filtrée par le UsedRange de la feuille :

Code:

Sub FiltrerCouleur()
Dim w As Worksheet, plage As Range
Application.ScreenUpdating = False
For Each w In Worksheets
  Set plage = Intersect(w.[A:A], w.UsedRange.EntireRow)
  plage.AutoFilter 1, RGB(255, 255, 0), xlFilterCellColor 'filtre la couleur jaune
  Set plage = plage.SpecialCells(xlCellTypeVisible)
  w.AutoFilterMode = False
  w.Rows("920:" & w.Rows.Count).Delete
  plage.EntireRow.Copy w.Rows(920)
  w.Rows(920).Delete
Next
End Sub

Fichier joint.

A+

marskng · 7 Novembre 2012

Re : copier lignes choisies les coller en bas sur plusieurs feuilles

Bonjour job75
merci mais normalement ça a marché dès le début avec le code que vous m'avez proposé en premier temps soit celui là:

Code:

Sub FiltrerCouleur()
Dim w As Worksheet, plage As Range
Application.ScreenUpdating = False
For Each w In Worksheets
  w.AutoFilterMode = False
  Set plage = w.UsedRange
  Set plage = w.Range("U1:U" & plage.Row + plage.Rows.Count)
  plage.AutoFilter 1, RGB(255, 255, 0), xlFilterCellColor 'filtre la couleur jaune
  Set plage = plage.SpecialCells(xlCellTypeVisible).EntireRow
  w.AutoFilterMode = False
  w.Rows("920:" & w.Rows.Count).Delete
  plage.Copy w.Rows(920)
  w.Rows(920).Delete
Next
End Sub

et votre dernier aussi a marché . merci encore une fois.

copier lignes choisies les coller en bas sur plusieurs feuilles

marskng

XLDnaute Nouveau

Pièces jointes

marskng

XLDnaute Nouveau

job75

XLDnaute Barbatruc

marskng

XLDnaute Nouveau

job75

XLDnaute Barbatruc

Pièces jointes

marskng

XLDnaute Nouveau

Discussions similaires