Copier les données d'un fichier à un autre

[Lili189]

Bonjour,

je souhaiterais une macro qui me copie les données du fichiers Valeur à insérer dans mon fichier Tableau 1.

La macro devra juste vérifier que la copie se fasse en fonction de la réference.

Pour REF = 1 dans le tableau 1 on copie les valeurs des colonnes de la ligne REF = 1 dans le fichier Valeur à insérer.

Merci d'avance, car je bloque.

 

[job75]

Re : Copier les données d'un fichier à un autre

Bonsoir Lili189,

Vous pouvez mettre cette macro n'importe où, dans n'importe quel classeur :

Sub Transfert()
Dim F1 As Worksheet, F2 As Worksheet, tablo1, tablo2
Dim ub&, i&, t, j&
Set F1 = Workbooks("Valeur a inserer dans le 1").Sheets("Feuil1")
Set F2 = Workbooks("Tableau 1").Sheets("Feuil1")
tablo1 = F1.Range("B2:D" & F1.[B65536].End(xlUp).Row)
tablo2 = F2.Range("A2:E" & F2.[A65536].End(xlUp).Row)
ub = UBound(tablo1)
For i = 1 To UBound(tablo2)
  t = tablo2(i, 1)
  For j = 1 To ub
    If tablo1(j, 1) = t Then
      tablo2(i, 3) = tablo1(j, 2)
      tablo2(i, 5) = tablo1(j, 3)
      Exit For
    End If
  Next
Next
F2.[A2:E2].Resize(UBound(tablo2)) = tablo2
End Sub

Elle est très rapide car elle utilise des tableaux VBA.

A+

 

[Lili189]

Re : Copier les données d'un fichier à un autre

merci beaucoup ! 🙂