Convertire le nombre de mois en année mois

[Yann71]

Bonjour la com.
Je ne trouve pas l'information que je recherche sur GOOGLE, donc je me dirige ici car pour moi le meilleur centre de recherche est ICI.
J'aimerai connaître la formule, qui me permet d'afficher des mois en année mois. Un exemple concret:

Dans cellule A1 j'ai 32 qui correspond dans ma colonne aux nombres de mois et j'aimerai qu'en A2 s'affiche 2 ans et 8 mois.

Merci d'avance pour votre aide.

 

[Dudu2]

Bonjour,
Cette formule devrait fonctionner:
=SI(A1>=12;ENT(A1/12) & " an" & SI( ENT(A1/12) > 1; "s"; "");"" ) & SI(ET(ENT(A1/12) >0;MOD(A1;12) >0);" et ";"") & SI(MOD(A1;12) >0;MOD(A1;12) & " mois";"")

 

[laurent3372]

Bonjour Yann,

en B1:

=ANNEE(DATE(0;A1+1;0))-1900&" ans et "&MOIS(DATE(0;A1+1;0))&" mois"

Cordialement,
--
LR

 

[patricktoulon]

bonjour le fils
sinon celle ci fonctionne aussi
=ENT(A5/12)&" an"&SI(ENT(A5/12)>1;"s ";" ") & SI(12*(A5-(12*ENT(A5/12)))/12>0;" et "& (12*(A5-(12*ENT(A5/12)))/12) & " mois";"" )

 

[R@chid]

Bonjour @ tous,

=ENT(A1/12)&" ans et "&MOD(A1;12)&" mois"

Cordialement

 

[patricktoulon]

bonjour @laurent3372

 

[patricktoulon]

bonjour R@chid c'est un peux mieux mais ajoute la condition "0" pour le "et........"

 

[patricktoulon]

correction de celle de @R@child
=ENT(A3/12)&" ans"& SI(MOD(A3;12)>0;" et " &MOD(A3;12)&" mois";"")

 

[R@chid]

bonjour R@chid c'est un peux mieux mais ajoute la condition "0" pour le "et........"
Regarde la pièce jointe 1058322

Re,
ehh oui, on doit aussi ajouter d'autre condition, si A1 est vide ou A1 est égale à 0, si aussi A1 contient un test et pas une valeur numérique.
Je ne veux pas rendre la formule trop longue.

Cordialement

 

[patricktoulon]

Re,
ehh oui, on doit aussi ajouter d'autre condition, si A1 est vide ou A1 est égale à 0, si aussi A1 contient un test et pas une valeur numérique.
Je ne veux pas rendre la formule trop longue.

Cordialement

revoir #post8

 

[R@chid]

correction de celle de @R@child
=ENT(A3/12)&" ans"& SI(MOD(A3;12)>0;" et " &MOD(A3;12)&" mois";"")

Regarde la pièce jointe 1058323

Aussi si ENT(A3/12)=1 pour enlever le S à la fin du mot "ans"

 

[patricktoulon]

re
ca reste dudu2 qui gagne une tringle à rideau

et si j'adapte les conditions pour tout ca reste celle de dudu2 la plus courte

 

[R@chid]

Je ne vois rien
il faut joindre un fichier

 

[patricktoulon]

re
ca sert a rien le test mod ne suffit pas car par exemple le 8 sera une erreur

MOD(8;12) donne 8 donc le test >0 walouh walouh
tout ce qui brille n'est pas d'or


celle ci teste même le vide le "s" le "et".....
=SI(A3<>0;SI(A3<12;A3 &" mois";SI(ENT(A3/12)>0;ENT(A3/12)&" an";"")&SI(ENT(A3/12)>1;"s";"") & SI(ET(A3>=12;(A3/12)-ENT(A3/12)>0);" et " & 12*(A3/12-(ENT(A3/12))) & " mois";""));"")

 

[Dudu2]

@patricktoulon j'ai failli me lancer dans cette évaluation pour choisir le meilleur prestataire
Ça tombe bien, j'ai une vieille tringle de 25 ans qui bloque et donc à changer