Convertir une liste de plage de N° en une seule liste...

[nicoebra]

Bonjour à tous,

J'ai besoin de votre aide pour convertir une liste de plage de N° (sur 2 colonnes, un champ debut plage et un second fin plage) en une seule liste de N°...

Vous avez un exemple en PJ beaucoup plus explicite... la première feuille représente les données que j'ai à disposition, la seconde feuille représente les données que je veux au final... Évidement, en vrai j'ai 7500 plages de N°....

Est-ce que vous voyez comment faire ça de façon automatique ??

Merci beaucoup,

Nico

 

[mth]

Re : Convertir une liste de plage de N° en une seule liste...

Bonsoir,

On doit pouvoir faire mieux, mais essaie avec ce code:

Sub macro1()
Application.ScreenUpdating = False
With Sheets("Format final")
    .Range("A2:C" & .Cells(Rows.Count, 1).End(xlUp).Row).ClearContents
End With
With Sheets("Données initiales")
    derlig = .Cells(Rows.Count, 1).End(xlUp).Row
    For i = 2 To derlig
        vdebut = .Cells(i, 1)
        vfin = .Cells(i, 2)
        vtype = .Cells(i, 3)
        vcat = .Cells(i, 4)
        For j = vdebut To vfin
            derlig2 = Sheets("Format final").Cells(Rows.Count, 1).End(xlUp).Row + 1
            With Sheets("Format final")
                .Range("A" & derlig2) = j
                .Range("B" & derlig2) = vtype
                .Range("C" & derlig2) = vcat
            End With
        Next j
    Next i
End With
Application.ScreenUpdating = True
End Sub

Bonne soirée,

mth

 

[nicoebra]

Re : Convertir une liste de plage de N° en une seule liste...

Salut,

Ca a marché nickel !! merci beaucoup, vraiment !

nico