Copier/coller des valeur et non des formules

[Tahititin]

Bonjour,
Quelqu'un pourrait-il m'aider à modifier la formule ci-dessous pour que le copier/coller se fasse sur les valeurs et non sur le contenu/formule ?

Sub Synthèse()
Dim Sh As Worksheet
With Sheets("Synthèse")
.[A2:J65536].Clear
Application.ScreenUpdating = 0
For Each Sh In Worksheets
If Sh.Name <> .Name Then _
Sh.Range("A11:J" & Sh.[A65536].End(xlUp).Row).Copy .[A65536].End(xlUp)(2)
Next
.[A2:J65536].Sort Key1:=.[G2], Order1:=xlAscending, Header:=xlNo
End With
End Sub

D'avance merci de votre aide précieuse

 

[Robert]

Bonjour Tahititin, bonjour le forum,

Essaie comme ça :

Sub Synthèse()
Dim Sh As Worksheet

With Sheets("Synthèse")
    .[A2:J65536].Clear
    Application.ScreenUpdating = 0
    For Each Sh In Worksheets
        If Sh.Name <> .Name Then
            Sh.Range("A11:J" & Sh.[A65536].End(xlUp).Row).Copy
            .[A65536].End(xlUp)(2).PasteSpecial (xlPasteValues)
        End If
    Next
    .[A2:J65536].Sort Key1:=.[G2], Order1:=xlAscending, Header:=xlNo
End With
End Sub

 

[Tahititin]

Bonjour Robert et merci pour ton retour,
Tu vas certainement trouver que je cherche la petite bête mais y a t'il un moyen de ne copier que la valeur (sans les formules) tout en gardant la mise en forme/format des cellules ? Je te joins un bout de fichier pour mieux comprendre.

Merci

 

[Robert]

Re,

Ça devrait donner ça :

Sub Synthèse()
Dim Sh As Worksheet

With Sheets("Synthèse")
    .[A2:J65536].Clear
    Application.ScreenUpdating = 0
    For Each Sh In Worksheets
        If Sh.Name <> .Name Then
            Sh.Range("A11:J" & Sh.[A65536].End(xlUp).Row).Copy
            .[A65536].End(xlUp)(2).PasteSpecial (xlPasteFormats)
            Sh.Range("A11:J" & Sh.[A65536].End(xlUp).Row).Copy
            .[A65536].End(xlUp)(2).PasteSpecial (xlPasteValues)
        End If
    Next
    .[A2:J65536].Sort Key1:=.[G2], Order1:=xlAscending, Header:=xlNo
End With
End Sub

 

[Tahititin]

Super !
Merci beaucoup Robert